vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set target=Build
  17 set target_arch=ia32
  18 set debug_arg=
  19 set nosnapshot_arg=
  20 set noprojgen=
  21 set nobuild=
  22 set nosign=
  23 set nosnapshot=
  24 set test=
  25 set test_args=
  26 set msi=
  27 set upload=
  28 set jslint=
  29
  30 :next-arg
  31 if "%1"=="" goto args-done
  32 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  33 if /i "%1"=="release"       set config=Release&goto arg-ok
  34 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  35 if /i "%1"=="ia32"          set target_arch=ia32&goto arg-ok
  36 if /i "%1"=="x86"           set target_arch=ia32&goto arg-ok
  37 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  38 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  39 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  40 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  41 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  42 if /i "%1"=="test-uv"       set test=test-uv&goto arg-ok
  43 if /i "%1"=="test-internet" set test=test-internet&goto arg-ok
  44 if /i "%1"=="test-pummel"   set test=test-pummel&goto arg-ok
  45 if /i "%1"=="test-simple"   set test=test-simple&goto arg-ok
  46 if /i "%1"=="test-message"  set test=test-message&goto arg-ok
  47 if /i "%1"=="test-all"      set test=test-all&goto arg-ok
  48 if /i "%1"=="test"          set test=test&goto arg-ok
  49 if /i "%1"=="msi"           set msi=1&goto arg-ok
  50 if /i "%1"=="upload"        set upload=1&goto arg-ok
  51 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  52
  53 echo Warning: ignoring invalid command line option `%1`.
  54
  55 :arg-ok
  56 shift
  57 goto next-arg
  58 :args-done
  59 if defined upload goto upload
  60 if defined jslint goto jslint
  61
  62 if "%config%"=="Debug" set debug_arg=--debug
  63 if defined nosnapshot set nosnapshot_arg=--without-snapshot
  64
  65 :project-gen
  66 @rem Skip project generation if requested.
  67 if defined noprojgen goto msbuild
  68
  69 @rem Generate the VS project.
  70 python configure %debug_arg% %nosnapshot_arg% --dest-cpu=%target_arch%
  71 if errorlevel 1 goto create-msvs-files-failed
  72 if not exist node.sln goto create-msvs-files-failed
  73 echo Project files generated.
  74
  75 :msbuild
  76 @rem Skip project generation if requested.
  77 if defined nobuild goto msi
  78
  79 @rem Bail out early if not running in VS build env.
  80 if defined VCINSTALLDIR goto msbuild-found
  81 if not defined VS100COMNTOOLS goto msbuild-not-found
  82 if not exist "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
  83 call "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat"
  84 if not defined VCINSTALLDIR goto msbuild-not-found
  85 goto msbuild-found
  86
  87 :msbuild-not-found
  88 echo Build skipped. To build, this file needs to run from VS cmd prompt.
  89 goto run
  90
  91 :msbuild-found
  92 @rem Build the sln with msbuild.
  93 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
  94 if errorlevel 1 goto exit
  95
  96 if defined nosign goto msi
  97 signtool sign /a Release\node.exe
  98
  99 :msi
 100 @rem Skip msi generation if not requested
 101 if not defined msi goto run
 102 python "%~dp0tools\getnodeversion.py" > "%temp%\node_version.txt"
 103 if not errorlevel 0 echo Cannot determine current version of node.js & goto exit
 104 for /F "tokens=*" %%i in (%temp%\node_version.txt) do set NODE_VERSION=%%i
 105 heat dir deps\npm -var var.NPMSourceDir -dr NodeModulesFolder -cg NPMFiles -gg -template fragment -nologo -out npm.wxs
 106 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:Configuration=%config% /p:NodeVersion=%NODE_VERSION% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 107 if errorlevel 1 goto exit
 108
 109 if defined nosign goto run
 110 signtool sign /a Release\node.msi
 111
 112 :run
 113 @rem Run tests if requested.
 114 if "%test%"=="" goto exit
 115
 116 if "%config%"=="Debug" set test_args=--mode=debug
 117 if "%config%"=="Release" set test_args=--mode=release
 118
 119 if "%test%"=="test" set test_args=%test_args% simple message
 120 if "%test%"=="test-internet" set test_args=%test_args% internet
 121 if "%test%"=="test-pummel" set test_args=%test_args% pummel
 122 if "%test%"=="test-simple" set test_args=%test_args% simple
 123 if "%test%"=="test-message" set test_args=%test_args% message
 124 if "%test%"=="test-all" set test_args=%test_args%
 125
 126 echo running 'python tools/test.py %test_args%'
 127 python tools/test.py %test_args%
 128
 129 if "%test%"=="test" goto jslint
 130
 131 goto exit
 132
 133 :create-msvs-files-failed
 134 echo Failed to create vc project files.
 135 goto exit
 136
 137 :upload
 138 echo uploading .exe .msi .pdb to nodejs.org
 139 python "%~dp0tools\getnodeversion.py" > "%temp%\node_version.txt"
 140 if not errorlevel 0 echo Cannot determine current version of node.js & goto exit
 141 for /F "tokens=*" %%i in (%temp%\node_version.txt) do set NODE_VERSION=%%i
 142 @echo on
 143 ssh node@nodejs.org mkdir -p web/nodejs.org/dist/v%NODE_VERSION%
 144 scp Release\node.msi node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node-v%NODE_VERSION%.msi
 145 scp Release\node.exe node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.exe
 146 scp Release\node.pdb node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.pdb
 147 @echo off
 148 goto exit
 149
 150 :jslint
 151 echo running jslint
 152 set PYTHONPATH=tools/closure_linter/
 153 python tools/closure_linter/closure_linter/gjslint.py --unix_mode --strict --nojsdoc -r lib/ -r src/ -r test/ --exclude_files lib/punycode.js
 154 goto exit
 155
 156 :help
 157 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [nobuild] [nosign]
 158 echo Examples:
 159 echo   vcbuild.bat                : builds release build
 160 echo   vcbuild.bat debug          : builds debug build
 161 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 162 echo   vcbuild.bat test           : builds debug build and runs tests
 163 goto exit
 164
 165 :exit