libds_tizen_files = [
  'pixel_format.c',
  'tbm_server.c',
  'dpms.c',
]

math = meson.get_compiler('c').find_library('m')
wayland_server = dependency('wayland-server', required: true)
pixman = dependency('pixman-1', required: true)
libdrm = dependency('libdrm', required: true)
xkbcommon = dependency('xkbcommon', required: true)
rt = meson.get_compiler('c').find_library('rt')

if wayland_server.version().version_compare('>= 1.19')
  cdata.set('HAVE_WL_SEAT_ERROR_MISSING_CAPABILITY', '1')
endif

base_deps = [
  math,
  wayland_server,
  pixman,
  libdrm,
  xkbcommon,
  rt,
]

libds_tizen_deps = [
  base_deps,
  dependency('libds', required: true),
  dependency('libdrm', required: true),
  dependency('libtbm', required: true),
  dependency('wayland-tbm-server', required: true),
  dependency('tizen-dpms-server', required: true),
]

subdir('allocator')
subdir('backend')
subdir('util')

lib_libds_tizen = shared_library('ds-tizen', libds_tizen_files,
  dependencies: libds_tizen_deps,
  include_directories: [ common_inc, include_directories('.') ],
  version: meson.project_version(),
  install: true
)

dep_libds_tizen = declare_dependency(
  link_with: lib_libds_tizen,
  dependencies: libds_tizen_deps,
  include_directories: [ common_inc, include_directories('.') ],
)

pkgconfig = import('pkgconfig')
pkgconfig.generate(lib_libds_tizen,
  version: meson.project_version(),
  filebase: 'libds-tizen',
  name: 'libds-tizen',
  description: 'extension of libds for tizen platform',
)

subdir('keyrouter')
#subdir('input-devicemgr')