vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Debug
  16 set target=Build
  17 set noprojgen=
  18 set nobuild=
  19 set test=
  20 set test_args=
  21 set msi=
  22 set upload=
  23
  24 :next-arg
  25 if "%1"=="" goto args-done
  26 if /i "%1"=="debug"        set config=Debug&goto arg-ok
  27 if /i "%1"=="release"      set config=Release&goto arg-ok
  28 if /i "%1"=="clean"        set target=Clean&goto arg-ok
  29 if /i "%1"=="noprojgen"    set noprojgen=1&goto arg-ok
  30 if /i "%1"=="nobuild"      set nobuild=1&goto arg-ok
  31 if /i "%1"=="test-uv"      set test=test-uv&goto arg-ok
  32 if /i "%1"=="test-internet"set test=test-internet&goto arg-ok
  33 if /i "%1"=="test-pummel"  set test=test-pummel&goto arg-ok
  34 if /i "%1"=="test-simple"  set test=test-simple&goto arg-ok
  35 if /i "%1"=="test-message" set test=test-message&goto arg-ok
  36 if /i "%1"=="test-all"     set test=test-all&goto arg-ok
  37 if /i "%1"=="test"         set test=test&goto arg-ok
  38 if /i "%1"=="msi"          set msi=1&goto arg-ok
  39 if /i "%1"=="upload"       set upload=1&goto arg-ok
  40 :arg-ok
  41 shift
  42 goto next-arg
  43 :args-done
  44 if defined upload goto upload
  45
  46
  47 :project-gen
  48 @rem Skip project generation if requested.
  49 if defined noprojgen goto msbuild
  50
  51 @rem Generate the VS project.
  52 python tools\gyp_node -f msvs -G msvs_version=2010
  53 if errorlevel 1 goto create-msvs-files-failed
  54 if not exist node.sln goto create-msvs-files-failed
  55 echo Project files generated.
  56
  57 :msbuild
  58 @rem Skip project generation if requested.
  59 if defined nobuild goto msi
  60
  61 @rem Bail out early if not running in VS build env.
  62 if defined VCINSTALLDIR goto msbuild-found
  63 if not defined VS100COMNTOOLS goto msbuild-not-found
  64 if not exist "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
  65 call "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat"
  66 if not defined VCINSTALLDIR goto msbuild-not-found
  67 goto msbuild-found
  68
  69 :msbuild-not-found
  70 echo Build skipped. To build, this file needs to run from VS cmd prompt.
  71 goto run
  72
  73 :msbuild-found
  74 @rem Build the sln with msbuild.
  75 msbuild node.sln /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
  76 if errorlevel 1 goto exit
  77
  78 :msi
  79 @rem Skip msi generation if not requested
  80 if not defined msi goto run
  81 python "%~dp0tools\getnodeversion.py" > "%temp%\node_version.txt"
  82 if not errorlevel 0 echo Cannot determine current version of node.js & goto exit
  83 for /F "tokens=*" %%i in (%temp%\node_version.txt) do set NODE_VERSION=%%i
  84 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /t:Clean,Build /p:Configuration=%config% /p:NodeVersion=%NODE_VERSION% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
  85 if errorlevel 1 goto exit
  86
  87 :run
  88 @rem Run tests if requested.
  89 if "%test%"=="" goto exit
  90
  91 if "%config%"=="Debug" set test_args=--mode=debug
  92 if "%config%"=="Release" set test_args=--mode=release
  93
  94 if "%test%"=="test" set test_args=%test_args% simple message
  95 if "%test%"=="test-internet" set test_args=%test_args% internet
  96 if "%test%"=="test-pummel" set test_args=%test_args% pummel
  97 if "%test%"=="test-simple" set test_args=%test_args% simple
  98 if "%test%"=="test-message" set test_args=%test_args% message
  99 if "%test%"=="test-all" set test_args=%test_args%
 100
 101 echo running 'python tools/test.py %test_args%'
 102 python tools/test.py %test_args%
 103 goto exit
 104
 105 :create-msvs-files-failed
 106 echo Failed to create vc project files.
 107 goto exit
 108
 109 :upload
 110 echo uploading .exe .msi .pdb to nodejs.org
 111 python "%~dp0tools\getnodeversion.py" > "%temp%\node_version.txt"
 112 if not errorlevel 0 echo Cannot determine current version of node.js & goto exit
 113 for /F "tokens=*" %%i in (%temp%\node_version.txt) do set NODE_VERSION=%%i
 114 @echo on
 115 ssh node@nodejs.org mkdir -p web/nodejs.org/dist/v%NODE_VERSION%
 116 scp Release\node.msi node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node-%NODE_VERSION%.msi
 117 scp Release\node.exe node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.exe
 118 scp Release\node.pdb node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.pdb
 119 @echo off
 120 goto exit
 121
 122 :help
 123 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [nobuild]
 124 echo Examples:
 125 echo   vcbuild.bat                : builds debug build
 126 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 127 echo   vcbuild.bat test           : builds debug build and runs tests
 128 goto exit
 129
 130 :exit