X-Git-Url: http://review.tizen.org/git/?a=blobdiff_plain;f=meson.build;h=e925ec907a818c04a76baaaa8d3edbad0fb2ec32;hb=6c621bba0273e6cc8570e6b189330fc67b1b8dcc;hp=7cab556e0c2b34b3aa0c4a1889c40aabcc1cc374;hpb=ca8068c6d793d7aaa6f2e2cc6324fdedfe2f33fa;p=platform%2Fupstream%2Fgstreamer.git

diff --git a/meson.build b/meson.build
index 7cab556..e925ec9 100644
--- a/meson.build
+++ b/meson.build
@@ -1,563 +1,525 @@
-project('gst-plugins-bad', 'c', 'cpp',
-  version : '1.19.2',
-  meson_version : '>= 0.54',
-  default_options : [ 'warning_level=1',
-                      'buildtype=debugoptimized' ])
-
-gst_version = meson.project_version()
-version_arr = gst_version.split('.')
-gst_version_major = version_arr[0].to_int()
-gst_version_minor = version_arr[1].to_int()
-gst_version_micro = version_arr[2].to_int()
- if version_arr.length() == 4
-  gst_version_nano = version_arr[3].to_int()
-else
-  gst_version_nano = 0
-endif
-gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
-
-glib_req = '>= 2.56.0'
-orc_req = '>= 0.4.17'
-gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
-
-api_version = '1.0'
-soversion = 0
-# maintaining compatibility with the previous libtool versioning
-# current = minor * 100 + micro
-curversion = gst_version_minor * 100 + gst_version_micro
-libversion = '@0@.@1@.0'.format(soversion, curversion)
-osxversion = curversion + 1
-
-plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
-plugins = []
-
+project('gstreamer-full', 'c',
+  version : '1.21.3.1',
+  meson_version : '>= 0.62.0',
+  default_options : ['buildtype=debugoptimized',
+                     # Needed due to https://github.com/mesonbuild/meson/issues/1889,
+                     # but this can cause problems in the future. Remove it
+                     # when it's no longer necessary.
+                     'cpp_std=c++14'])
+
+apiversion = '1.0'
+gst_version = '>= @0@'.format(meson.project_version())
+
+build_system = build_machine.system()
 cc = meson.get_compiler('c')
-cxx = meson.get_compiler('cpp')
-host_system = host_machine.system()
 
-if host_system in ['ios', 'darwin']
-  have_objc = add_languages('objc', native: false)
-  have_objcpp = add_languages('objcpp', native: false)
-else
-  have_objc = false
-  have_objcpp = false
+fs = import('fs')
+gnome = import('gnome')
+pkgconfig = import('pkgconfig')
+python3 = import('python').find_installation()
+# Ensure that we're not being run from inside the development environment
+# because that will confuse meson, and it might find the already-built
+# gstreamer. It's fine if people run `ninja` as long as it doesn't run
+# reconfigure because ninja doesn't care about the env.
+ensure_not_devenv = '''
+import os
+assert('GST_ENV' not in os.environ)
+'''
+cmdres = run_command(python3, '-c', ensure_not_devenv, check: false)
+if cmdres.returncode() != 0
+  error('Do not run `ninja reconfigure` or `meson` for gst-build inside the development environment, you will run into problems')
 endif
 
-cdata = configuration_data()
-
-if cc.get_id() == 'msvc'
-  msvc_args = [
-      # Ignore several spurious warnings for things gstreamer does very commonly
-      # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
-      # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
-      # NOTE: Only add warnings here if you are sure they're spurious
-      '/wd4018', # implicit signed/unsigned conversion
-      '/wd4146', # unary minus on unsigned (beware INT_MIN)
-      '/wd4244', # lossy type conversion (e.g. double -> int)
-      '/wd4305', # truncating type conversion (e.g. double -> float)
-      cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
-
-      # Enable some warnings on MSVC to match GCC/Clang behaviour
-      '/w14062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
-      '/w14101', # 'identifier' : unreferenced local variable
-      '/w14189', # 'identifier' : local variable is initialized but not referenced
-  ]
-  add_project_arguments(msvc_args, language: ['c', 'cpp'])
-  # Disable SAFESEH with MSVC for plugins and libs that use external deps that
-  # are built with MinGW
-  noseh_link_args = ['/SAFESEH:NO']
-else
-  if cxx.has_argument('-Wno-non-virtual-dtor')
-    add_project_arguments('-Wno-non-virtual-dtor', language: 'cpp')
+# Install gst-indent pre-commit hook
+run_command(python3, '-c', 'import shutil; shutil.copy("scripts/git-hooks/multi-pre-commit.hook", ".git/hooks/pre-commit")', check: false)
+
+# On macOS, you have to run "Install Certificates.command" otherwise Python
+# doesn't have access to the latest SSL CA Certificates, and Meson will fail to
+# download wrap files from websites that use, for example, Let's Encrypt.
+# We already recommend this in the README, but add a warning here as well.
+# Can't make this an error because the user might be using XCode's Python
+# 3 which doesn't have this script.
+if build_system == 'darwin'
+  python3_cacert_file = python3.get_path('data') / 'etc/openssl/cert.pem'
+  install_cert_cmd = '/Applications/Python @0@/Install Certificates.command'.format(python3.language_version())
+  if not fs.is_symlink(python3_cacert_file) and fs.is_file(install_cert_cmd)
+    warning('Please run "@0@" so that Python has access to the latest SSL certificates. Meson might fail to download some wraps without it.'.format(install_cert_cmd))
   endif
