vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set msiplatform=x86
  17 set target=Build
  18 set target_arch=ia32
  19 set debug_arg=
  20 set nosnapshot_arg=
  21 set noprojgen=
  22 set nobuild=
  23 set nosign=
  24 set nosnapshot=
  25 set test=
  26 set test_args=
  27 set msi=
  28 set licensertf=
  29 set upload=
  30 set jslint=
  31 set buildnodeweak=
  32 set noetw=
  33 set noetw_arg=
  34 set noetw_msi_arg=
  35
  36 :next-arg
  37 if "%1"=="" goto args-done
  38 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  39 if /i "%1"=="release"       set config=Release&goto arg-ok
  40 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  41 if /i "%1"=="ia32"          set target_arch=ia32&goto arg-ok
  42 if /i "%1"=="x86"           set target_arch=ia32&goto arg-ok
  43 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  44 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  45 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  46 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  47 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  48 if /i "%1"=="noetw"         set noetw=1&goto arg-ok
  49 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  50 if /i "%1"=="test-uv"       set test=test-uv&goto arg-ok
  51 if /i "%1"=="test-internet" set test=test-internet&goto arg-ok
  52 if /i "%1"=="test-pummel"   set test=test-pummel&goto arg-ok
  53 if /i "%1"=="test-simple"   set test=test-simple&goto arg-ok
  54 if /i "%1"=="test-message"  set test=test-message&goto arg-ok
  55 if /i "%1"=="test-gc"       set test=test-gc&set buildnodeweak=1&goto arg-ok
  56 if /i "%1"=="test-all"      set test=test-all&set buildnodeweak=1&goto arg-ok
  57 if /i "%1"=="test"          set test=test&goto arg-ok
  58 if /i "%1"=="msi"           set msi=1&set licensertf=1&goto arg-ok
  59 if /i "%1"=="upload"        set upload=1&goto arg-ok
  60 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  61
  62 echo Warning: ignoring invalid command line option `%1`.
  63
  64 :arg-ok
  65 shift
  66 goto next-arg
  67
  68 :args-done
  69 if defined upload goto upload
  70 if defined jslint goto jslint
  71
  72 if "%config%"=="Debug" set debug_arg=--debug
  73 if "%target_arch%"=="x64" set msiplatform=x64
  74 if defined nosnapshot set nosnapshot_arg=--without-snapshot
  75 if defined noetw set noetw_arg=--without-etw& set noetw_msi_arg=/p:NoETW=1
  76
  77 :project-gen
  78 @rem Skip project generation if requested.
  79 if defined noprojgen goto msbuild
  80
  81 @rem Generate the VS project.
  82 python configure %debug_arg% %nosnapshot_arg% %noetw_arg% --dest-cpu=%target_arch%
  83 if errorlevel 1 goto create-msvs-files-failed
  84 if not exist node.sln goto create-msvs-files-failed
  85 echo Project files generated.
  86
  87 :msbuild
  88 @rem Skip project generation if requested.
  89 if defined nobuild goto sign
  90
  91 @rem Bail out early if not running in VS build env.
  92 if defined VCINSTALLDIR goto msbuild-found
  93 if not defined VS100COMNTOOLS goto msbuild-not-found
  94 if not exist "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
  95 call "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat"
  96 if not defined VCINSTALLDIR goto msbuild-not-found
  97 goto msbuild-found
  98
  99 :msbuild-not-found
 100 echo Build skipped. To build, this file needs to run from VS cmd prompt.
 101 goto run
 102
 103 :msbuild-found
 104 @rem Build the sln with msbuild.
 105 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 106 if errorlevel 1 goto exit
 107
 108 :sign
 109 @rem Skip signing if the `nosign` option was specified.
 110 if defined nosign goto licensertf
 111
 112 signtool sign /a Release\node.exe
 113
 114 :licensertf
 115 @rem Skip license.rtf generation if not requested.
 116 if not defined licensertf goto msi
 117
 118 %config%\node tools\license2rtf.js < LICENSE > %config%\license.rtf
 119 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 120
 121 :msi
 122 @rem Skip msi generation if not requested
 123 if not defined msi goto run
 124 python "%~dp0tools\getnodeversion.py" > "%temp%\node_version.txt"
 125 if not errorlevel 0 echo Cannot determine current version of node.js & goto exit
 126 for /F "tokens=*" %%i in (%temp%\node_version.txt) do set NODE_VERSION=%%i
 127 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:Configuration=%config% /p:Platform=%msiplatform% /p:NodeVersion=%NODE_VERSION% %noetw_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 128 if errorlevel 1 goto exit
 129
 130 if defined nosign goto run
 131 signtool sign /a Release\node-v%NODE_VERSION%-%msiplatform%.msi
 132
 133 :run
 134 @rem Run tests if requested.
 135 if "%test%"=="" goto exit
 136
 137 if "%config%"=="Debug" set test_args=--mode=debug
 138 if "%config%"=="Release" set test_args=--mode=release
 139
 140 if "%test%"=="test" set test_args=%test_args% simple message
 141 if "%test%"=="test-internet" set test_args=%test_args% internet
 142 if "%test%"=="test-pummel" set test_args=%test_args% pummel
 143 if "%test%"=="test-simple" set test_args=%test_args% simple
 144 if "%test%"=="test-message" set test_args=%test_args% message
 145 if "%test%"=="test-gc" set test_args=%test_args% gc
 146 if "%test%"=="test-all" set test_args=%test_args%
 147
 148 :build-node-weak
 149 @rem Build node-weak if required
 150 if "%buildnodeweak%"=="" goto run-tests
 151 "%config%\node" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0."
 152 if errorlevel 1 goto build-node-weak-failed
 153 goto run-tests
 154
 155 :build-node-weak-failed
 156 echo Failed to build node-weak.
 157 goto exit
 158
 159 :run-tests
 160 echo running 'python tools/test.py %test_args%'
 161 python tools/test.py %test_args%
 162 if "%test%"=="test" goto jslint
 163 goto exit
 164
 165 :create-msvs-files-failed
 166 echo Failed to create vc project files.
 167 goto exit
 168
 169 :upload
 170 echo uploading .exe .msi .pdb to nodejs.org
 171 python "%~dp0tools\getnodeversion.py" > "%temp%\node_version.txt"
 172 if not errorlevel 0 echo Cannot determine current version of node.js & goto exit
 173 for /F "tokens=*" %%i in (%temp%\node_version.txt) do set NODE_VERSION=%%i
 174 @echo on
 175 ssh node@nodejs.org mkdir -p web/nodejs.org/dist/v%NODE_VERSION%
 176 scp Release\node.msi node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node-v%NODE_VERSION%.msi
 177 scp Release\node.exe node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.exe
 178 scp Release\node.pdb node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.pdb
 179 @echo off
 180 goto exit
 181
 182 :jslint
 183 echo running jslint
 184 set PYTHONPATH=tools/closure_linter/
 185 python tools/closure_linter/closure_linter/gjslint.py --unix_mode --strict --nojsdoc -r lib/ -r src/ -r test/ --exclude_files lib/punycode.js
 186 goto exit
 187
 188 :help
 189 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [nobuild] [nosign] [x86/x64]
 190 echo Examples:
 191 echo   vcbuild.bat                : builds release build
 192 echo   vcbuild.bat debug          : builds debug build
 193 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 194 echo   vcbuild.bat test           : builds debug build and runs tests
 195 goto exit
 196
 197 :exit