winpr/CMakeLists.txt

   1 # WinPR: Windows Portable Runtime
   2 # winpr cmake build script
   3 #
   4 # Copyright 2012 Marc-Andre Moreau <marcandre.moreau@gmail.com>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17
  18 cmake_minimum_required(VERSION 2.8)
  19
  20 project(WinPR C)
  21
  22 set(CMAKE_COLOR_MAKEFILE ON)
  23
  24 if(FREERDP_VERSION)
  25         set(FREERDP_BUILD 1)
  26 endif()
  27
  28 # Include cmake modules
  29 include(CheckIncludeFiles)
  30 include(CheckLibraryExists)
  31 include(CheckSymbolExists)
  32 include(CheckStructHasMember)
  33 include(FindPkgConfig)
  34 include(TestBigEndian)
  35
  36 # Include our extra modules
  37 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../cmake/)
  38
  39 # Check for cmake compatibility (enable/disable features)
  40 include(CheckCmakeCompat)
  41 include(FindFeature)
  42 include(AutoVersioning)
  43 include(ConfigOptions)
  44 include(ComplexLibrary)
  45 include(FeatureSummary)
  46 include(CheckCCompilerFlag)
  47 include(GNUInstallDirsWrapper)
  48 include(CMakePackageConfigHelpers)
  49
  50 # Soname versioning
  51 set(WINPR_VERSION_MAJOR "1")
  52 set(WINPR_VERSION_MINOR "2")
  53 set(WINPR_VERSION_REVISION "0")
  54 set(WINPR_VERSION "${WINPR_VERSION_MAJOR}.${WINPR_VERSION_MINOR}.${WINPR_VERSION_REVISION}")
  55 set(WINPR_VERSION_FULL "${WINPR_VERSION}")
  56 set(WINPR_API_VERSION "${WINPR_VERSION_MAJOR}")
  57
  58 if(NOT IOS)
  59         check_include_files(stdbool.h WINPR_HAVE_STDBOOL_H)
  60         check_include_files(stdint.h WINPR_HAVE_STDINT_H)
  61 else(NOT IOS)
  62         set(WINPR_HAVE_STDBOOL_H 1)
  63         set(WINPR_HAVE_STDINT_H 1)
  64 endif(NOT IOS)
  65
  66 if(FREERDP_BUILD)
  67         set(WINPR_VERSION_FULL ${WINPR_VERSION_FULL} PARENT_SCOPE)
  68         set(WINPR_VERSION ${WINPR_VERSION} PARENT_SCOPE)
  69 else()
  70         set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
  71
  72         if(NOT IOS AND NOT ANDROID)
  73                 find_package(Threads REQUIRED)
  74         endif()
  75
  76         # Include files
  77         if(NOT IOS)
  78                 check_include_files(fcntl.h HAVE_FCNTL_H)
  79                 check_include_files(unistd.h HAVE_UNISTD_H)
  80                 check_include_files(execinfo.h HAVE_EXECINFO_H)
  81                 check_include_files(inttypes.h HAVE_INTTYPES_H)
  82                 check_include_files(sys/modem.h HAVE_SYS_MODEM_H)
  83                 check_include_files(sys/filio.h HAVE_SYS_FILIO_H)
  84                 check_include_files(sys/sockio.h HAVE_SYS_SOCKIO_H)
  85                 check_include_files(sys/strtio.h HAVE_SYS_STRTIO_H)
  86                 check_include_files(sys/select.h HAVE_SYS_SELECT_H)
  87         else()
  88                 set(HAVE_FCNTL_H 1)
  89                 set(HAVE_UNISTD_H 1)
  90                 set(HAVE_INTTYPES_H 1)
  91                 set(HAVE_SYS_FILIO_H 1)
  92         endif()
  93
  94         if(NOT IOS)
  95                 check_struct_has_member("struct tm" tm_gmtoff time.h HAVE_TM_GMTOFF)
  96         else()
  97                 set(HAVE_TM_GMTOFF 1)
  98         endif()
  99
 100         if(NOT WIN32)
 101                 check_library_exists(pthread pthread_mutex_timedlock "" HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 102         endif()
 103
 104         set(OPENSSL_FEATURE_TYPE "OPTIONAL")
 105         set(OPENSSL_FEATURE_PURPOSE "cryptography")
 106         set(OPENSSL_FEATURE_DESCRIPTION "encryption, certificate validation, hashing functions")
 107
 108         set(MBEDTLS_FEATURE_TYPE "OPTIONAL")
 109         set(MBEDTLS_FEATURE_PURPOSE "cryptography")
 110         set(MBEDTLS_FEATURE_DESCRIPTION "encryption, certificate validation, hashing functions")
 111
 112         find_feature(OpenSSL ${OPENSSL_FEATURE_TYPE} ${OPENSSL_FEATURE_PURPOSE} ${OPENSSL_FEATURE_DESCRIPTION})
 113         find_feature(MbedTLS ${MBEDTLS_FEATURE_TYPE} ${MBEDTLS_FEATURE_PURPOSE} ${MBEDTLS_FEATURE_DESCRIPTION})
 114
 115         if(OPENSSL_FOUND)
 116                 add_definitions("-DWITH_OPENSSL")
 117         endif()
 118
 119         if(MBEDTLS_FOUND)
 120                 add_definitions("-DWITH_MBEDTLS")
 121         endif()
 122
 123         # Include directories
 124         include_directories(${CMAKE_CURRENT_BINARY_DIR})
 125
 126         # Configure files
 127         add_definitions("-DHAVE_CONFIG_H")
 128         configure_file(${CMAKE_CURRENT_SOURCE_DIR}/../config.h.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)
 129
 130         enable_testing()
 131
 132         if(MSVC)
 133                 set(TESTING_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}")
 134         else()
 135                 set(TESTING_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/Testing")
 136         endif()
 137 endif()
 138
 139 # Default to release build type
 140 if(NOT CMAKE_BUILD_TYPE)
 141    set(CMAKE_BUILD_TYPE "Release")
 142 endif()
 143
 144 # Default to build shared libs
 145 if(NOT DEFINED BUILD_SHARED_LIBS)
 146         set(BUILD_SHARED_LIBS ON)
 147 endif()
 148
 149 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -DWINPR_EXPORTS")
 150
 151 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include)
 152 include_directories(${CMAKE_CURRENT_BINARY_DIR}/include)
 153
 154 add_subdirectory(include)
 155
 156 add_subdirectory(libwinpr)
 157
 158 if(NOT ANDROID AND NOT IOS)
 159         add_subdirectory(tools)
 160 endif()
 161
 162 if(BUILD_TESTING)
 163         add_subdirectory(test)
 164 endif()
 165
 166 # Exporting
 167
 168 if(${CMAKE_VERSION} VERSION_GREATER "2.8.10")
 169
 170         export(PACKAGE winpr)
 171
 172         set(WINPR_CMAKE_INSTALL_DIR "${CMAKE_INSTALL_LIBDIR}/cmake/WinPR${WINPR_VERSION_MAJOR}")
 173
 174         set(WINPR_INCLUDE_DIR "include/winpr${WINPR_VERSION_MAJOR}")
 175
 176         configure_package_config_file(WinPRConfig.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/WinPRConfig.cmake
 177                 INSTALL_DESTINATION ${WINPR_CMAKE_INSTALL_DIR}
 178                 PATH_VARS WINPR_INCLUDE_DIR)
 179
 180         write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/WinPRConfigVersion.cmake
 181                 VERSION ${WINPR_VERSION} COMPATIBILITY SameMajorVersion)
 182
 183         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/WinPRConfig.cmake ${CMAKE_CURRENT_BINARY_DIR}/WinPRConfigVersion.cmake
 184                 DESTINATION ${WINPR_CMAKE_INSTALL_DIR})
 185
 186         install(EXPORT WinPRTargets DESTINATION ${WINPR_CMAKE_INSTALL_DIR})
 187
 188 endif()
 189
 190 if(FREERDP_BUILD)
 191         set(WINPR_PKG_CONFIG_FILENAME winpr${WINPR_VERSION_MAJOR} PARENT_SCOPE)
 192 endif()
 193 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/winpr.pc.in ${CMAKE_CURRENT_BINARY_DIR}/winpr${WINPR_VERSION_MAJOR}.pc @ONLY)
 194 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/winpr${WINPR_VERSION_MAJOR}.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)