libds_tizen_keyrouter_files = [
  tizen_security_files,
  'keyrouter_grab.c',
  'keyrouter.c',
]

libds_tizen_keyrouter_deps = [
  deps_libds_tizen,
  deps_tizen_security,
  dependency('tizen-extension-server', required: true),
]

keylayout_dir = get_option('keylayout_dir')

lib_libds_tizen_keyrouter = shared_library('ds-tizen-keyrouter', libds_tizen_keyrouter_files,
  dependencies: libds_tizen_keyrouter_deps,
  include_directories: [ common_inc, include_directories('.'), include_directories('..') ],
  version: meson.project_version(),
  c_args: [ '-DKEYLAYOUT_DIR="@0@"'.format(keylayout_dir) ],
  install: true
)

deps_libds_tizen_keyrouter = declare_dependency(
  link_with: lib_libds_tizen_keyrouter,
  dependencies: libds_tizen_keyrouter_deps,
  include_directories: [ common_inc, include_directories('.') ],
)

pkgconfig = import('pkgconfig')
pkgconfig.generate(lib_libds_tizen_keyrouter,
  version: meson.project_version(),
  filebase: 'libds-tizen-keyrouter',
  name: 'libds-tizen-keyrouter',
  description: 'tizen keyrouter extension of libds-tizen for tizen platform',
)