-
-  noseh_link_args = []
 endif
 
-if cc.has_link_argument('-Wl,-Bsymbolic-functions')
-  add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
-endif
-
-# Symbol visibility
-if cc.get_id() == 'msvc'
-  export_define = '__declspec(dllexport) extern'
-elif cc.has_argument('-fvisibility=hidden')
-  add_project_arguments('-fvisibility=hidden', language: 'c')
-  add_project_arguments('-fvisibility=hidden', language: 'cpp')
-  if have_objc
-    add_project_arguments('-fvisibility=hidden', language: 'objc')
+documented_projects = ''
+# Make it possible to use msys2 built zlib which fails
+# when not using the mingw toolchain as it uses unistd.h
+if not meson.is_subproject() and cc.get_id() == 'msvc'
+  uname = find_program('uname', required: false)
+  if uname.found()
+    ret = run_command(uname, '-o', check: false)
+    if ret.returncode() == 0 and ret.stdout().to_lower() == 'msys'
+      ret = run_command(uname, '-r', check: false)
+      # The kernel version returned by uname is actually the msys version
+      if ret.returncode() == 0 and ret.stdout().startswith('2')
+        # If a system zlib is found, disable UNIX features in zlib.h and zconf.h
+        if cc.find_library('z').found()
+          add_global_arguments('-DZ_SOLO', language: 'c')
+        endif
+      endif
+    endif
   endif
-  export_define = 'extern __attribute__ ((visibility ("default")))'
-else
-  export_define = 'extern'
 endif
 
-# Passing this through the command line would be too messy
-cdata.set('GST_API_EXPORT', export_define)
-
-# Disable strict aliasing
-if cc.has_argument('-fno-strict-aliasing')
-  add_project_arguments('-fno-strict-aliasing', language: 'c')
-endif
-if cxx.has_argument('-fno-strict-aliasing')
-  add_project_arguments('-fno-strict-aliasing', language: 'cpp')
+# Ensure that MSVC interprets all source code as UTF-8. Only do this when we're
+# not a subproject, because subprojects are not allowed to call
+# add_global_arguments().
+if not meson.is_subproject() and cc.get_id() == 'msvc'
+  add_global_arguments(
+      cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
+      language: ['c', 'cpp'])
 endif
 
-# Define G_DISABLE_DEPRECATED for development versions
-if gst_version_is_dev
-  message('Disabling deprecated GLib API')
-  add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
+building_full = get_option('default_library') == 'static'
+tools_option = []
+if building_full and not get_option('tools').disabled()
+  # Do not build subprojects tools when we build them against gst-full
+  tools_option = ['tools=disabled']
 endif
 
-cast_checks = get_option('gobject-cast-checks')
-if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
-  message('Disabling GLib cast checks')
-  add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
-endif
+# Ordered list of subprojects (dict has no ordering guarantees)
+subprojects = [
+  ['gstreamer', {'build-hotdoc': true, 'subproject_options': tools_option}],
+  ['gst-plugins-base', {'option': get_option('base'), 'build-hotdoc': true}],
+  ['gst-plugins-good', {'option': get_option('good'), 'build-hotdoc': true}],
+  ['libnice', { 'option': get_option('libnice'), 'match_gst_version': false}],
+  ['gst-plugins-bad', { 'option': get_option('bad'), 'build-hotdoc': true}],
+  ['gst-plugins-ugly', { 'option': get_option('ugly'), 'build-hotdoc': true}],
+  ['gst-libav', { 'option': get_option('libav'), 'build-hotdoc': true}],
+  ['gst-rtsp-server', { 'option': get_option('rtsp_server'), 'build-hotdoc': true}],
+  ['gst-devtools', { 'option': get_option('devtools'), 'build-hotdoc': true, 'subproject_options': tools_option}],
+  ['gst-integration-testsuites', { 'option': get_option('devtools') }],
+  ['gst-editing-services', { 'option': get_option('ges'), 'build-hotdoc': true, 'subproject_options': tools_option}],
+  ['gstreamer-vaapi', { 'option': get_option('vaapi'), 'build-hotdoc': true}],
+  ['gst-omx', { 'option': get_option('omx'), 'build-hotdoc': true}],
+  ['gstreamer-sharp', { 'option': get_option('sharp') }],
+  ['pygobject', { 'option': get_option('python'), 'match_gst_version': false, 'sysdep': 'pygobject-3.0', 'sysdep_version': '>= 3.8' }],
+  ['gst-python', { 'option': get_option('python')}],
+  ['gst-examples', { 'option': get_option('gst-examples'), 'match_gst_versions': false}],
+  ['gst-plugins-rs', { 'option': get_option('rs'), 'build-hotdoc': true, 'match_gst_version': false}],
+]
 
-glib_asserts = get_option('glib-asserts')
-if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
-  message('Disabling GLib asserts')
-  add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
+if build_system == 'windows'
+  subproject('win-flex-bison-binaries')
+  subproject('win-nasm')
+elif build_system == 'darwin'
+  subproject('macos-bison-binary')
 endif
 
