####### System-popup #############
CMAKE_MINIMUM_REQUIRED(VERSION 2.6)

SET(TABLE_PATH ${CMAKE_SOURCE_DIR}/edcs/table)

#common module
SET(SRCS ${COMMON_SRCS})

IF(PROFILE_WEARABLE)
	SET(SRCS ${SRCS} battery/battery-wearable.c)
	SET(SRCS ${SRCS} storage/lowstorage-wearable.c)
	SET(SRCS ${SRCS} cooldown/cooldown-wearable.c)
	SET(SRCS ${SRCS} power/power.c)
ELSEIF(PROFILE_MOBILE OR PROFILE_COMMON)
	IF(PROFILE STREQUAL mobile)
		SET(SRCS ${SRCS} battery/battery-mobile.c)
	ENDIF()
	SET(SRCS ${SRCS} storage/lowstorage-mobile.c)
	SET(SRCS ${SRCS} cooldown/cooldown-mobile.c)
	SET(SRCS ${SRCS} mmc/mmc-mobile.c)
	SET(SRCS ${SRCS}
		usb/usb-mobile.c
		usb/usbotg-mobile.c
		usb/usb-device.c
	)
	SET(SRCS ${SRCS} power/power.c)
ENDIF()


INCLUDE_DIRECTORIES(${CMAKE_SOURCE_DIR})
INCLUDE_DIRECTORIES(${CMAKE_SOURCE_DIR}/src/common)

SET(VENDOR "tizen")
SET(PACKAGE "system-syspopup")
SET(PKGNAME "org.${VENDOR}.${PACKAGE}")
SET(PREFIX "${CMAKE_INSTALL_PREFIX}/apps/${PKGNAME}")
SET(BINDIR "${PREFIX}/bin")
SET(RESDIR "${PREFIX}/res")
SET(MANIFESTDIR "${CMAKE_INSTALL_PREFIX}/share/packages")
SET(SYSTEM_RES "${TZ_SYS_RO_APP}/${PKGNAME}/shared/res")

SET(PKG_MODULES
		appcore-efl
		bundle
		dlog
		ecore
		evas
		syspopup
		vconf
		elementary
		deviced
		feedback
		efl-extension
		appsvc
		edbus
		capi-appfw-application
		capi-appfw-app-manager
		pkgmgr-info
)

INCLUDE(FindPkgConfig)
pkg_check_modules(system_pkgs REQUIRED ${PKG_MODULES})

FOREACH(flag ${system_pkgs_CFLAGS})
	SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} ${flag}")
ENDFOREACH(flag)

SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${EXTRA_CFLAGS} -O2 -g -Wall -fpie")

ADD_DEFINITIONS("-DPACKAGE=\"${PACKAGE}\"")
ADD_DEFINITIONS("-DLOCALEDIR=\"${LOCALEDIR}\"")
ADD_DEFINITIONS("-DRESDIR=\"${RESDIR}\"")
ADD_DEFINITIONS("-DSYSTEM_RES=\"${SYSTEM_RES}\"")
#USB POPUP
IF(PROFILE_MOBILE OR PROFILE_COMMON)
	ADD_DEFINITIONS("-DELM_USB_EDC=\"${SYSTEM_RES}/usb-popup.edj\"")
ENDIF()
#COOLDOWN POPUP
IF(PROFILE_WEARABLE)
	ADD_DEFINITIONS("-DELM_COOLDOWN_EDC=\"${SYSTEM_RES}/cooldown-popup.edj\"")
ENDIF()

SET(CMAKE_EXE_LINKER_FLAGS "-Wl,--as-needed -pie")

ADD_EXECUTABLE(${PACKAGE} ${SRCS})

TARGET_LINK_LIBRARIES(${PACKAGE} syspopup ${system_pkgs_LDFLAGS})

INSTALL(TARGETS ${PACKAGE} DESTINATION ${BINDIR})

#USB POPUP
IF(PROFILE_MOBILE OR PROFILE_COMMON)
	ADD_CUSTOM_TARGET(usb-popup.edj
		COMMAND edje_cc -no-save ${CMAKE_SOURCE_DIR}/src/usb/usb-popup.edc ${CMAKE_BINARY_DIR}/usb-popup.edj
		DEPENDS ${CMAKE_SOURCE_DIR}/src/usb/usb-popup.edc
		COMMENT "making usb popup edj file"
	)
	ADD_DEPENDENCIES(${PACKAGE} usb-popup.edj)
	INSTALL(FILES ${CMAKE_BINARY_DIR}/usb-popup.edj DESTINATION ${SYSTEM_RES})
ENDIF()

#COOLDOWN POPUP
IF(PROFILE_WEARABLE)
	ADD_CUSTOM_TARGET(cooldown-popup.edj
		COMMAND edje_cc -no-save ${CMAKE_SOURCE_DIR}/src/cooldown/cooldown-popup.edc ${CMAKE_BINARY_DIR}/cooldown-popup.edj
		DEPENDS ${CMAKE_SOURCE_DIR}/src/cooldown/cooldown-popup.edc
		COMMENT "making cooldown popup edj file"
	)
	ADD_DEPENDENCIES(${PACKAGE} cooldown-popup.edj)
	INSTALL(FILES ${CMAKE_BINARY_DIR}/cooldown-popup.edj DESTINATION ${SYSTEM_RES})
ENDIF()

IF(PROFILE STREQUAL wearable)
	INSTALL(FILES ${CMAKE_SOURCE_DIR}/data/overheat.png DESTINATION ${RESDIR})
ENDIF()

# install manifest file
INSTALL(FILES ${CMAKE_SOURCE_DIR}/src/${PKGNAME}.xml DESTINATION ${MANIFESTDIR})
############## END ##############