wayland_tbm_client = dependency('wayland-tbm-client', required: false)
libtbm = dependency('libtbm', required: false)
tizen_extension_client = dependency('tizen-extension-client', required: true)

if not wayland_tbm_client.found() or not libtbm.found()
  subdir_done()
endif

simple_tbm_files = ['simple-tbm.c']
simple_tbm_deps = [
  dependency('wayland-client', required: true),
  wayland_tbm_client,
  libtbm,
  tizen_extension_client,
]

protocols = {
  'xdg-shell': wl_protocol_dir / 'stable/xdg-shell/xdg-shell.xml',
}

protocols_code = {}
protocols_client_header = {}
foreach name, path : protocols
  code = custom_target(
    name.underscorify() + '_c',
    input: path,
    output: '@BASENAME@-protocol.c',
    command: [wayland_scanner, 'private-code', '@INPUT@', '@OUTPUT@'],
    )
  simple_tbm_files += code

  client_header = custom_target(
    name.underscorify() + '_client_h',
    input: path,
    output: '@BASENAME@-client-protocol.h',
    command: [wayland_scanner, 'client-header', '@INPUT@', '@OUTPUT@'],
    build_by_default: false,
  )
  simple_tbm_files += client_header
endforeach

executable('ds-simple-tbm',
  simple_tbm_files,
  dependencies: [simple_tbm_deps,
  deps_libds_tizen_text_input,
  ],
  install_dir: libds_tizen_bindir,
  install: true,
)

executable('ds-simple-dpms',
  'simple-dpms.c',
  dependencies: [
      dependency('wayland-client', required: true),
      dependency('tizen-dpms-client', required: true),
    ],
  install_dir: libds_tizen_bindir,
  install: true,
)

input_generator_files = ['input-generator.c']
input_generator_deps = [
  dependency('wayland-client', required: true),
  tizen_extension_client,
]

executable('input-generator',
  input_generator_files,
  dependencies: [input_generator_deps,
  deps_libds_tizen_input_method,
  ],
  install_dir: libds_tizen_bindir,
  install: true,
)