-glib_checks = get_option('glib-checks')
-if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
-  message('Disabling GLib checks')
-  add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
+orc_option = get_option('orc')
+# There is a check below to keep this in sync with subprojects/gst-plugins-base/meson.build
+orc_req = '>= 0.4.24'
+orc_source_option = get_option('orc-source')
+orc_subproject = disabler()
+if orc_option.allowed()
+  if orc_source_option == 'subproject'
+    orc_subproject = subproject('orc', required: orc_option)
+  else
+    dependency('orc-0.4', version: orc_req, required: orc_option,
+               allow_fallback: orc_source_option == 'auto')
+  endif
 endif
 
-check_headers = [
-  ['HAVE_DLFCN_H', 'dlfcn.h'],
-  ['HAVE_FCNTL_H', 'fcntl.h'],
-  ['HAVE_INTTYPES_H', 'inttypes.h'],
-  ['HAVE_MEMORY_H', 'memory.h'],
-  ['HAVE_NETINET_IN_H', 'netinet/in.h'],
-  ['HAVE_NETINET_IP_H', 'netinet/ip.h'],
-  ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
-  ['HAVE_PTHREAD_H', 'pthread.h'],
-  ['HAVE_STDINT_H', 'stdint.h'],
-  ['HAVE_STDLIB_H', 'stdlib.h'],
-  ['HAVE_STRINGS_H', 'strings.h'],
-  ['HAVE_STRING_H', 'string.h'],
-  ['HAVE_SYS_PARAM_H', 'sys/param.h'],
-  ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
-  ['HAVE_SYS_STAT_H', 'sys/stat.h'],
-  ['HAVE_SYS_TIME_H', 'sys/time.h'],
-  ['HAVE_SYS_TYPES_H', 'sys/types.h'],
-  ['HAVE_SYS_UTSNAME_H', 'sys/utsname.h'],
-  ['HAVE_UNISTD_H', 'unistd.h'],
-  ['HAVE_WINDOWS_H', 'windows.h'],
-  ['HAVE_WINSOCK2_H', 'winsock2.h'],
-  ['HAVE_WS2TCPIP_H', 'ws2tcpip.h'],
-]
-
-foreach h : check_headers
-  if cc.has_header(h.get(1))
-    cdata.set(h.get(0), 1)
-  endif
+foreach custom_subproj: get_option('custom_subprojects').split(',')
+    if custom_subproj != ''
+        message ('Adding custom subproject ' + custom_subproj)
+        subprojects += [[custom_subproj, {'match_gst_version': false}]]
+    endif
 endforeach
 
-check_functions = [
-  ['HAVE_DCGETTEXT', 'dcgettext'],
-  ['HAVE_GETPAGESIZE', 'getpagesize'],
-  ['HAVE_GMTIME_R', 'gmtime_r'],
-  ['HAVE_MEMFD_CREATE', 'memfd_create'],
-  ['HAVE_MMAP', 'mmap'],
-  ['HAVE_PIPE2', 'pipe2'],
-  ['HAVE_GETRUSAGE', 'getrusage', '#include<sys/resource.h>'],
-]
 
-foreach f : check_functions
-  prefix = ''
-  if f.length() == 3
-    prefix = f.get(2)
-  endif
-  if cc.has_function(f.get(1), prefix: prefix)
-    cdata.set(f.get(0), 1)
+subprojects_names = []
+plugins_doc_caches = []
+orc_update_targets = []
+all_plugins = []
+all_tools = {}
+# Using a list and not a dict to keep the ordering to build the chain of `gir`
+# dependencies
+all_libraries = []
+foreach sp : subprojects
+  project_name = sp[0]
+  build_infos = sp[1]
+  is_required = build_infos.get('option', true)
+  sysdep = build_infos.get('sysdep', '')
+  sysdep_version = build_infos.get('sysdep_version', '')
+  match_gst_version = build_infos.get('match_gst_version', true)
+  default_options =  build_infos.get('subproject_options', [])
+
+  if match_gst_version
+    subproj = subproject(project_name, version: gst_version, required: is_required, default_options: default_options)
+  elif sysdep != ''
+      sysdep_dep = dependency(sysdep, version: sysdep_version, required: false, default_options: default_options)
+      if not sysdep_dep.found()
+        subproj = subproject(project_name, required: is_required, default_options: default_options)
+      endif
+  else
+    subproj = subproject(project_name, required: is_required, default_options: default_options)
   endif
-endforeach
 
-cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
-cdata.set('SIZEOF_INT', cc.sizeof('int'))
-cdata.set('SIZEOF_LONG', cc.sizeof('long'))
-cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
-cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
-
-cdata.set_quoted('VERSION', gst_version)
-cdata.set_quoted('PACKAGE', 'gst-plugins-bad')
-cdata.set_quoted('PACKAGE_VERSION', gst_version)
-cdata.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.freedesktop.org/gstreamer/gst-plugins-bad/issues/new')
-cdata.set_quoted('PACKAGE_NAME', 'GStreamer Bad Plug-ins')
-cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-bad-1.0')
-cdata.set_quoted('GST_API_VERSION', api_version)
-cdata.set_quoted('GST_LICENSE', 'LGPL')
-cdata.set_quoted('LIBDIR', join_paths(get_option('prefix'), get_option('libdir')))
-cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
-
-warning_flags = [
-  '-Wmissing-declarations',
-  '-Wredundant-decls',
-  '-Wwrite-strings',
-  '-Wformat',
-  '-Wformat-security',
-  '-Winit-self',
-  '-Wmissing-include-dirs',
-  '-Waddress',
-  '-Wno-multichar',
-  '-Wvla',
-  '-Wpointer-arith',
-]
+  if project_name == 'gst-plugins-base'
+    gst_base_orc_req = subproj.get_variable('orc_req', '')
+    if gst_base_orc_req != orc_req
+      error('orc_req is "@0@" but it should be "@1@" from subprojects/gst-plugins-base/meson.build'
+            .format(orc_req, gst_base_orc_req))
+    endif
+  endif
 
-warning_c_flags = [
-  '-Wmissing-prototypes',
-  '-Wdeclaration-after-statement',
-  '-Wold-style-definition',
-]
+  if subproj.found()
+    plugins = subproj.get_variable('gst_plugins', [])
+    legacy_plugins = subproj.get_variable('plugins', [])
+    all_plugins += plugins
+    if plugins.length() == 0 and legacy_plugins.length() > 0
+      warning(f'DEPRECATED use of the `plugins` variable in @project_name@.')
+      warning('The variable should now be called `gst_plugins` and use:')
+      warning('`declare_dependency( link_with: <plugin_target>, variable: {\'full_path\': <plugin_target>.full_path()})` instead')
+      foreach plugin: legacy_plugins
+        all_plugins += [declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})]
+      endforeach
+    endif
 
-warning_cxx_flags = [
-  '-Wformat-nonliteral',
-]
+    all_libraries += subproj.get_variable('gst_libraries', [])
+    if not get_option('tools').disabled()
+      all_tools += subproj.get_variable('gst_tools', {})
+    endif
 
-foreach extra_arg : warning_c_flags
-  if cc.has_argument (extra_arg)
-    add_project_arguments([extra_arg], language: 'c')
-  endif
-endforeach
+    orc_update_targets += subproj.get_variable('orc_update_targets', [])
 
-foreach extra_arg : warning_cxx_flags
-  if cxx.has_argument (extra_arg)
-    add_project_arguments([extra_arg], language: 'cpp')
-  endif
-endforeach
+    subprojects_names += [project_name]
 
-foreach extra_arg : warning_flags
-  if cc.has_argument (extra_arg)
-    add_project_arguments([extra_arg], language: 'c')
-  endif
-  if cxx.has_argument (extra_arg)
-    add_project_arguments([extra_arg], language: 'cpp')
+    if not meson.is_cross_build() and build_infos.get('build-hotdoc', false)
+      plugins_doc_caches += [subproj.get_variable('gst_plugins_doc_dep', [])]
+      if documented_projects != ''
+        documented_projects += ','
+      endif
+      documented_projects  += project_name
+    endif
   endif
 endforeach
 
-# GStreamer package name and origin url
-gst_package_name = get_option('package-name')
-if gst_package_name == ''
-  if gst_version_nano == 0
-    gst_package_name = 'GStreamer Bad Plug-ins source release'
-  elif gst_version_nano == 1
-    gst_package_name = 'GStreamer Bad Plug-ins git'
-  else
-    gst_package_name = 'GStreamer Bad Plug-ins prerelease'
+# Check if we need to also build glib-networking for TLS modules
+giomodules = []
+glib_dep = dependency('glib-2.0')
+if glib_dep.type_name() == 'internal'
+  subp = subproject('glib-networking', required : get_option('tls'),
+             default_options: ['gnutls=auto', 'openssl=auto'])
+  if subp.found()
+    giomodules += subp.get_variable('giomodules', [])
   endif
 endif
-cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
-cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
-
-# FIXME: This should be exposed as a configuration option
-if host_system == 'linux'
-  cdata.set_quoted('DEFAULT_VIDEOSRC', 'v4l2src')
-elif ['darwin', 'ios'].contains(host_system)
-  cdata.set_quoted('DEFAULT_VIDEOSRC', 'avfvideosrc')
-  cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
-  # Yes, we set this for iOS too. Same as Autotools.
-  cdata.set('HAVE_OSX', 1)
-else
-  cdata.set_quoted('DEFAULT_VIDEOSRC', 'videotestsrc')
-endif
 
