CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
PROJECT(aul C CXX)
SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
SET(PREFIX ${CMAKE_INSTALL_PREFIX})
SET(EXEC_PREFIX "\${prefix}")
SET(VERSION ${FULLVER})

ADD_DEFINITIONS("-DSHARE_PREFIX=\"${SHARE_INSTALL_PREFIX}/aul\"")

# Set required packages
INCLUDE(FindPkgConfig)
SET(AUL-1_LIB_PKG_CHECK_MODULES
	bundle
	capi-system-info
	dlog
	gio-2.0
	glib-2.0
	iniparser
	libsmack
	libtzplatform-config
	libxml-2.0
	pkgmgr-info
	sqlite3
	storage
	ttrace
	uuid
	vconf
	xdgmime
	)
pkg_check_modules(libpkgs REQUIRED ${AUL-1_LIB_PKG_CHECK_MODULES})

FOREACH(flag ${libpkgs_CFLAGS})
	SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} ${flag}")
ENDFOREACH(flag)

pkg_check_modules(APP_LAUNCHER_DEPS glib-2.0 pkgmgr-info bundle)
FOREACH(APP_LAUNCHER_FLAGS ${APP_LAUNCHER_DEPS_CFLAGS})
	SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} ${APP_LAUNCHER_FLAGS}")
ENDFOREACH(APP_LAUNCHER_FLAGS)

# Compiler flags
INCLUDE_DIRECTORIES(${CMAKE_SOURCE_DIR}/include)
INCLUDE_DIRECTORIES(${CMAKE_SOURCE_DIR}/legacy)
INCLUDE_DIRECTORIES(${CMAKE_SOURCE_DIR}/feature)
INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR})
INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR}/aul)
INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR}/aul/api)
INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR}/aul/app_manager)
INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR}/aul/common)
INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR}/aul/socket)

SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Wl,-zdefs" )
SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -fvisibility=hidden")
SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -fpic")
SET(EXTRA_CFLAGS "${EXTRA_CFLAGS} -Werror")
SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${EXTRA_CFLAGS}")
SET(CMAKE_C_FLAGS_DEBUG "-O0 -g")
SET(CMAKE_C_FLAGS_RELEASE "-O2")

SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${EXTRA_CFLAGS} -fvisibility=hidden -std=c++14")
SET(CMAKE_CXX_FLAGS_DEBUG "-O0 -g")
SET(CMAKE_CXX_FLAGS_RELEASE "-O2")

SET(CMAKE_SKIP_BUILD_RPATH true)
# Linker flags
SET(CMAKE_EXE_LINKER_FLAGS "-Wl,--as-needed")

# aul
AUX_SOURCE_DIRECTORY(src SOURCES)
AUX_SOURCE_DIRECTORY(aul AUL_SOURCES)
AUX_SOURCE_DIRECTORY(aul/api AUL_API_SOURCES)
AUX_SOURCE_DIRECTORY(aul/app_manager AUL_APP_MANAGER_SOURCES)
AUX_SOURCE_DIRECTORY(aul/common AUL_COMMON_SOURCES)
AUX_SOURCE_DIRECTORY(aul/socket AUL_SOCKET_SOURCES)
add_library(aul SHARED
	${SOURCES}
	${AUL_SOURCES}
	${AUL_API_SOURCES}
	${AUL_APP_MANAGER_SOURCES}
	${AUL_COMMON_SOURCES}
	${AUL_SOCKET_SOURCES})
TARGET_LINK_LIBRARIES(aul ${libpkgs_LDFLAGS})
SET_TARGET_PROPERTIES(aul PROPERTIES SOVERSION ${MAJORVER})
SET_TARGET_PROPERTIES(aul PROPERTIES VERSION ${FULLVER})
INSTALL(TARGETS aul DESTINATION ${LIB_INSTALL_DIR} COMPONENT RuntimeLibraries)

# pkgconfig file
CONFIGURE_FILE(aul.pc.in aul.pc @ONLY)
CONFIGURE_FILE(feature/preexec_list.txt.in feature/preexec_list.txt @ONLY)

SET(HEADERS_LIB_AUL
	aul.h
	aul_sock.h
	aul_proc.h
	aul_rsc_mgr.h
	aul_svc.h
	aul_cmd.h
	aul_app_com.h
	aul_screen_connector.h
	aul_window.h
	aul_widget.h
	aul_job_scheduler.h
	aul_rpc_port.h
	aul_complication.h
	aul_debug_info.h
	aul_watchdog.h
	aul_svc_internal.h
	aul_key.h
	aul_comp_status.h
	aul_app_group.h
	aul_comp_info.h
	aul_comp_context.h
	aul_comp_info_internal.h
	aul_watch_control.h
	aul_comp_types.h
	aul_launcher_service.h
	aul_running_context.h
	)

# Install headers, other files
FOREACH(hfile ${HEADERS_LIB_AUL})
	INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/include/${hfile} DESTINATION include/aul)
ENDFOREACH(hfile)

SET(HEADERS_LIB_AUL_API
	aul_app_context.h
	aul_app_manager.h
	aul_app_event.h
	)
FOREACH(hfile ${HEADERS_LIB_AUL_API})
	INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/aul/api/${hfile} DESTINATION include/aul/api)
ENDFOREACH(hfile)

INSTALL(FILES ${CMAKE_CURRENT_BINARY_DIR}/aul.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig)
INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/feature/preexec_list.txt DESTINATION ${SHARE_INSTALL_PREFIX}/aul )
INSTALL(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/data/miregex DESTINATION ${SHARE_INSTALL_PREFIX}/aul )
INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/aul.conf DESTINATION /etc/dbus-1/system.d)

# tool
ADD_SUBDIRECTORY(tool)
ADD_SUBDIRECTORY(parser)