winpr/CMakeLists.txt

   1 # WinPR: Windows Portable Runtime
   2 # winpr cmake build script
   3 #
   4 # Copyright 2012 Marc-Andre Moreau <marcandre.moreau@gmail.com>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17
  18 cmake_minimum_required(VERSION 2.8)
  19
  20 project(WinPR C)
  21
  22 set(CMAKE_COLOR_MAKEFILE ON)
  23
  24 if(FREERDP_VERSION)
  25         set(FREERDP_BUILD 1)
  26 endif()
  27
  28 # Include cmake modules
  29 include(CheckIncludeFiles)
  30 include(CheckLibraryExists)
  31 include(CheckSymbolExists)
  32 include(CheckStructHasMember)
  33 include(FindPkgConfig)
  34 include(TestBigEndian)
  35
  36 # Include our extra modules
  37 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../cmake/)
  38
  39 # Check for cmake compatibility (enable/disable features)
  40 include(CheckCmakeCompat)
  41 include(FindFeature)
  42 include(AutoVersioning)
  43 include(ConfigOptions)
  44 include(ComplexLibrary)
  45 include(FeatureSummary)
  46 include(CheckCCompilerFlag)
  47 include(GNUInstallDirsWrapper)
  48 include(CMakePackageConfigHelpers)
  49
  50 # Soname versioning
  51 set(WINPR_VERSION_MAJOR "1")
  52 set(WINPR_VERSION_MINOR "1")
  53 set(WINPR_VERSION_REVISION "0")
  54 set(WINPR_VERSION "${WINPR_VERSION_MAJOR}.${WINPR_VERSION_MINOR}.${WINPR_VERSION_REVISION}")
  55 set(WINPR_VERSION_FULL "${WINPR_VERSION}")
  56 set(WINPR_API_VERSION "${WINPR_VERSION_MAJOR}")
  57
  58 if(FREERDP_BUILD)
  59         set(WINPR_VERSION_FULL ${WINPR_VERSION_FULL} PARENT_SCOPE)
  60         set(WINPR_VERSION ${WINPR_VERSION} PARENT_SCOPE)
  61 else()
  62         set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
  63
  64         if(NOT IOS AND NOT ANDROID)
  65                 find_package(Threads REQUIRED)
  66         endif()
  67
  68         # Include files
  69         if(NOT IOS)
  70                 check_include_files(fcntl.h HAVE_FCNTL_H)
  71                 check_include_files(unistd.h HAVE_UNISTD_H)
  72                 check_include_files(execinfo.h HAVE_EXECINFO_H)
  73                 check_include_files(stdint.h HAVE_STDINT_H)
  74                 check_include_files(inttypes.h HAVE_INTTYPES_H)
  75                 check_include_files(sys/modem.h HAVE_SYS_MODEM_H)
  76                 check_include_files(sys/filio.h HAVE_SYS_FILIO_H)
  77                 check_include_files(sys/sockio.h HAVE_SYS_SOCKIO_H)
  78                 check_include_files(sys/strtio.h HAVE_SYS_STRTIO_H)
  79                 check_include_files(sys/select.h HAVE_SYS_SELECT_H)
  80         else()
  81                 set(HAVE_FCNTL_H 1)
  82                 set(HAVE_UNISTD_H 1)
  83                 set(HAVE_STDINT_H 1)
  84                 set(HAVE_INTTYPES_H 1)
  85                 set(HAVE_SYS_FILIO_H 1)
  86         endif()
  87
  88         if(NOT IOS)
  89                 check_struct_has_member("struct tm" tm_gmtoff time.h HAVE_TM_GMTOFF)
  90         else()
  91                 set(HAVE_TM_GMTOFF 1)
  92         endif()
  93
  94         if(NOT WIN32)
  95                 check_library_exists(pthread pthread_mutex_timedlock "" HAVE_PTHREAD_MUTEX_TIMEDLOCK)
  96         endif()
  97
  98         set(OPENSSL_FEATURE_TYPE "OPTIONAL")
  99         set(OPENSSL_FEATURE_PURPOSE "cryptography")
 100         set(OPENSSL_FEATURE_DESCRIPTION "encryption, certificate validation, hashing functions")
 101
 102         set(MBEDTLS_FEATURE_TYPE "OPTIONAL")
 103         set(MBEDTLS_FEATURE_PURPOSE "cryptography")
 104         set(MBEDTLS_FEATURE_DESCRIPTION "encryption, certificate validation, hashing functions")
 105
 106         find_feature(OpenSSL ${OPENSSL_FEATURE_TYPE} ${OPENSSL_FEATURE_PURPOSE} ${OPENSSL_FEATURE_DESCRIPTION})
 107         find_feature(MbedTLS ${MBEDTLS_FEATURE_TYPE} ${MBEDTLS_FEATURE_PURPOSE} ${MBEDTLS_FEATURE_DESCRIPTION})
 108
 109         if(OPENSSL_FOUND)
 110                 add_definitions("-DWITH_OPENSSL")
 111         endif()
 112
 113         if(MBEDTLS_FOUND)
 114                 add_definitions("-DWITH_MBEDTLS")
 115         endif()
 116
 117         # Include directories
 118         include_directories(${CMAKE_CURRENT_BINARY_DIR})
 119
 120         # Configure files
 121         add_definitions("-DHAVE_CONFIG_H")
 122         configure_file(${CMAKE_CURRENT_SOURCE_DIR}/../config.h.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)
 123
 124         enable_testing()
 125
 126         if(MSVC)
 127                 set(TESTING_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}")
 128         else()
 129                 set(TESTING_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/Testing")
 130         endif()
 131 endif()
 132
 133 # Default to release build type
 134 if(NOT CMAKE_BUILD_TYPE)
 135    set(CMAKE_BUILD_TYPE "Release")
 136 endif()
 137
 138 # Default to build shared libs
 139 if(NOT DEFINED BUILD_SHARED_LIBS)
 140         set(BUILD_SHARED_LIBS ON)
 141 endif()
 142
 143 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DWINPR_EXPORTS")
 144
 145 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include)
 146 include_directories(${CMAKE_CURRENT_BINARY_DIR}/include)
 147
 148 add_subdirectory(include)
 149
 150 add_subdirectory(libwinpr)
 151
 152 if(NOT ANDROID AND NOT IOS)
 153         add_subdirectory(tools)
 154 endif()
 155
 156 if(BUILD_TESTING)
 157         add_subdirectory(test)
 158 endif()
 159
 160 # Exporting
 161
 162 if(${CMAKE_VERSION} VERSION_GREATER "2.8.10")
 163
 164         export(PACKAGE winpr)
 165
 166         set(WINPR_CMAKE_INSTALL_DIR "${CMAKE_INSTALL_LIBDIR}/cmake/WinPR${WINPR_VERSION_MAJOR}")
 167
 168         set(WINPR_INCLUDE_DIR "include/winpr${WINPR_VERSION_MAJOR}")
 169
 170         configure_package_config_file(WinPRConfig.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/WinPRConfig.cmake
 171                 INSTALL_DESTINATION ${WINPR_CMAKE_INSTALL_DIR}
 172                 PATH_VARS WINPR_INCLUDE_DIR)
 173
 174         write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/WinPRConfigVersion.cmake
 175                 VERSION ${WINPR_VERSION} COMPATIBILITY SameMajorVersion)
 176
 177         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/WinPRConfig.cmake ${CMAKE_CURRENT_BINARY_DIR}/WinPRConfigVersion.cmake
 178                 DESTINATION ${WINPR_CMAKE_INSTALL_DIR})
 179
 180         install(EXPORT WinPRTargets DESTINATION ${WINPR_CMAKE_INSTALL_DIR})
 181
 182 endif()
 183
 184 if(FREERDP_BUILD)
 185         set(WINPR_PKG_CONFIG_FILENAME winpr${WINPR_VERSION_MAJOR} PARENT_SCOPE)
 186 endif()
 187 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/winpr.pc.in ${CMAKE_CURRENT_BINARY_DIR}/winpr${WINPR_VERSION_MAJOR}.pc @ONLY)
 188 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/winpr${WINPR_VERSION_MAJOR}.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)