-# Mandatory GST deps
-gst_dep = dependency('gstreamer-1.0', version : gst_req,
-  fallback : ['gstreamer', 'gst_dep'])
-gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
-  fallback : ['gstreamer', 'gst_base_dep'])
-gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
-  fallback : ['gstreamer', 'gst_net_dep'])
-gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
-  fallback : ['gstreamer', 'gst_controller_dep'])
-
-gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
-    fallback : ['gst-plugins-base', 'pbutils_dep'])
-gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
-    fallback : ['gst-plugins-base', 'allocators_dep'])
-gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
-    fallback : ['gst-plugins-base', 'app_dep'])
-gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
-    fallback : ['gst-plugins-base', 'audio_dep'])
-gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
-    fallback : ['gst-plugins-base', 'fft_dep'])
-gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
-    fallback : ['gst-plugins-base', 'riff_dep'])
-gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
-    fallback : ['gst-plugins-base', 'rtp_dep'])
-gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
-    fallback : ['gst-plugins-base', 'rtsp_dep'])
-gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
-    fallback : ['gst-plugins-base', 'sdp_dep'])
-gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
-    fallback : ['gst-plugins-base', 'tag_dep'])
-gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
-    fallback : ['gst-plugins-base', 'video_dep'])
-gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
-    required : get_option('tests'),
-    fallback : ['gstreamer', 'gst_check_dep'])
-
-# GStreamer OpenGL
-gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
-    fallback : ['gst-plugins-base', 'gstgl_dep'], required: get_option('gl'))
-gstglproto_dep = dependency('gstreamer-gl-prototypes-1.0', version : gst_req,
-    fallback : ['gst-plugins-base', 'gstglproto_dep'], required: get_option('gl'))
-gstglx11_dep = dependency('', required : false)
-gstglwayland_dep = dependency('', required : false)
-gstglegl_dep = dependency('', required : false)
-
-if gstgl_dep.found()
-  if gstgl_dep.type_name() == 'pkgconfig'
-    gst_gl_apis = gstgl_dep.get_pkgconfig_variable('gl_apis').split()
-    gst_gl_winsys = gstgl_dep.get_pkgconfig_variable('gl_winsys').split()
-    gst_gl_platforms = gstgl_dep.get_pkgconfig_variable('gl_platforms').split()
-  else
-    gstbase = subproject('gst-plugins-base')
-    gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
-    gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
-    gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
+gst_plugins_doc_dep = custom_target('plugins-doc-cache',
+  command: [python3, '-c', 'print("Built all doc caches")'],
+  input: plugins_doc_caches,
+  output: 'plugins_doc_caches',
+  capture: true,
+)
+
+if meson.is_cross_build() or build_machine.system() == 'windows'
+    if get_option('doc').enabled()
+        error('Documentation enabled but building the doc while cross building or building on windows is not supported yet.')
+    endif
+
+    documented_projects = ''
+    message('Documentation not built as building the documentation while cross building or building on windows is not supported yet.')
+else
+  hotdoc_p = find_program('hotdoc', required : get_option('doc'))
+  if not hotdoc_p.found()
+    documented_projects = ''
+    message('Not building documentation as hotdoc was not found')
   endif
+endif
 
-  message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
-  message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
-  message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
+write_file_contents = '''
+import os
+import sys
 
-  foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
-    set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
-  endforeach
+assert len(sys.argv) >= 3
+fname = sys.argv[1]
+contents = sys.argv[2]
 
-  foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
-    set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
-  endforeach
+with open(fname, 'w') as f:
+    f.write(contents)
+'''
 
-  foreach api : ['gl', 'gles2']
-    set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
-  endforeach
+configure_file(
+  output : 'GstDocumentedSubprojects',
+  command : [python3,
+             '-c', write_file_contents,
+             '@OUTPUT@',
+             documented_projects]
+)
 
-  # Behind specific checks because meson fails at optional dependencies with a
-  # fallback to the same subproject.  On the first failure, meson will never
-  # check the system again even if the fallback never existed.
-  # Last checked with meson 0.54.3
-  if gst_gl_have_window_x11
-    gstglx11_dep = dependency('gstreamer-gl-x11-1.0', version : gst_req,
-        fallback : ['gst-plugins-base', 'gstglx11_dep'], required: true)
-  endif
-  if gst_gl_have_window_wayland
-    gstglwayland_dep = dependency('gstreamer-gl-wayland-1.0', version : gst_req,
-        fallback : ['gst-plugins-base', 'gstglwayland_dep'], required: true)
-  endif
-  if gst_gl_have_platform_egl
-    gstglegl_dep = dependency('gstreamer-gl-egl-1.0', version : gst_req,
-        fallback : ['gst-plugins-base', 'gstglegl_dep'], required: true)
+if documented_projects != ''
+  gst_doc = subproject('gst-docs', required: get_option('doc').enabled())
+  if gst_doc.found()
+    gst_doc_target = gst_doc.get_variable('gstreamer_doc')
+    alias_target('gst-doc', gst_doc_target)
   endif
+  message('Gst docs subprojects: ' + documented_projects)
 endif
 
-libm = cc.find_library('m', required : false)
-glib_dep = dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep'])
-gmodule_dep = dependency('gmodule-2.0', fallback: ['glib', 'libgmodule_dep'])
-gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
-# gio-unix-2.0 is used by sys/bluez
+all_plugins_paths = []
+all_plugins_dirs = []
+plugins_names = []
+foreach plugin: all_plugins
+  plugin_path = plugin.get_variable('full_path')
+  all_plugins_paths += plugin_path
+  all_plugins_dirs += fs.parent(plugin_path)
+  plugins_names += fs.name(plugin_path)
+endforeach
 
