vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set target=Build
  17 set target_arch=x86
  18 set target_env=
  19 set noprojgen=
  20 set nobuild=
  21 set nosign=
  22 set nosnapshot=
  23 set test_args=
  24 set msi=
  25 set upload=
  26 set licensertf=
  27 set jslint=
  28 set buildnodeweak=
  29 set noetw=
  30 set noetw_msi_arg=
  31 set noperfctr=
  32 set noperfctr_msi_arg=
  33 set i18n_arg=
  34 set download_arg=
  35 set release_urls_arg=
  36 set build_release=
  37 set configure_flags=
  38 set build_addons=
  39
  40 :next-arg
  41 if "%1"=="" goto args-done
  42 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  43 if /i "%1"=="release"       set config=Release&goto arg-ok
  44 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  45 if /i "%1"=="ia32"          set target_arch=x86&goto arg-ok
  46 if /i "%1"=="x86"           set target_arch=x86&goto arg-ok
  47 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  48 if /i "%1"=="vc2013"        set target_env=vc2013&goto arg-ok
  49 if /i "%1"=="vc2015"        set target_env=vc2015&goto arg-ok
  50 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  51 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  52 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  53 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  54 if /i "%1"=="noetw"         set noetw=1&goto arg-ok
  55 if /i "%1"=="noperfctr"     set noperfctr=1&goto arg-ok
  56 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  57 if /i "%1"=="test"          set test_args=%test_args% addons sequential parallel message -J&set jslint=1&set build_addons=1&goto arg-ok
  58 if /i "%1"=="test-ci"       set test_args=%test_args% %test_ci_args% -p tap --logfile test.tap addons message sequential parallel&set build_addons=1&goto arg-ok
  59 if /i "%1"=="test-addons"   set test_args=%test_args% addons&set build_addons=1&goto arg-ok
  60 if /i "%1"=="test-simple"   set test_args=%test_args% sequential parallel -J&goto arg-ok
  61 if /i "%1"=="test-message"  set test_args=%test_args% message&goto arg-ok
  62 if /i "%1"=="test-gc"       set test_args=%test_args% gc&set buildnodeweak=1&goto arg-ok
  63 if /i "%1"=="test-internet" set test_args=%test_args% internet&goto arg-ok
  64 if /i "%1"=="test-pummel"   set test_args=%test_args% pummel&goto arg-ok
  65 if /i "%1"=="test-all"      set test_args=%test_args% sequential parallel message gc internet pummel&set buildnodeweak=1&set jslint=1&goto arg-ok
  66 if /i "%1"=="test-known-issues" set test_args=%test_args% known_issues --expect-fail&goto arg-ok
  67 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  68 if /i "%1"=="msi"           set msi=1&set licensertf=1&set download_arg="--download=all"&set i18n_arg=small-icu&goto arg-ok
  69 if /i "%1"=="build-release" set build_release=1&goto arg-ok
  70 if /i "%1"=="upload"        set upload=1&goto arg-ok
  71 if /i "%1"=="small-icu"     set i18n_arg=%1&goto arg-ok
  72 if /i "%1"=="full-icu"      set i18n_arg=%1&goto arg-ok
  73 if /i "%1"=="intl-none"     set i18n_arg=%1&goto arg-ok
  74 if /i "%1"=="download-all"  set download_arg="--download=all"&goto arg-ok
  75 if /i "%1"=="ignore-flaky"  set test_args=%test_args% --flaky-tests=dontcare&goto arg-ok
  76
  77 echo Warning: ignoring invalid command line option `%1`.
  78
  79 :arg-ok
  80 :arg-ok
  81 shift
  82 goto next-arg
  83
  84 :args-done
  85
  86 if defined build_release (
  87   set config=Release
  88   set msi=1
  89   set licensertf=1
  90   set download_arg="--download=all"
  91   set i18n_arg=small-icu
  92 )
  93
  94 :: assign path to node_exe
  95 set "node_exe=%config%\node.exe"
  96
  97 if "%config%"=="Debug" set configure_flags=%configure_flags% --debug
  98 if defined nosnapshot set configure_flags=%configure_flags% --without-snapshot
  99 if defined noetw set configure_flags=%configure_flags% --without-etw& set noetw_msi_arg=/p:NoETW=1
 100 if defined noperfctr set configure_flags=%configure_flags% --without-perfctr& set noperfctr_msi_arg=/p:NoPerfCtr=1
 101 if defined release_urlbase set release_urlbase_arg=--release-urlbase=%release_urlbase%
 102 if defined download_arg set configure_flags=%configure_flags% %download_arg%
 103
 104 if "%i18n_arg%"=="full-icu" set configure_flags=%configure_flags% --with-intl=full-icu
 105 if "%i18n_arg%"=="small-icu" set configure_flags=%configure_flags% --with-intl=small-icu
 106 if "%i18n_arg%"=="intl-none" set configure_flags=%configure_flags% --with-intl=none
 107
 108 if defined config_flags set configure_flags=%configure_flags% %config_flags%
 109
 110 if not exist "%~dp0deps\icu" goto no-depsicu
 111 if "%target%"=="Clean" echo deleting %~dp0deps\icu
 112 if "%target%"=="Clean" rmdir /S /Q %~dp0deps\icu
 113 :no-depsicu
 114
 115 call :getnodeversion || exit /b 1
 116
 117 @rem Set environment for msbuild
 118
 119 if defined target_env if "%target_env%" NEQ "vc2015" goto vc-set-2013
 120 @rem Look for Visual Studio 2015
 121 echo Looking for Visual Studio 2015
 122 if not defined VS140COMNTOOLS goto vc-set-2013
 123 if not exist "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat" goto vc-set-2013
 124 echo Found Visual Studio 2015
 125 if defined msi (
 126   echo Looking for WiX installation for Visual Studio 2015...
 127   if not exist "%WIX%\SDK\VS2015" (
 128     echo Failed to find WiX install for Visual Studio 2015
 129     echo VS2015 support for WiX is only present starting at version 3.10
 130     goto vc-set-2013
 131   )
 132 )
 133 if "%VCVARS_VER%" NEQ "140" (
 134   call "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat"
 135   SET VCVARS_VER=140
 136 )
 137 if not defined VCINSTALLDIR goto vc-set-2013
 138 set GYP_MSVS_VERSION=2015
 139 set PLATFORM_TOOLSET=v140
 140 goto msbuild-found
 141
 142 :vc-set-2013
 143 if defined target_env if "%target_env%" NEQ "vc2013" goto msbuild-not-found
 144 @rem Look for Visual Studio 2013
 145 echo Looking for Visual Studio 2013
 146 if not defined VS120COMNTOOLS goto msbuild-not-found
 147 if not exist "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
 148 echo Found Visual Studio 2013
 149 if defined msi (
 150   echo Looking for WiX installation for Visual Studio 2013...
 151   if not exist "%WIX%\SDK\VS2013" (
 152     echo Failed to find WiX install for Visual Studio 2013
 153     echo VS2013 support for WiX is only present starting at version 3.8
 154     goto wix-not-found
 155   )
 156 )
 157 if "%VCVARS_VER%" NEQ "120" (
 158   call "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat"
 159   SET VCVARS_VER=120
 160 )
 161 if not defined VCINSTALLDIR goto msbuild-not-found
 162 set GYP_MSVS_VERSION=2013
 163 set PLATFORM_TOOLSET=v120
 164 goto msbuild-found
 165
 166 :msbuild-not-found
 167 echo Failed to find Visual Studio installation.
 168 goto exit
 169
 170 :wix-not-found
 171 echo Build skipped. To generate installer, you need to install Wix.
 172 goto run
 173
 174 :msbuild-found
 175
 176 :project-gen
 177 @rem Skip project generation if requested.
 178 if defined noprojgen goto msbuild
 179
 180 @rem Generate the VS project.
 181 echo configure %configure_flags% --dest-cpu=%target_arch% --tag=%TAG%
 182 python configure %configure_flags% --dest-cpu=%target_arch% --tag=%TAG%
 183 if errorlevel 1 goto create-msvs-files-failed
 184 if not exist node.sln goto create-msvs-files-failed
 185 echo Project files generated.
 186
 187 :msbuild
 188 @rem Skip build if requested.
 189 if defined nobuild goto sign
 190
 191 @rem Build the sln with msbuild.
 192 set "msbplatform=Win32"
 193 if "%target_arch%"=="x64" set "msbplatform=x64"
 194 msbuild node.sln /m /t:%target% /p:Configuration=%config% /p:Platform=%msbplatform% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 195 if errorlevel 1 goto exit
 196 if "%target%" == "Clean" goto exit
 197
 198 :sign
 199 @rem Skip signing if the `nosign` option was specified.
 200 if defined nosign goto licensertf
 201
 202 signtool sign /a /d "Node.js" /du "https://nodejs.org" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\node.exe
 203 if errorlevel 1 echo Failed to sign exe&goto exit
 204
 205 :licensertf
 206 @rem Skip license.rtf generation if not requested.
 207 if not defined licensertf goto msi
 208
 209 %config%\node tools\license2rtf.js < LICENSE > %config%\license.rtf
 210 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 211
 212 :msi
 213 @rem Skip msi generation if not requested
 214 if not defined msi goto run
 215
 216 :msibuild
 217 echo Building node-v%FULLVERSION%-%target_arch%.msi
 218 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:PlatformToolset=%PLATFORM_TOOLSET% /p:GypMsvsVersion=%GYP_MSVS_VERSION% /p:Configuration=%config% /p:Platform=%target_arch% /p:NodeVersion=%NODE_VERSION% /p:FullVersion=%FULLVERSION% /p:DistTypeDir=%DISTTYPEDIR% %noetw_msi_arg% %noperfctr_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 219 if errorlevel 1 goto exit
 220
 221 if defined nosign goto upload
 222 signtool sign /a /d "Node.js" /du "https://nodejs.org" /t http://timestamp.globalsign.com/scripts/timestamp.dll node-v%FULLVERSION%-%target_arch%.msi
 223 if errorlevel 1 echo Failed to sign msi&goto exit
 224
 225 :upload
 226 @rem Skip upload if not requested
 227 if not defined upload goto run
 228
 229 if not defined SSHCONFIG (
 230   echo SSHCONFIG is not set for upload
 231   exit /b 1
 232 )
 233 if not defined STAGINGSERVER set STAGINGSERVER=node-www
 234 ssh -F %SSHCONFIG% %STAGINGSERVER% "mkdir -p nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%"
 235 scp -F %SSHCONFIG% Release\node.exe %STAGINGSERVER%:nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/node.exe
 236 scp -F %SSHCONFIG% Release\node.lib %STAGINGSERVER%:nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/node.lib
 237 scp -F %SSHCONFIG% node-v%FULLVERSION%-%target_arch%.msi %STAGINGSERVER%:nodejs/%DISTTYPEDIR%/v%FULLVERSION%/
 238 ssh -F %SSHCONFIG% %STAGINGSERVER% "touch nodejs/%DISTTYPEDIR%/v%FULLVERSION%/node-v%FULLVERSION%-%target_arch%.msi.done nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%.done && chmod -R ug=rw-x+X,o=r+X nodejs/%DISTTYPEDIR%/v%FULLVERSION%/node-v%FULLVERSION%-%target_arch%.msi* nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%*"
 239
 240 :run
 241 @rem Run tests if requested.
 242
 243 :build-node-weak
 244 @rem Build node-weak if required
 245 if "%buildnodeweak%"=="" goto build-addons
 246 "%config%\node" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0."
 247 if errorlevel 1 goto build-node-weak-failed
 248 goto build-addons
 249
 250 :build-node-weak-failed
 251 echo Failed to build node-weak.
 252 goto exit
 253
 254 :build-addons
 255 if not defined build_addons goto run-tests
 256 if not exist "%node_exe%" (
 257   echo Failed to find node.exe
 258   goto run-tests
 259 )
 260 echo Building add-ons
 261 :: clear
 262 for /d %%F in (test\addons\??_*) do (
 263   rd /s /q %%F
 264 )
 265 :: generate
 266 "%node_exe%" tools\doc\addon-verify.js
 267 :: building addons
 268 for /d %%F in (test\addons\*) do (
 269   "%node_exe%" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild ^
 270     --directory="%%F" ^
 271     --nodedir="%cd%"
 272 )
 273 goto run-tests
 274
 275 :run-tests
 276 if "%test_args%"=="" goto jslint
 277 if "%config%"=="Debug" set test_args=--mode=debug %test_args%
 278 if "%config%"=="Release" set test_args=--mode=release %test_args%
 279 echo running 'cctest'
 280 "%config%\cctest"
 281 echo running 'python tools\test.py %test_args%'
 282 python tools\test.py %test_args%
 283 goto jslint
 284
 285 :jslint
 286 if not defined jslint goto exit
 287 echo running jslint
 288 %config%\node tools\eslint\bin\eslint.js benchmark lib src test tools\doc tools\eslint-rules --rulesdir tools\eslint-rules
 289 goto exit
 290
 291 :create-msvs-files-failed
 292 echo Failed to create vc project files.
 293 goto exit
 294
 295 :help
 296
 297 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [small-icu/full-icu/intl-none] [nobuild] [nosign] [x86/x64] [vc2013/vc2015] [download-all]
 298
 299 echo Examples:
 300 echo   vcbuild.bat                : builds release build
 301 echo   vcbuild.bat debug          : builds debug build
 302 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 303 echo   vcbuild.bat test           : builds debug build and runs tests
 304 echo   vcbuild.bat build-release  : builds the release distribution as used by nodejs.org
 305 goto exit
 306
 307 :exit
 308 goto :EOF
 309
 310 rem ***************
 311 rem   Subroutines
 312 rem ***************
 313
 314 :getnodeversion
 315 set NODE_VERSION=
 316 set TAG=
 317 set FULLVERSION=
 318
 319 for /F "usebackq tokens=*" %%i in (`python "%~dp0tools\getnodeversion.py"`) do set NODE_VERSION=%%i
 320 if not defined NODE_VERSION (
 321   echo Cannot determine current version of Node.js
 322   exit /b 1
 323 )
 324
 325 if not defined DISTTYPE set DISTTYPE=release
 326 if "%DISTTYPE%"=="release" (
 327   set FULLVERSION=%NODE_VERSION%
 328   goto exit
 329 )
 330 if "%DISTTYPE%"=="custom" (
 331   if not defined CUSTOMTAG (
 332     echo "CUSTOMTAG is not set for DISTTYPE=custom"
 333     exit /b 1
 334   )
 335   set TAG=%CUSTOMTAG%
 336 )
 337 if not "%DISTTYPE%"=="custom" (
 338   if not defined DATESTRING (
 339     echo "DATESTRING is not set for nightly"
 340     exit /b 1
 341   )
 342   if not defined COMMIT (
 343     echo "COMMIT is not set for nightly"
 344     exit /b 1
 345   )
 346   if not "%DISTTYPE%"=="nightly" (
 347     if not "%DISTTYPE%"=="next-nightly" (
 348       echo "DISTTYPE is not release, custom, nightly or next-nightly"
 349       exit /b 1
 350     )
 351   )
 352   set TAG=%DISTTYPE%%DATESTRING%%COMMIT%
 353 )
 354 set FULLVERSION=%NODE_VERSION%-%TAG%
 355
 356 :exit
 357 if not defined DISTTYPEDIR set DISTTYPEDIR=%DISTTYPE%
 358 goto :EOF