AC_PREREQ(2.60)
AC_INIT([dbuspolicy],
        [1.1.0],
        [dev@lists.tizen.org],
        [dbuspolicy],
        [http://review.tizen.org])
AC_CONFIG_SRCDIR([src/libdbuspolicy1.cpp])
AC_CONFIG_AUX_DIR([build-aux])
AM_INIT_AUTOMAKE([
	check-news
	foreign
	1.11
	-Wall
	-Wno-portability
	silent-rules
	tar-pax
	no-dist-gzip
	dist-xz
	subdir-objects
])
AC_PROG_CC_STDC
AC_PROG_CXX
AC_USE_SYSTEM_EXTENSIONS
AC_SYS_LARGEFILE
AC_CONFIG_MACRO_DIR([m4])
AM_SILENT_RULES([yes])
LT_INIT([
	disable-static
	pic-only
])
AC_PREFIX_DEFAULT([/usr])

AC_PROG_SED
AC_PROG_MKDIR_P

AC_ARG_ENABLE([logging],
        AS_HELP_STRING([--disable-logging], [disable system logging @<:@default=enabled@:>@]),
        [], enable_logging=yes)
AS_IF([test "x$enable_logging" = "xyes"], [
        AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
])

AC_ARG_ENABLE([debug],
        AS_HELP_STRING([--enable-debug], [enable debug messages @<:@default=disabled@:>@]),
        [], [enable_debug=no])
AS_IF([test "x$enable_debug" = "xyes"], [
        AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
])

AC_ARG_ENABLE(tests, AS_HELP_STRING([--enable-tests], [Add API function that allows to change credentials during execution]),
					 [with_tests=yes],
					 with_tests=no)
AM_CONDITIONAL([ENABLE_STANDALONE_TESTS], [test x$with_tests = xyes])
if test "x$with_tests" = "xyes"; then
   AC_DEFINE(LIBDBUSPOLICY_TESTS_API, 1, [Define if tests are enabled])
fi


AC_ARG_ENABLE([doxygen],
        AS_HELP_STRING([--enable-doxygen], [enable doxygen documentation @<:@default=disabled@:>@]),
        [], [enable_doxygen=no])
AM_CONDITIONAL([ENABLE_DOXYGEN], [test x$enable_doxygen = xyes])
AS_IF([test "x$enable_doxygen" = "xyes"], [
	AC_CHECK_PROGS([DOXYGEN], [doxygen])
	if test -z "$DOXYGEN"
		then AC_MSG_ERROR([Doxygen not found!])
		enable_doxygen=no
	fi
])

AC_CHECK_FUNCS([ \
	__secure_getenv \
	secure_getenv\
])

my_CFLAGS="\
-Wall \
-Wextra \
-Werror \
"
AC_SUBST([my_CFLAGS])

my_CXXFLAGS="\
-Wall \
-Wextra \
-Werror \
-std=c++14 \
"

AC_SUBST([my_CXXFLAGS])
PKG_CHECK_MODULES([CYNARA], [cynara-client >= 0.4.2 cynara-session >= 0.4.2],
     [AC_DEFINE([ENABLE_CYNARA], [1], [Define to enable Cynara privilege checks in libdbuspolicy])],
     [AC_MSG_ERROR([libcynara-client-async and cynara-session are required to enable Cynara integration])])
PKG_CHECK_MODULES([DLOG], [dlog])

AC_SUBST([CYNARA_CFLAGS])
AC_SUBST([CYNARA_LIBS])

AC_SUBST([DLOG_CFLAGS])
AC_SUBST([DLOG_LIBS])

AC_CONFIG_HEADERS(config.h)
AC_CONFIG_FILES([
        Makefile
])

AC_OUTPUT
AC_MSG_RESULT([
        $PACKAGE $VERSION
        =====

        prefix:                 ${prefix}
        sysconfdir:             ${sysconfdir}
        libdir:                 ${libdir}
        includedir:             ${includedir}

        compiler:               ${CC}
        cflags:                 ${CFLAGS} ${CYNARA_CFLAGS}
        ldflags:                ${LDFLAGS} ${CYMARA_LIBS}

        logging:                ${enable_logging}
        debug:                  ${enable_debug}
	doxygen:		${enable_doxygen}
])