-# Optional dep of ext/gl and gst/librfb
-x11_dep = dependency('x11', required : get_option('x11'))
-if x11_dep.found()
-  cdata.set('HAVE_X11', 1)
-endif
+# Work around meson bug: https://github.com/mesonbuild/meson/pull/6770
+pathsep = host_machine.system() == 'windows' ? ';' : ':'
+all_plugins_paths = pathsep.join(all_plugins_paths)
 
-if host_machine.system() == 'windows'
-  winsock2 = [cc.find_library('ws2_32')]
+devenv = environment()
+if not building_full
+  devenv.prepend('GST_PLUGIN_PATH', all_plugins_dirs)
 else
-  winsock2 = []
+  # Make sure the current build directory is first in PATH so we prefer tools
+  # built here that links on gst-full instead instead of those built in
+  # subprojects.
+  devenv.prepend('PATH', meson.current_build_dir())
 endif
+devenv.set('CURRENT_GST', meson.current_source_dir())
+devenv.set('GST_VERSION', meson.project_version())
+devenv.set('GST_ENV', 'gst-' + meson.project_version())
+devenv.set('GST_REGISTRY', meson.current_build_dir() / 'registry.dat')
+devenv.set('GST_PLUGIN_SYSTEM_PATH', '')
+meson.add_devenv(devenv)
+
+generate_plugins_paths = find_program('scripts/generate_plugins_path.py')
+configure_file(
+  output : 'GstPluginsPath.json',
+  command : [generate_plugins_paths,
+             '@OUTPUT@',
+             all_plugins_paths]
+)
 
-if ['darwin', 'ios'].contains(host_system)
-  if not have_objc
-    error('Building on MacOS/iOS/etc requires an ObjC compiler')
-  endif
-  if host_system == 'ios'
-    cdata.set('HAVE_IOS', 1)
+if building_full
+  cdata = configuration_data()
+  cdata.set_quoted('GST_API_VERSION', apiversion)
+  cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-full-1.0')
+  cdata.set_quoted('PACKAGE_VERSION', gst_version)
+  cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
+  configure_file(output : 'config.h', configuration : cdata)
+  configinc = include_directories('.')
+  gst_c_args = ['-DHAVE_CONFIG_H']
+
+  # Generate a .c file which declare and register all built plugins
+  all_plugin_names = ';'.join(plugins_names)
+
+  static_plugins = get_option('gst-full-plugins')
+  if static_plugins == '*'
+    static_plugins = all_plugin_names
   endif
+  generate_init_static_plugins = find_program('scripts/generate_init_static_plugins.py')
+  init_static_plugins_c = configure_file(
+    output: 'gstinitstaticplugins.c',
+    command : [generate_init_static_plugins,
+               '-o ' + '@OUTPUT@',
+               '-p ' + static_plugins,
+               '-e ' + get_option('gst-full-elements'),
+               '-t ' + get_option('gst-full-typefind-functions'),
+               '-d ' + get_option('gst-full-device-providers'),
+               '-T ' + get_option('gst-full-dynamic-types'),
+               '--giomodules', ';'.join(giomodules),
+               ]
+  )
+
+  gstfull_link_args = cc.get_supported_link_arguments(['-Wl,-Bsymbolic-functions'])
+
+  # Get a list of libraries that needs to be exposed in the ABI.
+  exposed_libs = []
+  exposed_deps = []
+  exposed_girs = []
+  incdir_deps = []
+  wanted_libs = ['gstreamer-1.0'] + get_option('gst-full-libraries')
+  all_libs = '*' in wanted_libs
+
+  foreach pkgname_library : all_libraries
+    pkg_name = pkgname_library[0]
+    lib_def = pkgname_library[1]
+
+    if pkg_name in wanted_libs or all_libs
+      if lib_def.has_key('lib')
+        exposed_deps += dependency(pkg_name)
+        incdir_deps += dependency(pkg_name).partial_dependency(includes: true, sources: true)
+        exposed_libs += [lib_def['lib']]
+      endif
+
+      if lib_def.has_key('gir')
+        exposed_girs += lib_def['gir']
+      endif
+    endif
+  endforeach
 
-  avfoundation_dep = dependency('AVFoundation', required : false)
-  if avfoundation_dep.found()
-      cdata.set('HAVE_AVFOUNDATION', 1)
+  # glib and gobject are part of our public API. If we are using glib from the
+  # system then our pkg-config file must require it. If we built it as
+  # subproject then we need to link_whole it.
+  glib_deps = []
+  glib_dep = dependency('glib-2.0')
+  gobject_dep = dependency('gobject-2.0')
+  if gobject_dep.type_name() == 'internal'
+    glib_subproject = subproject('glib')
+    exposed_libs += glib_subproject.get_variable('libglib')
+    exposed_libs += glib_subproject.get_variable('libgobject')
+    incdir_deps += [
+      glib_dep.partial_dependency(includes: true),
+      gobject_dep.partial_dependency(includes: true),
+    ]
+  else
+    glib_deps = [glib_dep, gobject_dep]
   endif
 
