vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set msiplatform=x86
  17 set target=Build
  18 set target_arch=ia32
  19 set debug_arg=
  20 set snapshot_arg=
  21 set noprojgen=
  22 set nobuild=
  23 set nosign=
  24 set snapshot=
  25 set test_args=
  26 set msi=
  27 set licensertf=
  28 set jslint=
  29 set buildnodeweak=
  30 set noetw=
  31 set noetw_arg=
  32 set noetw_msi_arg=
  33 set noperfctr=
  34 set noperfctr_arg=
  35 set noperfctr_msi_arg=
  36 set i18n_arg=
  37 set download_arg=
  38
  39 :next-arg
  40 if "%1"=="" goto args-done
  41 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  42 if /i "%1"=="release"       set config=Release&goto arg-ok
  43 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  44 if /i "%1"=="ia32"          set target_arch=ia32&goto arg-ok
  45 if /i "%1"=="x86"           set target_arch=ia32&goto arg-ok
  46 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  47 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  48 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  49 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  50 if /i "%1"=="snapshot"      set snapshot=1&goto arg-ok
  51 if /i "%1"=="noetw"         set noetw=1&goto arg-ok
  52 if /i "%1"=="noperfctr"     set noperfctr=1&goto arg-ok
  53 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  54 if /i "%1"=="test"          set test_args=%test_args% sequential parallel message -J&set jslint=1&goto arg-ok
  55 if /i "%1"=="test-simple"   set test_args=%test_args% sequential parallel -J&goto arg-ok
  56 if /i "%1"=="test-message"  set test_args=%test_args% message&goto arg-ok
  57 if /i "%1"=="test-gc"       set test_args=%test_args% gc&set buildnodeweak=1&goto arg-ok
  58 if /i "%1"=="test-internet" set test_args=%test_args% internet&goto arg-ok
  59 if /i "%1"=="test-pummel"   set test_args=%test_args% pummel&goto arg-ok
  60 if /i "%1"=="test-all"      set test_args=%test_args% sequential parallel message gc internet pummel&set buildnodeweak=1&set jslint=1&goto arg-ok
  61 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  62 if /i "%1"=="msi"           set msi=1&set licensertf=1&goto arg-ok
  63 if /i "%1"=="small-icu"     set i18n_arg=%1&goto arg-ok
  64 if /i "%1"=="full-icu"      set i18n_arg=%1&goto arg-ok
  65 if /i "%1"=="intl-none"     set i18n_arg=%1&goto arg-ok
  66 if /i "%1"=="download-all"  set download_arg="--download=all"&goto arg-ok
  67
  68 echo Warning: ignoring invalid command line option `%1`.
  69
  70 :arg-ok
  71 :arg-ok
  72 shift
  73 goto next-arg
  74
  75 :args-done
  76 if "%config%"=="Debug" set debug_arg=--debug
  77 if "%target_arch%"=="x64" set msiplatform=x64
  78 if defined snapshot set snapshot_arg=--with-snapshot
  79 if defined noetw set noetw_arg=--without-etw& set noetw_msi_arg=/p:NoETW=1
  80 if defined noperfctr set noperfctr_arg=--without-perfctr& set noperfctr_msi_arg=/p:NoPerfCtr=1
  81
  82 if "%i18n_arg%"=="full-icu" set i18n_arg=--with-intl=full-icu
  83 if "%i18n_arg%"=="small-icu" set i18n_arg=--with-intl=small-icu
  84 if "%i18n_arg%"=="intl-none" set i18n_arg=--with-intl=none
  85
  86 :project-gen
  87 @rem Skip project generation if requested.
  88 if defined noprojgen goto msbuild
  89
  90 if defined NIGHTLY set TAG=nightly-%NIGHTLY%
  91
  92 if not defined PYTHON set PYTHON=python
  93
  94 @rem Generate the VS project.
  95 SETLOCAL
  96   if defined VS100COMNTOOLS call "%VS100COMNTOOLS%\VCVarsQueryRegistry.bat"
  97   "%PYTHON%" configure %download_arg% %i18n_arg% %debug_arg% %snapshot_arg% %noetw_arg% %noperfctr_arg% --dest-cpu=%target_arch% --tag=%TAG%
  98   if errorlevel 1 goto create-msvs-files-failed
  99   if not exist node.sln goto create-msvs-files-failed
 100   echo Project files generated.
 101 ENDLOCAL
 102
 103 :msbuild
 104 @rem Skip project generation if requested.
 105 if defined nobuild goto sign
 106
 107 @rem Look for Visual Studio 2013
 108 if not defined VS120COMNTOOLS goto msbuild-not-found
 109 if not exist "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
 110 if "%VCVARS_VER%" NEQ "120" (
 111   call "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat"
 112   SET VCVARS_VER=120
 113 )
 114 if not defined VCINSTALLDIR goto msbuild-not-found
 115 set GYP_MSVS_VERSION=2013
 116 goto msbuild-found
 117
 118 :msbuild-not-found
 119 echo Build skipped. To build, this file needs to run from VS cmd prompt.
 120 goto run
 121
 122 :msbuild-found
 123 @rem Build the sln with msbuild.
 124 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 125 if errorlevel 1 goto exit
 126
 127 :sign
 128 @rem Skip signing if the `nosign` option was specified.
 129 if defined nosign goto licensertf
 130
 131 signtool sign /a /d "io.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\iojs.exe
 132 if errorlevel 1 echo Failed to sign exe&goto exit
 133
 134 :licensertf
 135 @rem Skip license.rtf generation if not requested.
 136 if not defined licensertf goto msi
 137
 138 %config%\iojs tools\license2rtf.js < LICENSE > %config%\license.rtf
 139 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 140
 141 :msi
 142 @rem Skip msi generation if not requested
 143 if not defined msi goto run
 144 call :getnodeversion
 145
 146 if not defined NIGHTLY goto msibuild
 147 set NODE_VERSION=%NODE_VERSION%.%NIGHTLY%
 148
 149 :msibuild
 150 echo Building iojs-%NODE_VERSION%
 151 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:Configuration=%config% /p:Platform=%msiplatform% /p:NodeVersion=%NODE_VERSION% %noetw_msi_arg% %noperfctr_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 152 if errorlevel 1 goto exit
 153
 154 if defined nosign goto run
 155 signtool sign /a /d "io.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\iojs-v%NODE_VERSION%-%msiplatform%.msi
 156 if errorlevel 1 echo Failed to sign msi&goto exit
 157
 158 :run
 159 @rem Run tests if requested.
 160
 161 :build-node-weak
 162 @rem Build node-weak if required
 163 if "%buildnodeweak%"=="" goto run-tests
 164 "%config%\iojs" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0."
 165 if errorlevel 1 goto build-node-weak-failed
 166 goto run-tests
 167
 168 :build-node-weak-failed
 169 echo Failed to build node-weak.
 170 goto exit
 171
 172 :run-tests
 173 if "%test_args%"=="" goto jslint
 174 if "%config%"=="Debug" set test_args=--mode=debug %test_args%
 175 if "%config%"=="Release" set test_args=--mode=release %test_args%
 176 echo running 'cctest'
 177 "%config%\cctest"
 178 echo running 'python tools/test.py %test_args%'
 179 "%PYTHON%" tools/test.py %test_args%
 180 goto jslint
 181
 182 :jslint
 183 if not defined jslint goto exit
 184 echo running jslint
 185 set PYTHONPATH=tools/closure_linter/;tools/gflags/
 186 "%PYTHON%" tools/closure_linter/closure_linter/gjslint.py --unix_mode --strict --nojsdoc -r lib/ -r src/ --exclude_files lib/punycode.js
 187 goto exit
 188
 189 :create-msvs-files-failed
 190 echo Failed to create vc project files.
 191 goto exit
 192
 193 :help
 194 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [small-icu/full-icu/intl-none] [nobuild] [nosign] [x86/x64] [download-all]
 195 echo Examples:
 196 echo   vcbuild.bat                : builds release build
 197 echo   vcbuild.bat debug          : builds debug build
 198 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 199 echo   vcbuild.bat test           : builds debug build and runs tests
 200 goto exit
 201
 202 :exit
 203 goto :EOF
 204
 205 rem ***************
 206 rem   Subroutines
 207 rem ***************
 208
 209 :getnodeversion
 210 set NODE_VERSION=
 211 for /F "usebackq tokens=*" %%i in (`"%PYTHON%" "%~dp0tools\getnodeversion.py"`) do set NODE_VERSION=%%i
 212 if not defined NODE_VERSION echo Cannot determine current version of io.js & exit /b 1
 213 goto :EOF