vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set target=Build
  17 set target_arch=x86
  18 set debug_arg=
  19 set snapshot_arg=
  20 set noprojgen=
  21 set nobuild=
  22 set nosign=
  23 set nosnapshot=
  24 set test_args=
  25 set msi=
  26 set upload=
  27 set licensertf=
  28 set jslint=
  29 set buildnodeweak=
  30 set noetw=
  31 set noetw_arg=
  32 set noetw_msi_arg=
  33 set noperfctr=
  34 set noperfctr_arg=
  35 set noperfctr_msi_arg=
  36 set i18n_arg=
  37 set download_arg=
  38
  39 :next-arg
  40 if "%1"=="" goto args-done
  41 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  42 if /i "%1"=="release"       set config=Release&goto arg-ok
  43 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  44 if /i "%1"=="ia32"          set target_arch=x86&goto arg-ok
  45 if /i "%1"=="x86"           set target_arch=x86&goto arg-ok
  46 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  47 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  48 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  49 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  50 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  51 if /i "%1"=="noetw"         set noetw=1&goto arg-ok
  52 if /i "%1"=="noperfctr"     set noperfctr=1&goto arg-ok
  53 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  54 if /i "%1"=="test"          set test_args=%test_args% sequential parallel message -J&set jslint=1&goto arg-ok
  55 if /i "%1"=="test-ci"       set test_args=%test_args% -p tap --logfile test.tap message sequential parallel&goto arg-ok
  56 if /i "%1"=="test-simple"   set test_args=%test_args% sequential parallel -J&goto arg-ok
  57 if /i "%1"=="test-message"  set test_args=%test_args% message&goto arg-ok
  58 if /i "%1"=="test-gc"       set test_args=%test_args% gc&set buildnodeweak=1&goto arg-ok
  59 if /i "%1"=="test-internet" set test_args=%test_args% internet&goto arg-ok
  60 if /i "%1"=="test-pummel"   set test_args=%test_args% pummel&goto arg-ok
  61 if /i "%1"=="test-all"      set test_args=%test_args% sequential parallel message gc internet pummel&set buildnodeweak=1&set jslint=1&goto arg-ok
  62 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  63 if /i "%1"=="msi"           set msi=1&set licensertf=1&goto arg-ok
  64 if /i "%1"=="upload"        set upload=1&goto arg-ok
  65 if /i "%1"=="small-icu"     set i18n_arg=%1&goto arg-ok
  66 if /i "%1"=="full-icu"      set i18n_arg=%1&goto arg-ok
  67 if /i "%1"=="intl-none"     set i18n_arg=%1&goto arg-ok
  68 if /i "%1"=="download-all"  set download_arg="--download=all"&goto arg-ok
  69
  70 echo Warning: ignoring invalid command line option `%1`.
  71
  72 :arg-ok
  73 :arg-ok
  74 shift
  75 goto next-arg
  76
  77 :args-done
  78 if "%config%"=="Debug" set debug_arg=--debug
  79 if defined nosnapshot set snapshot_arg=--without-snapshot
  80 if defined noetw set noetw_arg=--without-etw& set noetw_msi_arg=/p:NoETW=1
  81 if defined noperfctr set noperfctr_arg=--without-perfctr& set noperfctr_msi_arg=/p:NoPerfCtr=1
  82
  83 if "%i18n_arg%"=="full-icu" set i18n_arg=--with-intl=full-icu
  84 if "%i18n_arg%"=="small-icu" set i18n_arg=--with-intl=small-icu
  85 if "%i18n_arg%"=="intl-none" set i18n_arg=--with-intl=none
  86
  87 call :getnodeversion || exit /b 1
  88
  89 @rem Set environment for msbuild
  90 :project-gen
  91 @rem Skip project generation if requested.
  92 if defined noprojgen goto msbuild
  93
  94 @rem Generate the VS project.
  95 SETLOCAL
  96   if defined VS100COMNTOOLS call "%VS100COMNTOOLS%\VCVarsQueryRegistry.bat"
  97   python configure %download_arg% %i18n_arg% %debug_arg% %snapshot_arg% %noetw_arg% %noperfctr_arg% --dest-cpu=%target_arch% --tag=%TAG%
  98   if errorlevel 1 goto create-msvs-files-failed
  99   if not exist node.sln goto create-msvs-files-failed
 100   echo Project files generated.
 101 ENDLOCAL
 102
 103 @rem Look for Visual Studio 2015
 104 if not defined VS140COMNTOOLS goto vc-set-2013
 105 if not exist "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat" goto vc-set-2013
 106 if "%VCVARS_VER%" NEQ "140" (
 107   call "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat"
 108   SET VCVARS_VER=140
 109 )
 110 if not defined VCINSTALLDIR goto vc-set-2013
 111 set GYP_MSVS_VERSION=2015
 112 goto msbuild-found
 113
 114 :vc-set-2013
 115 @rem Look for Visual Studio 2013
 116 if not defined VS120COMNTOOLS goto msbuild-not-found
 117 if not exist "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
 118 if "%VCVARS_VER%" NEQ "120" (
 119   call "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat"
 120   SET VCVARS_VER=120
 121 )
 122 if not defined VCINSTALLDIR goto msbuild-not-found
 123 set GYP_MSVS_VERSION=2013
 124 goto msbuild-found
 125
 126 :msbuild-not-found
 127 echo Failed to find Visual Studio installation.
 128 goto exit
 129
 130 :msbuild-found
 131
 132 :project-gen
 133 @rem Skip project generation if requested.
 134 if defined noprojgen goto msbuild
 135
 136 @rem Generate the VS project.
 137 python configure %download_arg% %i18n_arg% %debug_arg% %snapshot_arg% %noetw_arg% %noperfctr_arg% --dest-cpu=%target_arch% --tag=%TAG%
 138 if errorlevel 1 goto create-msvs-files-failed
 139 if not exist node.sln goto create-msvs-files-failed
 140 echo Project files generated.
 141
 142 :msbuild
 143 @rem Skip build if requested.
 144 if defined nobuild goto sign
 145
 146 @rem Build the sln with msbuild.
 147 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 148 if errorlevel 1 goto exit
 149 if "%target%" == "Clean" goto exit
 150
 151 :sign
 152 @rem Skip signing if the `nosign` option was specified.
 153 if defined nosign goto licensertf
 154
 155 signtool sign /a /d "io.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\iojs.exe
 156 if errorlevel 1 echo Failed to sign exe&goto exit
 157
 158 :licensertf
 159 @rem Skip license.rtf generation if not requested.
 160 if not defined licensertf goto msi
 161
 162 %config%\iojs tools\license2rtf.js < LICENSE > %config%\license.rtf
 163 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 164
 165 :msi
 166 @rem Skip msi generation if not requested
 167 if not defined msi goto run
 168
 169 :msibuild
 170 echo Building iojs-v%FULLVERSION%-%target_arch%.msi
 171 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:Configuration=%config% /p:Platform=%target_arch% /p:NodeVersion=%NODE_VERSION% /p:FullVersion=%FULLVERSION% /p:DistTypeDir=%DISTTYPEDIR% %noetw_msi_arg% %noperfctr_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 172 if errorlevel 1 goto exit
 173
 174 if defined nosign goto upload
 175 signtool sign /a /d "io.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll iojs-v%FULLVERSION%-%target_arch%.msi
 176 if errorlevel 1 echo Failed to sign msi&goto exit
 177
 178 :upload
 179 @rem Skip upload if not requested
 180 if not defined upload goto run
 181
 182 if not defined SSHCONFIG (
 183   echo SSHCONFIG is not set for upload
 184   exit /b 1
 185 )
 186 if not defined STAGINGSERVER set STAGINGSERVER=iojs-www
 187 ssh -F %SSHCONFIG% %STAGINGSERVER% "mkdir -p staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%"
 188 scp -F %SSHCONFIG% Release\iojs.exe %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/iojs.exe
 189 scp -F %SSHCONFIG% Release\iojs.lib %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/iojs.lib
 190 scp -F %SSHCONFIG% iojs-v%FULLVERSION%-%target_arch%.msi %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/
 191 ssh -F %SSHCONFIG% %STAGINGSERVER% "touch staging/%DISTTYPEDIR%/v%FULLVERSION%/iojs-v%FULLVERSION%-%target_arch%.msi.done staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%.done"
 192
 193 :run
 194 @rem Run tests if requested.
 195
 196 :build-node-weak
 197 @rem Build node-weak if required
 198 if "%buildnodeweak%"=="" goto run-tests
 199 "%config%\iojs" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0."
 200 if errorlevel 1 goto build-node-weak-failed
 201 goto run-tests
 202
 203 :build-node-weak-failed
 204 echo Failed to build node-weak.
 205 goto exit
 206
 207 :run-tests
 208 if "%test_args%"=="" goto jslint
 209 if "%config%"=="Debug" set test_args=--mode=debug %test_args%
 210 if "%config%"=="Release" set test_args=--mode=release %test_args%
 211 echo running 'cctest'
 212 "%config%\cctest"
 213 echo running 'python tools\test.py %test_args%'
 214 python tools\test.py %test_args%
 215 goto jslint
 216
 217 :jslint
 218 if not defined jslint goto exit
 219 echo running jslint
 220 %config%\iojs tools\eslint\bin\eslint.js src lib test --rulesdir tools\eslint-rules --reset --quiet
 221 goto exit
 222
 223 :create-msvs-files-failed
 224 echo Failed to create vc project files.
 225 goto exit
 226
 227 :help
 228 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [small-icu/full-icu/intl-none] [nobuild] [nosign] [x86/x64] [download-all]
 229 echo Examples:
 230 echo   vcbuild.bat                : builds release build
 231 echo   vcbuild.bat debug          : builds debug build
 232 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 233 echo   vcbuild.bat test           : builds debug build and runs tests
 234 goto exit
 235
 236 :exit
 237 goto :EOF
 238
 239 rem ***************
 240 rem   Subroutines
 241 rem ***************
 242
 243 :getnodeversion
 244 set NODE_VERSION=
 245 set TAG=
 246 set FULLVERSION=
 247
 248 for /F "usebackq tokens=*" %%i in (`python "%~dp0tools\getnodeversion.py"`) do set NODE_VERSION=%%i
 249 if not defined NODE_VERSION (
 250   echo Cannot determine current version of io.js
 251   exit /b 1
 252 )
 253
 254 if not defined DISTTYPE set DISTTYPE=release
 255 if "%DISTTYPE%"=="release" (
 256   set FULLVERSION=%NODE_VERSION%
 257   goto exit
 258 )
 259 if "%DISTTYPE%"=="custom" (
 260   if not defined CUSTOMTAG (
 261     echo "CUSTOMTAG is not set for DISTTYPE=custom"
 262     exit /b 1
 263   )
 264   set TAG=%CUSTOMTAG%
 265 )
 266 if not "%DISTTYPE%"=="custom" (
 267   if not defined DATESTRING (
 268     echo "DATESTRING is not set for nightly"
 269     exit /b 1
 270   )
 271   if not defined COMMIT (
 272     echo "COMMIT is not set for nightly"
 273     exit /b 1
 274   )
 275   if not "%DISTTYPE%"=="nightly" (
 276     if not "%DISTTYPE%"=="next-nightly" (
 277       echo "DISTTYPE is not release, custom, nightly or next-nightly"
 278       exit /b 1
 279     )
 280   )
 281   set TAG=%DISTTYPE%%DATESTRING%%COMMIT%
 282 )
 283 set FULLVERSION=%NODE_VERSION%-%TAG%
 284
 285 :exit
 286 if not defined DISTTYPEDIR set DISTTYPEDIR=%DISTTYPE%
 287 goto :EOF