-  videotoolbox_dep = dependency('VideoToolbox', required : false)
-  if videotoolbox_dep.found()
-      cdata.set('HAVE_VIDEOTOOLBOX', 1)
+  link_deps = []
+  if get_option('gst-full-version-script') != ''
+    symbol_map = meson.current_source_dir() / get_option('gst-full-version-script')
+    link_arg = '-Wl,--version-script=' + symbol_map
+    if cc.has_link_argument(link_arg)
+      gstfull_link_args += link_arg
+      link_deps += symbol_map
+    elif cc.get_id() == 'msvc'
+      warning('FIXME: Provide a def file to publish the public symbols')
+    else
+      warning('FIXME: Linker does not support the supplied version script (' + symbol_map + '), please disable the "gst-full-version-script" option')
+    endif
   endif
 
-#  FIXME: framework.version() returns 'unknown'
-#  if videotoolbox_dep.version().version_compare('>=10.9.6')
-#    cdata.set('HAVE_VIDEOTOOLBOX_10_9_6', 1)
-#  endif
-endif
-
-have_orcc = false
-orcc_args = []
-orc_targets = []
-# Used by various libraries/elements that use Orc code
-orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
-    fallback : ['orc', 'orc_dep'])
-orcc = find_program('orcc', required : get_option('orc'))
-if orc_dep.found() and orcc.found()
-  have_orcc = true
-  orcc_args = [orcc, '--include', 'glib.h']
-  cdata.set('HAVE_ORC', 1)
-else
-  message('Orc Compiler not found or disabled, will use backup C code')
-  cdata.set('DISABLE_ORC', 1)
-endif
-cdata.set('GST_ENABLE_EXTRA_CHECKS', not get_option('extra-checks').disabled())
-
-gnustl_dep = declare_dependency()
-if host_system == 'android'
-  gnustl_dep = dependency('gnustl', required : false)
-endif
+  giomodules_deps = []
+  foreach module : giomodules
+    giomodules_deps += dependency(module)
+  endforeach
 
-# Disable compiler warnings for unused variables and args if gst debug system is disabled
-if gst_dep.type_name() == 'internal'
-  gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
-else
-  # We can't check that in the case of subprojects as we won't
-  # be able to build against an internal dependency (which is not built yet)
-  gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
-endif
+  # Build both shared and static library
+  gstfull = both_libraries('gstreamer-full-1.0',
+    init_static_plugins_c,
+    link_args: gstfull_link_args,
+    link_whole : exposed_libs,
+    dependencies : [incdir_deps, glib_deps, all_plugins, giomodules_deps],
+    link_depends : link_deps,
+    install : true,
+  )
+
+  gst_full_dep = declare_dependency(link_with: gstfull.get_shared_lib(),
+    dependencies : incdir_deps + glib_deps,
+    include_directories: include_directories('.')
+  )
+
+  gst_full_libs_private = cc.get_supported_link_arguments(['-Wl,--undefined=gst_init_static_plugins'])
+  if gst_full_libs_private == []
+    warning('The compiler does not support `-Wl,--undefined` linker flag. The method `gst_init_static_plugins` might be dropped during the link stage of an application using libgstreamer-full-1.0.a, preventing plugins registration.')
+  endif
 
-if gst_debug_disabled
-  message('GStreamer debug system is disabled')
-  if cc.has_argument('-Wno-unused')
-    add_project_arguments('-Wno-unused', language: 'c')
+  if not get_option('introspection').disabled()
+    built_girs = {}
+    foreach gir: exposed_girs
+      includes = []
+      foreach include: gir.get('includes', [])
+        includes += [built_girs.get(include, include)]
+      endforeach
+
+      gir += {
+        'includes': includes,
+        'extra_args': gir.get('extra_args', []) + ['--add-include-path=' + meson.current_build_dir()],
+        'install': true,
+      }
+      built_girs += {gir.get('namespace') + '-' + gir.get('nsversion'): gnome.generate_gir(gstfull, kwargs: gir)[0]}
+    endforeach
   endif
-  if cxx.has_argument ('-Wno-unused')
-    add_project_arguments('-Wno-unused', language: 'cpp')
+
+  pkgconfig.generate(gstfull,
+    requires: glib_deps,
+    libraries_private: gst_full_libs_private,
+    subdirs : 'gstreamer-1.0')
+  meson.override_dependency('gstreamer-full-1.0', gst_full_dep)
+
+  if not get_option('tools').disabled()
+    foreach tool, data: all_tools
+      exe_name = '@0@-@1@'.format(tool, apiversion)
+      extra_args = data.get('extra_c_args', [])
+      sources = data.get('files')
+      install_tag = data.get('install_tag', 'bin')
+      deps = []
+      foreach d : data.get('deps', [])
+        if d not in exposed_deps
+          deps += d
+        endif
+      endforeach
+
+      executable(exe_name,
+        sources,
+        install: true,
+        install_tag: install_tag,
+        include_directories : [configinc],
+        dependencies : [gst_full_dep] + deps,
+        c_args: extra_args + gst_c_args + ['-DG_LOG_DOMAIN="@0@"'.format(exe_name)],
+      )
+
+      if data.has_key('man_page')
+        install_man(data.get('man_page'))
+      endif
+
+    endforeach
   endif
-else
-  message('GStreamer debug system is enabled')
 endif
 
-gst_plugins_bad_args = ['-DHAVE_CONFIG_H']
-configinc = include_directories('.')
-libsinc = include_directories('gst-libs')
+message('Building subprojects: ' + ', '.join(subprojects_names))
 
