vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set msiplatform=x86
  17 set target=Build
  18 set target_arch=ia32
  19 set debug_arg=
  20 set nosnapshot_arg=
  21 set noprojgen=
  22 set nobuild=
  23 set nosign=
  24 set nosnapshot=
  25 set test=
  26 set test_args=
  27 set msi=
  28 set licensertf=
  29 set upload=
  30 set jslint=
  31
  32 :next-arg
  33 if "%1"=="" goto args-done
  34 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  35 if /i "%1"=="release"       set config=Release&goto arg-ok
  36 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  37 if /i "%1"=="ia32"          set target_arch=ia32&goto arg-ok
  38 if /i "%1"=="x86"           set target_arch=ia32&goto arg-ok
  39 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  40 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  41 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  42 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  43 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  44 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  45 if /i "%1"=="test-uv"       set test=test-uv&goto arg-ok
  46 if /i "%1"=="test-internet" set test=test-internet&goto arg-ok
  47 if /i "%1"=="test-pummel"   set test=test-pummel&goto arg-ok
  48 if /i "%1"=="test-simple"   set test=test-simple&goto arg-ok
  49 if /i "%1"=="test-message"  set test=test-message&goto arg-ok
  50 if /i "%1"=="test-all"      set test=test-all&goto arg-ok
  51 if /i "%1"=="test"          set test=test&goto arg-ok
  52 if /i "%1"=="msi"           set msi=1&set licensertf=1&goto arg-ok
  53 if /i "%1"=="upload"        set upload=1&goto arg-ok
  54 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  55
  56 echo Warning: ignoring invalid command line option `%1`.
  57
  58 :arg-ok
  59 shift
  60 goto next-arg
  61 :args-done
  62 if defined upload goto upload
  63 if defined jslint goto jslint
  64
  65 if "%config%"=="Debug" set debug_arg=--debug
  66 if "%target_arch%"=="x64" set msiplatform=x64
  67 if defined nosnapshot set nosnapshot_arg=--without-snapshot
  68
  69 :project-gen
  70 @rem Skip project generation if requested.
  71 if defined noprojgen goto msbuild
  72
  73 @rem Generate the VS project.
  74 python configure %debug_arg% %nosnapshot_arg% --dest-cpu=%target_arch%
  75 if errorlevel 1 goto create-msvs-files-failed
  76 if not exist node.sln goto create-msvs-files-failed
  77 echo Project files generated.
  78
  79 :msbuild
  80 @rem Skip project generation if requested.
  81 if defined nobuild goto sign
  82
  83 @rem Bail out early if not running in VS build env.
  84 if defined VCINSTALLDIR goto msbuild-found
  85 if not defined VS100COMNTOOLS goto msbuild-not-found
  86 if not exist "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
  87 call "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat"
  88 if not defined VCINSTALLDIR goto msbuild-not-found
  89 goto msbuild-found
  90
  91 :msbuild-not-found
  92 echo Build skipped. To build, this file needs to run from VS cmd prompt.
  93 goto run
  94
  95 :msbuild-found
  96 @rem Build the sln with msbuild.
  97 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
  98 if errorlevel 1 goto exit
  99
 100 :sign
 101 @rem Skip signing if the `nosign` option was specified.
 102 if defined nosign goto licensertf
 103
 104 signtool sign /a Release\node.exe
 105
 106 :licensertf
 107 @rem Skip license.rtf generation if not requested.
 108 if not defined licensertf goto msi
 109
 110 %config%\node tools\license2rtf.js < LICENSE > %config%\license.rtf
 111 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 112
 113 :msi
 114 @rem Skip msi generation if not requested
 115 if not defined msi goto run
 116 python "%~dp0tools\getnodeversion.py" > "%temp%\node_version.txt"
 117 if not errorlevel 0 echo Cannot determine current version of node.js & goto exit
 118 for /F "tokens=*" %%i in (%temp%\node_version.txt) do set NODE_VERSION=%%i
 119 heat dir deps\npm -var var.NPMSourceDir -dr NodeModulesFolder -cg NPMFiles -gg -template fragment -nologo -out npm.wxs
 120 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:Configuration=%config% /p:Platform=%msiplatform% /p:NodeVersion=%NODE_VERSION% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 121 if errorlevel 1 goto exit
 122
 123 if defined nosign goto run
 124 signtool sign /a Release\node.msi
 125
 126 :run
 127 @rem Run tests if requested.
 128 if "%test%"=="" goto exit
 129
 130 if "%config%"=="Debug" set test_args=--mode=debug
 131 if "%config%"=="Release" set test_args=--mode=release
 132
 133 if "%test%"=="test" set test_args=%test_args% simple message
 134 if "%test%"=="test-internet" set test_args=%test_args% internet
 135 if "%test%"=="test-pummel" set test_args=%test_args% pummel
 136 if "%test%"=="test-simple" set test_args=%test_args% simple
 137 if "%test%"=="test-message" set test_args=%test_args% message
 138 if "%test%"=="test-all" set test_args=%test_args%
 139
 140 echo running 'python tools/test.py %test_args%'
 141 python tools/test.py %test_args%
 142
 143 if "%test%"=="test" goto jslint
 144
 145 goto exit
 146
 147 :create-msvs-files-failed
 148 echo Failed to create vc project files.
 149 goto exit
 150
 151 :upload
 152 echo uploading .exe .msi .pdb to nodejs.org
 153 python "%~dp0tools\getnodeversion.py" > "%temp%\node_version.txt"
 154 if not errorlevel 0 echo Cannot determine current version of node.js & goto exit
 155 for /F "tokens=*" %%i in (%temp%\node_version.txt) do set NODE_VERSION=%%i
 156 @echo on
 157 ssh node@nodejs.org mkdir -p web/nodejs.org/dist/v%NODE_VERSION%
 158 scp Release\node.msi node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node-v%NODE_VERSION%.msi
 159 scp Release\node.exe node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.exe
 160 scp Release\node.pdb node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.pdb
 161 @echo off
 162 goto exit
 163
 164 :jslint
 165 echo running jslint
 166 set PYTHONPATH=tools/closure_linter/
 167 python tools/closure_linter/closure_linter/gjslint.py --unix_mode --strict --nojsdoc -r lib/ -r src/ -r test/ --exclude_files lib/punycode.js
 168 goto exit
 169
 170 :help
 171 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [nobuild] [nosign] [x86/x64]
 172 echo Examples:
 173 echo   vcbuild.bat                : builds release build
 174 echo   vcbuild.bat debug          : builds debug build
 175 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 176 echo   vcbuild.bat test           : builds debug build and runs tests
 177 goto exit
 178
 179 :exit