vulkaninfo/CMakeLists.txt

   1 # ~~~
   2 # Copyright (c) 2018-2019 Valve Corporation
   3 # Copyright (c) 2018-2019 LunarG, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16 # ~~~
  17
  18 # CMakeLists.txt file for building Vulkaninfo
  19
  20 if(WIN32)
  21     # ~~~
  22     # Setup the vulkaninfo.rc file to contain the correct info
  23     # Optionally uses the VULKANINFO_BUILD_DLL_VERSIONINFO build option to allow setting the exact build version
  24     # When VULKANINFO_BUILD_DLL_VERSIONINFO is not provided, "Dev Build" is added to the version string
  25     # ~~~
  26     if ("$CACHE{VULKANINFO_BUILD_DLL_VERSIONINFO}" STREQUAL "")
  27         # Default version - for when no version is provided
  28         set(VULKANINFO_RC_VERSION "1.0.1111.2222")
  29         set(VULKANINFO_VER_FILE_VERSION_STR "\"${VULKANINFO_RC_VERSION}.Dev Build\"")
  30         set(VULKANINFO_VER_FILE_DESCRIPTION_STR "\"Vulkan Loader - Dev Build\"")
  31     else()
  32         set(VULKANINFO_RC_VERSION "$CACHE{VULKANINFO_BUILD_DLL_VERSIONINFO}")
  33         set(VULKANINFO_VER_FILE_VERSION_STR "\"${VULKANINFO_RC_VERSION}\"")
  34         set(VULKANINFO_VER_FILE_DESCRIPTION_STR "\"Vulkan Loader\"")
  35     endif()
  36
  37     # RC file wants the value of FILEVERSION to separated by commas
  38     string(REPLACE "." ", " VULKANINFO_VER_FILE_VERSION "${VULKANINFO_RC_VERSION}")
  39
  40     # Configure the file to include the versioning info
  41     configure_file(vulkaninfo.rc.in ${CMAKE_CURRENT_BINARY_DIR}/vulkaninfo.rc)
  42
  43     add_executable(vulkaninfo vulkaninfo.cpp ${CMAKE_CURRENT_BINARY_DIR}/vulkaninfo.rc)
  44     if (MINGW)
  45       target_link_libraries(vulkaninfo ucrt)
  46     endif ()
  47 elseif(APPLE)
  48     add_executable(vulkaninfo
  49                    vulkaninfo.cpp
  50                    ${CMAKE_CURRENT_SOURCE_DIR}/macOS/vulkaninfo/metal_view.mm
  51                    ${CMAKE_CURRENT_SOURCE_DIR}/macOS/vulkaninfo/metal_view.h)
  52 else()
  53     add_executable(vulkaninfo vulkaninfo.cpp)
  54 endif()
  55
  56 target_include_directories(vulkaninfo PRIVATE ${CMAKE_SOURCE_DIR}/vulkaninfo)
  57 target_include_directories(vulkaninfo PRIVATE ${CMAKE_SOURCE_DIR}/vulkaninfo/generated)
  58
  59 if (NOT WIN32)
  60     target_link_libraries(vulkaninfo ${CMAKE_DL_LIBS})
  61 endif()
  62
  63 if(UNIX AND NOT APPLE) # i.e. Linux
  64     find_package(PkgConfig)
  65     option(BUILD_WSI_XCB_SUPPORT "Build XCB WSI support" ON)
  66     option(BUILD_WSI_XLIB_SUPPORT "Build Xlib WSI support" ON)
  67     option(BUILD_WSI_WAYLAND_SUPPORT "Build Wayland WSI support" ON)
  68     option(BUILD_WSI_DIRECTFB_SUPPORT "Build DirectFB WSI support" OFF)
  69
  70     if(BUILD_WSI_XCB_SUPPORT)
  71         find_package(XCB REQUIRED)
  72         target_include_directories(vulkaninfo PRIVATE ${XCB_INCLUDE_DIRS})
  73         target_link_libraries(vulkaninfo ${XCB_LIBRARIES})
  74         target_compile_definitions(vulkaninfo PRIVATE -DVK_USE_PLATFORM_XCB_KHR -DVK_NO_PROTOTYPES)
  75     endif()
  76
  77     if(BUILD_WSI_XLIB_SUPPORT)
  78         find_package(X11 REQUIRED)
  79         target_include_directories(vulkaninfo PRIVATE ${X11_INCLUDE_DIR})
  80         target_link_libraries(vulkaninfo ${X11_LIBRARIES})
  81         target_compile_definitions(vulkaninfo PRIVATE -DVK_USE_PLATFORM_XLIB_KHR -DVK_NO_PROTOTYPES)
  82     endif()
  83
  84     if(BUILD_WSI_WAYLAND_SUPPORT)
  85         find_package(Wayland REQUIRED)
  86         target_include_directories(vulkaninfo PRIVATE ${WAYLAND_CLIENT_INCLUDE_DIR})
  87         target_link_libraries(vulkaninfo ${WAYLAND_CLIENT_LIBRARIES})
  88         target_compile_definitions(vulkaninfo PRIVATE -DVK_USE_PLATFORM_WAYLAND_KHR -DVK_NO_PROTOTYPES)
  89     endif()
  90
  91     if(BUILD_WSI_DIRECTFB_SUPPORT)
  92         find_package(DirectFB REQUIRED)
  93         target_include_directories(vulkaninfo PRIVATE ${DIRECTFB_INCLUDE_DIR})
  94         target_link_libraries(vulkaninfo ${DIRECTFB_LIBRARIES})
  95         target_compile_definitions(vulkaninfo PRIVATE -DVK_USE_PLATFORM_DIRECTFB_EXT -DVK_NO_PROTOTYPES)
  96     endif()
  97 endif()
  98
  99 if(APPLE)
 100     # We do this so vulkaninfo is linked to an individual library and NOT a framework.
 101     target_link_libraries(vulkaninfo ${Vulkan_LIBRARY} "-framework AppKit -framework QuartzCore")
 102     target_include_directories(vulkaninfo PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/macOS/vulkaninfo)
 103 endif()
 104
 105 target_link_libraries(vulkaninfo Vulkan::Headers)
 106
 107 if(WIN32)
 108     target_compile_definitions(vulkaninfo PUBLIC -DVK_USE_PLATFORM_WIN32_KHR -DWIN32_LEAN_AND_MEAN -D_CRT_SECURE_NO_WARNINGS -DVK_NO_PROTOTYPES)
 109     if(MSVC AND NOT MSVC_VERSION LESS 1900)
 110         # If MSVC, Enable control flow guard
 111         message(STATUS "Building vulkaninfo with control flow guard")
 112         add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/guard:cf>")
 113         set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /guard:cf")
 114         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /guard:cf")
 115     endif()
 116
 117     # Use static MSVCRT libraries
 118     foreach(configuration
 119             in
 120             CMAKE_C_FLAGS_DEBUG
 121             CMAKE_C_FLAGS_MINSIZEREL
 122             CMAKE_C_FLAGS_RELEASE
 123             CMAKE_C_FLAGS_RELWITHDEBINFO
 124             CMAKE_CXX_FLAGS_DEBUG
 125             CMAKE_CXX_FLAGS_MINSIZEREL
 126             CMAKE_CXX_FLAGS_RELEASE
 127             CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 128         if(${configuration} MATCHES "/MD")
 129             string(REGEX
 130                    REPLACE "/MD"
 131                            "/MT"
 132                            ${configuration}
 133                            "${${configuration}}")
 134         endif()
 135     endforeach()
 136 elseif(APPLE)
 137     add_definitions(-DVK_USE_PLATFORM_MACOS_MVK -DVK_USE_PLATFORM_METAL_EXT)
 138 endif()
 139
 140 if(APPLE)
 141     install(TARGETS vulkaninfo RUNTIME DESTINATION "vulkaninfo")
 142 else()
 143     install(TARGETS vulkaninfo RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 144 endif()
 145