-python3 = import('python').find_installation()
-
-gir = find_program('g-ir-scanner', required : get_option('introspection'))
-gnome = import('gnome')
-build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
-gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
-    'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
-    'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
-    'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
-    'gst_init(NULL,NULL);', '--quiet']
+setenv = find_program('gst-env.py')
 
-presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
+devenv_cmd = [setenv, '--builddir=@0@'.format(meson.global_build_root()),
+              '--srcdir=@0@'.format(meson.global_source_root())]
 
-pkgconfig = import('pkgconfig')
-plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
-if get_option('default_library') == 'shared'
-  # If we don't build static plugins there is no need to generate pc files
-  plugins_pkgconfig_install_dir = disabler()
-endif
-
-pkgconfig_variables = ['exec_prefix=${prefix}',
-    'toolsdir=${exec_prefix}/bin',
-    'pluginsdir=${libdir}/gstreamer-1.0',
-    'datarootdir=${prefix}/share',
-    'datadir=${datarootdir}',
-    'girdir=${datadir}/gir-1.0',
-    'typelibdir=${libdir}/girepository-1.0']
-
-pkgconfig_subdirs = ['gstreamer-1.0']
-
-pkgconfig.generate(
-  libraries : [gst_dep],
-  variables : pkgconfig_variables,
-  subdirs : pkgconfig_subdirs,
-  name : 'gstreamer-plugins-bad-1.0',
-  description : 'Streaming media framework, bad plugins libraries',
-)
-
-subdir('gst-libs')
-subdir('gst')
-subdir('sys')
-subdir('ext')
 subdir('tests')
-subdir('data')
-subdir('tools')
-
-if have_orcc
-  update_orc_dist_files = find_program('scripts/update-orc-dist-files.py')
-
-  orc_update_targets = []
-  foreach t : orc_targets
-    orc_name = t.get('name')
-    orc_file = t.get('orc-source')
-    header = t.get('header')
-    source = t.get('source')
-    # alias_target() only works with build targets, so can't use run_target() here
-    orc_update_targets += [
-      custom_target('update-orc-@0@'.format(orc_name),
-        input: [header, source],
-        command: [update_orc_dist_files, orc_file, header, source],
-        output: ['@0@-dist.c'.format(orc_name)]) # not entirely true
-    ]
-  endforeach
-
-  if meson.version().version_compare('>= 0.52') and orc_update_targets.length() > 0
-    update_orc_dist_target = alias_target('update-orc-dist', orc_update_targets)
+subdir('ci/fuzzing')
+
+if meson.can_run_host_binaries() and build_machine.system() == 'linux' and host_machine.system() == 'windows'
+  # FIXME: Ideally we could get the wrapper directly from meson
+  devenv_cmd += ['--wine', host_machine.cpu_family() == 'x86_64' ? 'wine64' : 'wine32']
+  sysroot = meson.get_cross_property('sys_root')
+  if sysroot != ''
+    # Logic from meson
+    devenv_cmd += ['--winepath', 'Z:' + join_paths(sysroot, 'bin')]
   endif
 endif
 
-# xgettext is optional (on Windows for instance)
-if find_program('xgettext', required : get_option('nls')).found()
-  cdata.set('ENABLE_NLS', 1)
-  subdir('po')
+run_target('devenv', command : devenv_cmd)
+
+if orc_subproject.found() and orc_update_targets.length() > 0
+  alias_target('update-orc-dist', orc_update_targets)
 endif
 
 subdir('scripts')
 
-# Set release date
-if gst_version_nano == 0
-  extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
-  run_result = run_command(extract_release_date, gst_version, files('gst-plugins-bad.doap'))
-  if run_result.returncode() == 0
-    release_date = run_result.stdout().strip()
-    cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
-    message('Package release date: ' + release_date)
-  else
-    # Error out if our release can't be found in the .doap file
-    error(run_result.stderr())
-  endif
-endif
-
-if glib_dep.version().version_compare('< 2.67.4')
-  cdata.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
+dotnet_format = find_program('dotnet-format', required: false)
+if dotnet_format.found()
+    run_target('csharp_format_check',
+        command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
+            '--check'
+        ],
+    )
+    run_target('csharp_format_apply',
+        command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
+        ],
+    )
 endif
 
-configure_file(output : 'config.h', configuration : cdata)
+summary({
+  'gstreamer-full library': building_full,
+}, section: 'Build options', bool_yn: true, list_sep: '  ')
 
-run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
-
-subdir('docs')
+gst_tools = []
+foreach tool, data: all_tools
+  gst_tools += tool
+endforeach
 
-if meson.version().version_compare('>= 0.54')
-  plugin_names = []
-  foreach plugin: plugins
-    # FIXME: Use str.subtring() when we can depend on Meson 0.56
-    split = plugin.name().split('gst')
-    if split.length() == 2
-      plugin_names += [split[1]]
-    else
-      warning('Need substring API in meson >= 0.56 to properly parse plugin name: ' + plugin.name())
-      plugin_names += [plugin.name()]
-    endif
-  endforeach
-  summary({'Plugins':plugin_names}, list_sep: ', ')
-endif
+summary({
+    'Tools': gst_tools,
+}, section: 'Build options', list_sep: ', ')