configure: drop deprecated autoconf macros.

Bump autoconf required version to 2.58, needed for AS_HELP_STRING macro.

Signed-off-by: Gwenole Beauchesne <gwenole.beauchesne@intel.com>

diff --git a/configure.ac b/configure.ac
index d69959b..e221e4f 100644 (file)
--- a/configure.ac
+++ b/configure.ac
@@ -55,14 +55,14 @@ m4_define([gtkdoc_major_version], [1])
 m4_define([gtkdoc_minor_version], [9])
 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
 
-AC_PREREQ([2.57])
+AC_PREREQ([2.58])
 AC_INIT([gst_vaapi], [gst_vaapi_version],
     [gwenole.beauchesne@intel.com],
     [gstreamer-vaapi])
 AC_CONFIG_SRCDIR([Makefile.am])
 AC_CANONICAL_TARGET
 AM_INIT_AUTOMAKE
-AM_CONFIG_HEADER([config.h])
+AC_CONFIG_HEADERS([config.h])
 
 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
 AC_SUBST(TODAY)
@@ -94,27 +94,27 @@ AM_PROG_CC_C_O
 AC_PROG_LIBTOOL
 
 AC_ARG_ENABLE(glx,
-    AC_HELP_STRING([--enable-glx],
+    AS_HELP_STRING([--enable-glx],
                    [enable OpenGL/X11 @<:@default=yes@:>@]),
     [], [enable_glx="yes"])
 
 AC_ARG_ENABLE(vaapi-glx,
-    AC_HELP_STRING([--enable-vaapi-glx],
+    AS_HELP_STRING([--enable-vaapi-glx],
                    [enable VA/GLX extensions @<:@default=yes@:>@]),
     [], [enable_vaapi_glx="yes"])
 
 AC_ARG_ENABLE(vaapisink-glx,
-    AC_HELP_STRING([--enable-vaapisink-glx],
+    AS_HELP_STRING([--enable-vaapisink-glx],
                    [enable OpenGL/X11 to vaapisink @<:@default=yes@:>@]),
     [], [enable_vaapisink_glx="no"])
 
 AC_ARG_ENABLE(ffmpeg,
-    AC_HELP_STRING([--enable-ffmpeg],
+    AS_HELP_STRING([--enable-ffmpeg],
                    [enable bitstream parsing from FFmpeg @<:@default=no@:>@]),
     [], [enable_ffmpeg="no"])
 
 AC_ARG_ENABLE(codecparsers,
-    AC_HELP_STRING([--enable-codecparsers],
+    AS_HELP_STRING([--enable-codecparsers],
                    [enable adhoc bitstream parsers from GStreamer @<:@default=yes@:>@]),
     [], [enable_codecparsers="yes"])
 
@@ -170,9 +170,10 @@ AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
     CFLAGS="$CFLAGS $GST_CFLAGS"
     saved_LIBS="$LIBS"
     LIBS="$LIBS $GST_LIBS"
-    AC_TRY_COMPILE(
-        [#include <gst/base/gstbasesink.h>],
-        [GstBaseSinkClass klass; klass.query = NULL;],
+    AC_COMPILE_IFELSE(
+        [AC_LANG_PROGRAM(
+            [[#include <gst/base/gstbasesink.h>]],
+            [[GstBaseSinkClass klass; klass.query = NULL;]])],
         [ac_cv_have_gst_base_sink_query="yes"],
         [ac_cv_have_gst_base_sink_query="no"]
     )
@@ -212,9 +213,10 @@ AC_CACHE_CHECK([for GstVideoOverlayComposition],
     CFLAGS="$CFLAGS $GST_CFLAGS"
     saved_LIBS="$LIBS"
     LIBS="$LIBS $GST_LIBS"
-    AC_TRY_COMPILE(
-        [#include <gst/video/video-overlay-composition.h>],
-        [GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);],
+    AC_COMPILE_IFELSE(
+        [AC_LANG_PROGRAM(
+            [[#include <gst/video/video-overlay-composition.h>]],
+            [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
         [ac_cv_have_gst_video_overlay_composition="yes"],
         [ac_cv_have_gst_video_overlay_composition="no"]
     )
@@ -252,10 +254,11 @@ AC_CACHE_CHECK([for GstH264SliceHdr::n_emulation_prevention_bytes],
     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
     saved_LIBS="$LIBS"
     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
-    AC_TRY_COMPILE(
-        [#include <gst/codecparsers/gsth264parser.h>],
-        [GstH264SliceHdr slice_hdr;
-         slice_hdr.n_emulation_prevention_bytes = 0;],
+    AC_COMPILE_IFELSE(
+        [AC_LANG_PROGRAM(
+            [[#include <gst/codecparsers/gsth264parser.h>]],
+            [[GstH264SliceHdr slice_hdr;
+              slice_hdr.n_emulation_prevention_bytes = 0;]])],
         [ac_cv_have_gst_h264_slice_hdr_epb_count="yes"],
         [ac_cv_have_gst_h264_slice_hdr_epb_count="no"]
     )
@@ -269,9 +272,10 @@ AC_CACHE_CHECK([for JPEG parser],
     CFLAGS="$CFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
     saved_LIBS="$LIBS"
     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
-    AC_TRY_COMPILE(
-        [#include <gst/codecparsers/gstjpegparser.h>],
-        [GstJpegImage jpeg_image;],
+    AC_COMPILE_IFELSE(
+        [AC_LANG_PROGRAM(
+            [[#include <gst/codecparsers/gstjpegparser.h>]],
+            [[GstJpegImage jpeg_image;]])],
         [ac_cv_have_gst_jpeg_parser="yes"],
         [ac_cv_have_gst_jpeg_parser="no" USE_LOCAL_CODEC_PARSERS=1]
     )
@@ -350,11 +354,13 @@ AC_CACHE_CHECK([for old VA-API 0.29],
     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
     saved_LIBS="$LIBS"
     LIBS="$LIBS $LIBVA_LIBS"
-    AC_TRY_LINK(
-    [#include <va_x11.h>],
-    [vaGetDisplay(NULL)],
-    [ac_cv_have_vaapi_old="yes"],
-    [ac_cv_have_vaapi_old="no"])
+    AC_LINK_IFELSE(
+        [AC_LANG_PROGRAM(
+            [[#include <va_x11.h>]],
+            [[vaGetDisplay(NULL)]])],
+        [ac_cv_have_vaapi_old="yes"],
+        [ac_cv_have_vaapi_old="no"]
+    )
     CFLAGS="$saved_CFLAGS"
     LIBS="$saved_LIBS"
 ])
@@ -408,13 +414,14 @@ AC_CACHE_CHECK([for JPEG decoding API],
     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
     saved_LIBS="$LIBS"
     LIBS="$CFLAGS $LIBVA_LIBS"
-    AC_TRY_COMPILE(
-        [#include <va/va.h>
-         #include <va/va_dec_jpeg.h>],
-        [VAPictureParameterBufferJPEG pic_param;
-         VASliceParameterBufferJPEG slice_param;
-         VAHuffmanTableBufferJPEG huffman_table;
-         VAIQMatrixBufferJPEG iq_matrix;],
+    AC_COMPILE_IFELSE(
+        [AC_LANG_PROGRAM(
+            [[#include <va/va.h>
+              #include <va/va_dec_jpeg.h>]],
+            [[VAPictureParameterBufferJPEG pic_param;
+              VASliceParameterBufferJPEG slice_param;
+              VAHuffmanTableBufferJPEG huffman_table;
+              VAIQMatrixBufferJPEG iq_matrix;]])],
         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
         [ac_cv_have_jpeg_decoding_api="no"]
     )
@@ -479,7 +486,7 @@ VA_VERSION_STR="$VA_VERSION"
 pkgconfigdir=${libdir}/pkgconfig
 AC_SUBST(pkgconfigdir)
 
-AC_OUTPUT([
+AC_CONFIG_FILES([
     Makefile
     debian.upstream/Makefile
     debian.upstream/changelog
@@ -517,6 +524,7 @@ pkgconfig/gstreamer-vaapi-x11.pc.in
     gst/vaapi/Makefile
     tests/Makefile
 ])
+AC_OUTPUT
 
 dnl Print summary
 yesno() {