vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set target=Build
  17 set target_arch=x86
  18 set debug_arg=
  19 set snapshot_arg=
  20 set noprojgen=
  21 set nobuild=
  22 set nosign=
  23 set nosnapshot=
  24 set test_args=
  25 set msi=
  26 set upload=
  27 set licensertf=
  28 set jslint=
  29 set buildnodeweak=
  30 set noetw=
  31 set noetw_arg=
  32 set noetw_msi_arg=
  33 set noperfctr=
  34 set noperfctr_arg=
  35 set noperfctr_msi_arg=
  36 set i18n_arg=
  37 set download_arg=
  38
  39 :next-arg
  40 if "%1"=="" goto args-done
  41 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  42 if /i "%1"=="release"       set config=Release&goto arg-ok
  43 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  44 if /i "%1"=="ia32"          set target_arch=x86&goto arg-ok
  45 if /i "%1"=="x86"           set target_arch=x86&goto arg-ok
  46 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  47 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  48 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  49 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  50 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  51 if /i "%1"=="noetw"         set noetw=1&goto arg-ok
  52 if /i "%1"=="noperfctr"     set noperfctr=1&goto arg-ok
  53 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  54 if /i "%1"=="test"          set test_args=%test_args% sequential parallel message -J&set jslint=1&goto arg-ok
  55 if /i "%1"=="test-ci"       set test_args=%test_args% -p tap --logfile test.tap message sequential parallel&goto arg-ok
  56 if /i "%1"=="test-simple"   set test_args=%test_args% sequential parallel -J&goto arg-ok
  57 if /i "%1"=="test-message"  set test_args=%test_args% message&goto arg-ok
  58 if /i "%1"=="test-gc"       set test_args=%test_args% gc&set buildnodeweak=1&goto arg-ok
  59 if /i "%1"=="test-internet" set test_args=%test_args% internet&goto arg-ok
  60 if /i "%1"=="test-pummel"   set test_args=%test_args% pummel&goto arg-ok
  61 if /i "%1"=="test-all"      set test_args=%test_args% sequential parallel message gc internet pummel&set buildnodeweak=1&set jslint=1&goto arg-ok
  62 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  63 if /i "%1"=="msi"           set msi=1&set licensertf=1&goto arg-ok
  64 if /i "%1"=="upload"        set upload=1&goto arg-ok
  65 if /i "%1"=="small-icu"     set i18n_arg=%1&goto arg-ok
  66 if /i "%1"=="full-icu"      set i18n_arg=%1&goto arg-ok
  67 if /i "%1"=="intl-none"     set i18n_arg=%1&goto arg-ok
  68 if /i "%1"=="download-all"  set download_arg="--download=all"&goto arg-ok
  69
  70 echo Warning: ignoring invalid command line option `%1`.
  71
  72 :arg-ok
  73 :arg-ok
  74 shift
  75 goto next-arg
  76
  77 :args-done
  78 if "%config%"=="Debug" set debug_arg=--debug
  79 if defined nosnapshot set snapshot_arg=--without-snapshot
  80 if defined noetw set noetw_arg=--without-etw& set noetw_msi_arg=/p:NoETW=1
  81 if defined noperfctr set noperfctr_arg=--without-perfctr& set noperfctr_msi_arg=/p:NoPerfCtr=1
  82
  83 if "%i18n_arg%"=="full-icu" set i18n_arg=--with-intl=full-icu
  84 if "%i18n_arg%"=="small-icu" set i18n_arg=--with-intl=small-icu
  85 if "%i18n_arg%"=="intl-none" set i18n_arg=--with-intl=none
  86
  87 call :getnodeversion || exit /b 1
  88
  89 @rem Set environment for msbuild
  90
  91 @rem Look for Visual Studio 2015
  92 if not defined VS140COMNTOOLS goto vc-set-2013
  93 if not exist "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat" goto vc-set-2013
  94 if "%VCVARS_VER%" NEQ "140" (
  95   call "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat"
  96   SET VCVARS_VER=140
  97 )
  98 if not defined VCINSTALLDIR goto vc-set-2013
  99 set GYP_MSVS_VERSION=2015
 100 goto msbuild-found
 101
 102 :vc-set-2013
 103 @rem Look for Visual Studio 2013
 104 if not defined VS120COMNTOOLS goto msbuild-not-found
 105 if not exist "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
 106 if "%VCVARS_VER%" NEQ "120" (
 107   call "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat"
 108   SET VCVARS_VER=120
 109 )
 110 if not defined VCINSTALLDIR goto msbuild-not-found
 111 set GYP_MSVS_VERSION=2013
 112 goto msbuild-found
 113
 114 :msbuild-not-found
 115 echo Failed to find Visual Studio installation.
 116 goto exit
 117
 118 :msbuild-found
 119
 120 :project-gen
 121 @rem Skip project generation if requested.
 122 if defined noprojgen goto msbuild
 123
 124 @rem Generate the VS project.
 125 python configure %download_arg% %i18n_arg% %debug_arg% %snapshot_arg% %noetw_arg% %noperfctr_arg% --dest-cpu=%target_arch% --tag=%TAG%
 126 if errorlevel 1 goto create-msvs-files-failed
 127 if not exist node.sln goto create-msvs-files-failed
 128 echo Project files generated.
 129
 130 :msbuild
 131 @rem Skip build if requested.
 132 if defined nobuild goto sign
 133
 134 @rem Build the sln with msbuild.
 135 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 136 if errorlevel 1 goto exit
 137 if "%target%" == "Clean" goto exit
 138
 139 :sign
 140 @rem Skip signing if the `nosign` option was specified.
 141 if defined nosign goto licensertf
 142
 143 signtool sign /a /d "io.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\iojs.exe
 144 if errorlevel 1 echo Failed to sign exe&goto exit
 145
 146 :licensertf
 147 @rem Skip license.rtf generation if not requested.
 148 if not defined licensertf goto msi
 149
 150 %config%\iojs tools\license2rtf.js < LICENSE > %config%\license.rtf
 151 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 152
 153 :msi
 154 @rem Skip msi generation if not requested
 155 if not defined msi goto run
 156
 157 :msibuild
 158 echo Building iojs-v%FULLVERSION%-%target_arch%.msi
 159 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:Configuration=%config% /p:Platform=%target_arch% /p:NodeVersion=%NODE_VERSION% /p:FullVersion=%FULLVERSION% /p:DistTypeDir=%DISTTYPEDIR% %noetw_msi_arg% %noperfctr_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 160 if errorlevel 1 goto exit
 161
 162 if defined nosign goto upload
 163 signtool sign /a /d "io.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll iojs-v%FULLVERSION%-%target_arch%.msi
 164 if errorlevel 1 echo Failed to sign msi&goto exit
 165
 166 :upload
 167 @rem Skip upload if not requested
 168 if not defined upload goto run
 169
 170 if not defined SSHCONFIG (
 171   echo SSHCONFIG is not set for upload
 172   exit /b 1
 173 )
 174 if not defined STAGINGSERVER set STAGINGSERVER=iojs-www
 175 ssh -F %SSHCONFIG% %STAGINGSERVER% "mkdir -p staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%"
 176 scp -F %SSHCONFIG% Release\iojs.exe %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/iojs.exe
 177 scp -F %SSHCONFIG% Release\iojs.lib %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/iojs.lib
 178 scp -F %SSHCONFIG% iojs-v%FULLVERSION%-%target_arch%.msi %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/
 179 ssh -F %SSHCONFIG% %STAGINGSERVER% "touch staging/%DISTTYPEDIR%/v%FULLVERSION%/iojs-v%FULLVERSION%-%target_arch%.msi.done staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%.done"
 180
 181 :run
 182 @rem Run tests if requested.
 183
 184 :build-node-weak
 185 @rem Build node-weak if required
 186 if "%buildnodeweak%"=="" goto run-tests
 187 "%config%\iojs" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0."
 188 if errorlevel 1 goto build-node-weak-failed
 189 goto run-tests
 190
 191 :build-node-weak-failed
 192 echo Failed to build node-weak.
 193 goto exit
 194
 195 :run-tests
 196 if "%test_args%"=="" goto jslint
 197 if "%config%"=="Debug" set test_args=--mode=debug %test_args%
 198 if "%config%"=="Release" set test_args=--mode=release %test_args%
 199 echo running 'cctest'
 200 "%config%\cctest"
 201 echo running 'python tools\test.py %test_args%'
 202 python tools\test.py %test_args%
 203 goto jslint
 204
 205 :jslint
 206 if not defined jslint goto exit
 207 echo running jslint
 208 %config%\iojs tools\eslint\bin\eslint.js src lib test --rulesdir tools\eslint-rules --reset --quiet
 209 goto exit
 210
 211 :create-msvs-files-failed
 212 echo Failed to create vc project files.
 213 goto exit
 214
 215 :help
 216 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [small-icu/full-icu/intl-none] [nobuild] [nosign] [x86/x64] [download-all]
 217 echo Examples:
 218 echo   vcbuild.bat                : builds release build
 219 echo   vcbuild.bat debug          : builds debug build
 220 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 221 echo   vcbuild.bat test           : builds debug build and runs tests
 222 goto exit
 223
 224 :exit
 225 goto :EOF
 226
 227 rem ***************
 228 rem   Subroutines
 229 rem ***************
 230
 231 :getnodeversion
 232 set NODE_VERSION=
 233 set TAG=
 234 set FULLVERSION=
 235
 236 for /F "usebackq tokens=*" %%i in (`python "%~dp0tools\getnodeversion.py"`) do set NODE_VERSION=%%i
 237 if not defined NODE_VERSION (
 238   echo Cannot determine current version of io.js
 239   exit /b 1
 240 )
 241
 242 if not defined DISTTYPE set DISTTYPE=release
 243 if "%DISTTYPE%"=="release" (
 244   set FULLVERSION=%NODE_VERSION%
 245   goto exit
 246 )
 247 if "%DISTTYPE%"=="custom" (
 248   if not defined CUSTOMTAG (
 249     echo "CUSTOMTAG is not set for DISTTYPE=custom"
 250     exit /b 1
 251   )
 252   set TAG=%CUSTOMTAG%
 253 )
 254 if not "%DISTTYPE%"=="custom" (
 255   if not defined DATESTRING (
 256     echo "DATESTRING is not set for nightly"
 257     exit /b 1
 258   )
 259   if not defined COMMIT (
 260     echo "COMMIT is not set for nightly"
 261     exit /b 1
 262   )
 263   if not "%DISTTYPE%"=="nightly" (
 264     if not "%DISTTYPE%"=="next-nightly" (
 265       echo "DISTTYPE is not release, custom, nightly or next-nightly"
 266       exit /b 1
 267     )
 268   )
 269   set TAG=%DISTTYPE%%DATESTRING%%COMMIT%
 270 )
 271 set FULLVERSION=%NODE_VERSION%-%TAG%
 272
 273 :exit
 274 if not defined DISTTYPEDIR set DISTTYPEDIR=%DISTTYPE%
 275 goto :EOF