vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set target=Build
  17 set target_arch=x86
  18 set target_env=
  19 set noprojgen=
  20 set nobuild=
  21 set nosign=
  22 set nosnapshot=
  23 set test_args=
  24 set msi=
  25 set upload=
  26 set licensertf=
  27 set jslint=
  28 set buildnodeweak=
  29 set noetw=
  30 set noetw_msi_arg=
  31 set noperfctr=
  32 set noperfctr_msi_arg=
  33 set i18n_arg=
  34 set download_arg=
  35 set release_urls_arg=
  36 set build_release=
  37 set configure_flags=
  38
  39 :next-arg
  40 if "%1"=="" goto args-done
  41 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  42 if /i "%1"=="release"       set config=Release&goto arg-ok
  43 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  44 if /i "%1"=="ia32"          set target_arch=x86&goto arg-ok
  45 if /i "%1"=="x86"           set target_arch=x86&goto arg-ok
  46 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  47 if /i "%1"=="vc2013"        set target_env=vc2013&goto arg-ok
  48 if /i "%1"=="vc2015"        set target_env=vc2015&goto arg-ok
  49 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  50 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  51 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  52 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  53 if /i "%1"=="noetw"         set noetw=1&goto arg-ok
  54 if /i "%1"=="noperfctr"     set noperfctr=1&goto arg-ok
  55 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  56 if /i "%1"=="test"          set test_args=%test_args% sequential parallel message -J&set jslint=1&goto arg-ok
  57 if /i "%1"=="test-ci"       set test_args=%test_args% %test_ci_args% -p tap --logfile test.tap message sequential parallel&goto arg-ok
  58 if /i "%1"=="test-simple"   set test_args=%test_args% sequential parallel -J&goto arg-ok
  59 if /i "%1"=="test-message"  set test_args=%test_args% message&goto arg-ok
  60 if /i "%1"=="test-gc"       set test_args=%test_args% gc&set buildnodeweak=1&goto arg-ok
  61 if /i "%1"=="test-internet" set test_args=%test_args% internet&goto arg-ok
  62 if /i "%1"=="test-pummel"   set test_args=%test_args% pummel&goto arg-ok
  63 if /i "%1"=="test-all"      set test_args=%test_args% sequential parallel message gc internet pummel&set buildnodeweak=1&set jslint=1&goto arg-ok
  64 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  65 if /i "%1"=="msi"           set msi=1&set licensertf=1&set download_arg="--download=all"&set i18n_arg=small-icu&goto arg-ok
  66 if /i "%1"=="build-release" set build_release=1&goto arg-ok
  67 if /i "%1"=="upload"        set upload=1&goto arg-ok
  68 if /i "%1"=="small-icu"     set i18n_arg=%1&goto arg-ok
  69 if /i "%1"=="full-icu"      set i18n_arg=%1&goto arg-ok
  70 if /i "%1"=="intl-none"     set i18n_arg=%1&goto arg-ok
  71 if /i "%1"=="download-all"  set download_arg="--download=all"&goto arg-ok
  72 if /i "%1"=="ignore-flaky"  set test_args=%test_args% --flaky-tests=dontcare&goto arg-ok
  73
  74 echo Warning: ignoring invalid command line option `%1`.
  75
  76 :arg-ok
  77 :arg-ok
  78 shift
  79 goto next-arg
  80
  81 :args-done
  82
  83 if defined build_release (
  84   set config=Release
  85   set msi=1
  86   set licensertf=1
  87   set download_arg="--download=all"
  88   set i18n_arg=small-icu
  89 )
  90
  91 if "%config%"=="Debug" set configure_flags=%configure_flags% --debug
  92 if defined nosnapshot set configure_flags=%configure_flags% --without-snapshot
  93 if defined noetw set configure_flags=%configure_flags% --without-etw& set noetw_msi_arg=/p:NoETW=1
  94 if defined noperfctr set configure_flags=%configure_flags% --without-perfctr& set noperfctr_msi_arg=/p:NoPerfCtr=1
  95 if defined release_urlbase set release_urlbase_arg=--release-urlbase=%release_urlbase%
  96 if defined download_arg set configure_flags=%configure_flags% %download_arg%
  97
  98 if "%i18n_arg%"=="full-icu" set configure_flags=%configure_flags% --with-intl=full-icu
  99 if "%i18n_arg%"=="small-icu" set configure_flags=%configure_flags% --with-intl=small-icu
 100 if "%i18n_arg%"=="intl-none" set configure_flags=%configure_flags% --with-intl=none
 101
 102 if defined config_flags set configure_flags=%configure_flags% %config_flags%
 103
 104 if not exist "%~dp0deps\icu" goto no-depsicu
 105 if "%target%"=="Clean" echo deleting %~dp0deps\icu
 106 if "%target%"=="Clean" rmdir /S /Q %~dp0deps\icu
 107 :no-depsicu
 108
 109 call :getnodeversion || exit /b 1
 110
 111 @rem Set environment for msbuild
 112
 113 if defined target_env if "%target_env%" NEQ "vc2015" goto vc-set-2013
 114 @rem Look for Visual Studio 2015
 115 echo Looking for Visual Studio 2015
 116 if not defined VS140COMNTOOLS goto vc-set-2013
 117 if not exist "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat" goto vc-set-2013
 118 echo Found Visual Studio 2015
 119 if defined msi (
 120   echo Looking for WiX installation for Visual Studio 2015...
 121   if not exist "%WIX%\SDK\VS2015" (
 122     echo Failed to find WiX install for Visual Studio 2015
 123     echo VS2015 support for WiX is only present starting at version 3.10
 124     goto vc-set-2013
 125   )
 126 )
 127 if "%VCVARS_VER%" NEQ "140" (
 128   call "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat"
 129   SET VCVARS_VER=140
 130 )
 131 if not defined VCINSTALLDIR goto vc-set-2013
 132 set GYP_MSVS_VERSION=2015
 133 set PLATFORM_TOOLSET=v140
 134 goto msbuild-found
 135
 136 :vc-set-2013
 137 if defined target_env if "%target_env%" NEQ "vc2013" goto msbuild-not-found
 138 @rem Look for Visual Studio 2013
 139 echo Looking for Visual Studio 2013
 140 if not defined VS120COMNTOOLS goto msbuild-not-found
 141 if not exist "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
 142 echo Found Visual Studio 2013
 143 if defined msi (
 144   echo Looking for WiX installation for Visual Studio 2013...
 145   if not exist "%WIX%\SDK\VS2013" (
 146     echo Failed to find WiX install for Visual Studio 2013
 147     echo VS2013 support for WiX is only present starting at version 3.8
 148     goto wix-not-found
 149   )
 150 )
 151 if "%VCVARS_VER%" NEQ "120" (
 152   call "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat"
 153   SET VCVARS_VER=120
 154 )
 155 if not defined VCINSTALLDIR goto msbuild-not-found
 156 set GYP_MSVS_VERSION=2013
 157 set PLATFORM_TOOLSET=v120
 158 goto msbuild-found
 159
 160 :msbuild-not-found
 161 echo Failed to find Visual Studio installation.
 162 goto exit
 163
 164 :wix-not-found
 165 echo Build skipped. To generate installer, you need to install Wix.
 166 goto run
 167
 168 :msbuild-found
 169
 170 :project-gen
 171 @rem Skip project generation if requested.
 172 if defined noprojgen goto msbuild
 173
 174 @rem Generate the VS project.
 175 echo configure %configure_flags% --dest-cpu=%target_arch% --tag=%TAG%
 176 python configure %configure_flags% --dest-cpu=%target_arch% --tag=%TAG%
 177 if errorlevel 1 goto create-msvs-files-failed
 178 if not exist node.sln goto create-msvs-files-failed
 179 echo Project files generated.
 180
 181 :msbuild
 182 @rem Skip build if requested.
 183 if defined nobuild goto sign
 184
 185 @rem Build the sln with msbuild.
 186 set "msbplatform=Win32"
 187 if "%target_arch%"=="x64" set "msbplatform=x64"
 188 msbuild node.sln /m /t:%target% /p:Configuration=%config% /p:Platform=%msbplatform% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 189 if errorlevel 1 goto exit
 190 if "%target%" == "Clean" goto exit
 191
 192 :sign
 193 @rem Skip signing if the `nosign` option was specified.
 194 if defined nosign goto licensertf
 195
 196 signtool sign /a /d "Node.js" /du "https://nodejs.org" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\node.exe
 197 if errorlevel 1 echo Failed to sign exe&goto exit
 198
 199 :licensertf
 200 @rem Skip license.rtf generation if not requested.
 201 if not defined licensertf goto msi
 202
 203 %config%\node tools\license2rtf.js < LICENSE > %config%\license.rtf
 204 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 205
 206 :msi
 207 @rem Skip msi generation if not requested
 208 if not defined msi goto run
 209
 210 :msibuild
 211 echo Building node-v%FULLVERSION%-%target_arch%.msi
 212 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:PlatformToolset=%PLATFORM_TOOLSET% /p:GypMsvsVersion=%GYP_MSVS_VERSION% /p:Configuration=%config% /p:Platform=%target_arch% /p:NodeVersion=%NODE_VERSION% /p:FullVersion=%FULLVERSION% /p:DistTypeDir=%DISTTYPEDIR% %noetw_msi_arg% %noperfctr_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 213 if errorlevel 1 goto exit
 214
 215 if defined nosign goto upload
 216 signtool sign /a /d "Node.js" /du "https://nodejs.org" /t http://timestamp.globalsign.com/scripts/timestamp.dll node-v%FULLVERSION%-%target_arch%.msi
 217 if errorlevel 1 echo Failed to sign msi&goto exit
 218
 219 :upload
 220 @rem Skip upload if not requested
 221 if not defined upload goto run
 222
 223 if not defined SSHCONFIG (
 224   echo SSHCONFIG is not set for upload
 225   exit /b 1
 226 )
 227 if not defined STAGINGSERVER set STAGINGSERVER=node-www
 228 ssh -F %SSHCONFIG% %STAGINGSERVER% "mkdir -p nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%"
 229 scp -F %SSHCONFIG% Release\node.exe %STAGINGSERVER%:nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/node.exe
 230 scp -F %SSHCONFIG% Release\node.lib %STAGINGSERVER%:nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/node.lib
 231 scp -F %SSHCONFIG% node-v%FULLVERSION%-%target_arch%.msi %STAGINGSERVER%:nodejs/%DISTTYPEDIR%/v%FULLVERSION%/
 232 ssh -F %SSHCONFIG% %STAGINGSERVER% "touch nodejs/%DISTTYPEDIR%/v%FULLVERSION%/node-v%FULLVERSION%-%target_arch%.msi.done nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%.done && chmod -R ug=rw-x+X,o=r+X nodejs/%DISTTYPEDIR%/v%FULLVERSION%/node-v%FULLVERSION%-%target_arch%.msi* nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%*"
 233
 234 :run
 235 @rem Run tests if requested.
 236
 237 :build-node-weak
 238 @rem Build node-weak if required
 239 if "%buildnodeweak%"=="" goto run-tests
 240 "%config%\node" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0."
 241 if errorlevel 1 goto build-node-weak-failed
 242 goto run-tests
 243
 244 :build-node-weak-failed
 245 echo Failed to build node-weak.
 246 goto exit
 247
 248 :run-tests
 249 if "%test_args%"=="" goto jslint
 250 if "%config%"=="Debug" set test_args=--mode=debug %test_args%
 251 if "%config%"=="Release" set test_args=--mode=release %test_args%
 252 echo running 'cctest'
 253 "%config%\cctest"
 254 echo running 'python tools\test.py %test_args%'
 255 python tools\test.py %test_args%
 256 goto jslint
 257
 258 :jslint
 259 if not defined jslint goto exit
 260 echo running jslint
 261 %config%\node tools\eslint\bin\eslint.js lib src test tools\doc tools\eslint-rules --rulesdir tools\eslint-rules
 262 goto exit
 263
 264 :create-msvs-files-failed
 265 echo Failed to create vc project files.
 266 goto exit
 267
 268 :help
 269
 270 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [small-icu/full-icu/intl-none] [nobuild] [nosign] [x86/x64] [vc2013/vc2015] [download-all]
 271
 272 echo Examples:
 273 echo   vcbuild.bat                : builds release build
 274 echo   vcbuild.bat debug          : builds debug build
 275 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 276 echo   vcbuild.bat test           : builds debug build and runs tests
 277 echo   vcbuild.bat build-release  : builds the release distribution as used by nodejs.org
 278 goto exit
 279
 280 :exit
 281 goto :EOF
 282
 283 rem ***************
 284 rem   Subroutines
 285 rem ***************
 286
 287 :getnodeversion
 288 set NODE_VERSION=
 289 set TAG=
 290 set FULLVERSION=
 291
 292 for /F "usebackq tokens=*" %%i in (`python "%~dp0tools\getnodeversion.py"`) do set NODE_VERSION=%%i
 293 if not defined NODE_VERSION (
 294   echo Cannot determine current version of Node.js
 295   exit /b 1
 296 )
 297
 298 if not defined DISTTYPE set DISTTYPE=release
 299 if "%DISTTYPE%"=="release" (
 300   set FULLVERSION=%NODE_VERSION%
 301   goto exit
 302 )
 303 if "%DISTTYPE%"=="custom" (
 304   if not defined CUSTOMTAG (
 305     echo "CUSTOMTAG is not set for DISTTYPE=custom"
 306     exit /b 1
 307   )
 308   set TAG=%CUSTOMTAG%
 309 )
 310 if not "%DISTTYPE%"=="custom" (
 311   if not defined DATESTRING (
 312     echo "DATESTRING is not set for nightly"
 313     exit /b 1
 314   )
 315   if not defined COMMIT (
 316     echo "COMMIT is not set for nightly"
 317     exit /b 1
 318   )
 319   if not "%DISTTYPE%"=="nightly" (
 320     if not "%DISTTYPE%"=="next-nightly" (
 321       echo "DISTTYPE is not release, custom, nightly or next-nightly"
 322       exit /b 1
 323     )
 324   )
 325   set TAG=%DISTTYPE%%DATESTRING%%COMMIT%
 326 )
 327 set FULLVERSION=%NODE_VERSION%-%TAG%
 328
 329 :exit
 330 if not defined DISTTYPEDIR set DISTTYPEDIR=%DISTTYPE%
 331 goto :EOF