vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Debug
  16 set target=Build
  17 set noprojgen=
  18 set nobuild=
  19 set nosign=
  20 set nosnapshot=
  21 set test=
  22 set test_args=
  23 set msi=
  24 set upload=
  25
  26 :next-arg
  27 if "%1"=="" goto args-done
  28 if /i "%1"=="debug"        set config=Debug&goto arg-ok
  29 if /i "%1"=="release"      set config=Release&goto arg-ok
  30 if /i "%1"=="clean"        set target=Clean&goto arg-ok
  31 if /i "%1"=="noprojgen"    set noprojgen=1&goto arg-ok
  32 if /i "%1"=="nobuild"      set nobuild=1&goto arg-ok
  33 if /i "%1"=="nosign"       set nosign=1&goto arg-ok
  34 if /i "%1"=="nosnapshot"   set nosnapshot=1&goto arg-ok
  35 if /i "%1"=="test-uv"      set test=test-uv&goto arg-ok
  36 if /i "%1"=="test-internet"set test=test-internet&goto arg-ok
  37 if /i "%1"=="test-pummel"  set test=test-pummel&goto arg-ok
  38 if /i "%1"=="test-simple"  set test=test-simple&goto arg-ok
  39 if /i "%1"=="test-message" set test=test-message&goto arg-ok
  40 if /i "%1"=="test-all"     set test=test-all&goto arg-ok
  41 if /i "%1"=="test"         set test=test&goto arg-ok
  42 if /i "%1"=="msi"          set msi=1&goto arg-ok
  43 if /i "%1"=="upload"       set upload=1&goto arg-ok
  44
  45
  46 :arg-ok
  47 shift
  48 goto next-arg
  49 :args-done
  50 if defined upload goto upload
  51
  52
  53 :project-gen
  54 @rem Skip project generation if requested.
  55 if defined noprojgen goto msbuild
  56
  57 @rem Generate the VS project.
  58 if defined nosnapshot goto nosnapshotgen
  59 python tools\gyp_node -f msvs -G msvs_version=2010
  60 if errorlevel 1 goto create-msvs-files-failed
  61 if not exist node.sln goto create-msvs-files-failed
  62 echo Project files generated.
  63 goto msbuild
  64
  65 :nosnapshotgen
  66 python tools\gyp_node -f msvs -G msvs_version=2010 -D v8_use_snapshot='false'
  67 if errorlevel 1 goto create-msvs-files-failed
  68 if not exist node.sln goto create-msvs-files-failed
  69 echo Project files generated.
  70
  71 :msbuild
  72 @rem Skip project generation if requested.
  73 if defined nobuild goto msi
  74
  75 @rem Bail out early if not running in VS build env.
  76 if defined VCINSTALLDIR goto msbuild-found
  77 if not defined VS100COMNTOOLS goto msbuild-not-found
  78 if not exist "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
  79 call "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat"
  80 if not defined VCINSTALLDIR goto msbuild-not-found
  81 goto msbuild-found
  82
  83 :msbuild-not-found
  84 echo Build skipped. To build, this file needs to run from VS cmd prompt.
  85 goto run
  86
  87 :msbuild-found
  88 @rem Build the sln with msbuild.
  89 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
  90 if errorlevel 1 goto exit
  91
  92 if defined nosign goto msi
  93 signtool sign /a Release\node.exe
  94
  95 :msi
  96 @rem Skip msi generation if not requested
  97 if not defined msi goto run
  98 python "%~dp0tools\getnodeversion.py" > "%temp%\node_version.txt"
  99 if not errorlevel 0 echo Cannot determine current version of node.js & goto exit
 100 for /F "tokens=*" %%i in (%temp%\node_version.txt) do set NODE_VERSION=%%i
 101 heat dir deps\npm -var var.NPMSourceDir -dr NodeModulesFolder -cg NPMFiles -gg -template fragment -nologo -out npm.wxs
 102 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:Configuration=%config% /p:NodeVersion=%NODE_VERSION% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 103 if errorlevel 1 goto exit
 104
 105 if defined nosign goto run
 106 signtool sign /a Release\node.msi
 107
 108 :run
 109 @rem Run tests if requested.
 110 if "%test%"=="" goto exit
 111
 112 if "%config%"=="Debug" set test_args=--mode=debug
 113 if "%config%"=="Release" set test_args=--mode=release
 114
 115 if "%test%"=="test" set test_args=%test_args% simple message
 116 if "%test%"=="test-internet" set test_args=%test_args% internet
 117 if "%test%"=="test-pummel" set test_args=%test_args% pummel
 118 if "%test%"=="test-simple" set test_args=%test_args% simple
 119 if "%test%"=="test-message" set test_args=%test_args% message
 120 if "%test%"=="test-all" set test_args=%test_args%
 121
 122 echo running 'python tools/test.py %test_args%'
 123 python tools/test.py %test_args%
 124 goto exit
 125
 126 :create-msvs-files-failed
 127 echo Failed to create vc project files.
 128 goto exit
 129
 130 :upload
 131 echo uploading .exe .msi .pdb to nodejs.org
 132 python "%~dp0tools\getnodeversion.py" > "%temp%\node_version.txt"
 133 if not errorlevel 0 echo Cannot determine current version of node.js & goto exit
 134 for /F "tokens=*" %%i in (%temp%\node_version.txt) do set NODE_VERSION=%%i
 135 @echo on
 136 ssh node@nodejs.org mkdir -p web/nodejs.org/dist/v%NODE_VERSION%
 137 scp Release\node.msi node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node-v%NODE_VERSION%.msi
 138 scp Release\node.exe node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.exe
 139 scp Release\node.pdb node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.pdb
 140 @echo off
 141 goto exit
 142
 143 :help
 144 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [nobuild] [nosign]
 145 echo Examples:
 146 echo   vcbuild.bat                : builds debug build
 147 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 148 echo   vcbuild.bat test           : builds debug build and runs tests
 149 goto exit
 150
 151 :exit