vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set msiplatform=x86
  17 set target=Build
  18 set target_arch=ia32
  19 set debug_arg=
  20 set snapshot_arg=
  21 set noprojgen=
  22 set nobuild=
  23 set nosign=
  24 set snapshot=
  25 set test_args=
  26 set msi=
  27 set licensertf=
  28 set jslint=
  29 set buildnodeweak=
  30 set noetw=
  31 set noetw_arg=
  32 set noetw_msi_arg=
  33 set noperfctr=
  34 set noperfctr_arg=
  35 set noperfctr_msi_arg=
  36 set i18n_arg=
  37 set download_arg=
  38
  39 :next-arg
  40 if "%1"=="" goto args-done
  41 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  42 if /i "%1"=="release"       set config=Release&goto arg-ok
  43 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  44 if /i "%1"=="ia32"          set target_arch=ia32&goto arg-ok
  45 if /i "%1"=="x86"           set target_arch=ia32&goto arg-ok
  46 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  47 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  48 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  49 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  50 if /i "%1"=="snapshot"      set snapshot=1&goto arg-ok
  51 if /i "%1"=="noetw"         set noetw=1&goto arg-ok
  52 if /i "%1"=="noperfctr"     set noperfctr=1&goto arg-ok
  53 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  54 if /i "%1"=="test"          set test_args=%test_args% sequential parallel message -J&set jslint=1&goto arg-ok
  55 if /i "%1"=="test-ci"       set test_args=%test_args% -p tap --logfile test.tap message sequential parallel&set jslint=1&goto arg-ok
  56 if /i "%1"=="test-simple"   set test_args=%test_args% sequential parallel -J&goto arg-ok
  57 if /i "%1"=="test-message"  set test_args=%test_args% message&goto arg-ok
  58 if /i "%1"=="test-gc"       set test_args=%test_args% gc&set buildnodeweak=1&goto arg-ok
  59 if /i "%1"=="test-internet" set test_args=%test_args% internet&goto arg-ok
  60 if /i "%1"=="test-pummel"   set test_args=%test_args% pummel&goto arg-ok
  61 if /i "%1"=="test-all"      set test_args=%test_args% sequential parallel message gc internet pummel&set buildnodeweak=1&set jslint=1&goto arg-ok
  62 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  63 if /i "%1"=="msi"           set msi=1&set licensertf=1&goto arg-ok
  64 if /i "%1"=="small-icu"     set i18n_arg=%1&goto arg-ok
  65 if /i "%1"=="full-icu"      set i18n_arg=%1&goto arg-ok
  66 if /i "%1"=="intl-none"     set i18n_arg=%1&goto arg-ok
  67 if /i "%1"=="download-all"  set download_arg="--download=all"&goto arg-ok
  68
  69 echo Warning: ignoring invalid command line option `%1`.
  70
  71 :arg-ok
  72 :arg-ok
  73 shift
  74 goto next-arg
  75
  76 :args-done
  77 if "%config%"=="Debug" set debug_arg=--debug
  78 if "%target_arch%"=="x64" set msiplatform=x64
  79 if defined snapshot set snapshot_arg=--with-snapshot
  80 if defined noetw set noetw_arg=--without-etw& set noetw_msi_arg=/p:NoETW=1
  81 if defined noperfctr set noperfctr_arg=--without-perfctr& set noperfctr_msi_arg=/p:NoPerfCtr=1
  82
  83 if "%i18n_arg%"=="full-icu" set i18n_arg=--with-intl=full-icu
  84 if "%i18n_arg%"=="small-icu" set i18n_arg=--with-intl=small-icu
  85 if "%i18n_arg%"=="intl-none" set i18n_arg=--with-intl=none
  86
  87 :project-gen
  88 @rem Skip project generation if requested.
  89 if defined noprojgen goto msbuild
  90
  91 if defined NIGHTLY set TAG=nightly-%NIGHTLY%
  92
  93 @rem Generate the VS project.
  94 SETLOCAL
  95   if defined VS100COMNTOOLS call "%VS100COMNTOOLS%\VCVarsQueryRegistry.bat"
  96   python configure %download_arg% %i18n_arg% %debug_arg% %snapshot_arg% %noetw_arg% %noperfctr_arg% --dest-cpu=%target_arch% --tag=%TAG%
  97   if errorlevel 1 goto create-msvs-files-failed
  98   if not exist node.sln goto create-msvs-files-failed
  99   echo Project files generated.
 100 ENDLOCAL
 101
 102 :msbuild
 103 @rem Skip project generation if requested.
 104 if defined nobuild goto sign
 105
 106 @rem Look for Visual Studio 2013
 107 if not defined VS120COMNTOOLS goto msbuild-not-found
 108 if not exist "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
 109 if "%VCVARS_VER%" NEQ "120" (
 110   call "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat"
 111   SET VCVARS_VER=120
 112 )
 113 if not defined VCINSTALLDIR goto msbuild-not-found
 114 set GYP_MSVS_VERSION=2013
 115 goto msbuild-found
 116
 117 :msbuild-not-found
 118 echo Build skipped. To build, this file needs to run from VS cmd prompt.
 119 goto run
 120
 121 :msbuild-found
 122 @rem Build the sln with msbuild.
 123 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 124 if errorlevel 1 goto exit
 125
 126 :sign
 127 @rem Skip signing if the `nosign` option was specified.
 128 if defined nosign goto licensertf
 129
 130 signtool sign /a /d "io.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\iojs.exe
 131 if errorlevel 1 echo Failed to sign exe&goto exit
 132
 133 :licensertf
 134 @rem Skip license.rtf generation if not requested.
 135 if not defined licensertf goto msi
 136
 137 %config%\iojs tools\license2rtf.js < LICENSE > %config%\license.rtf
 138 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 139
 140 :msi
 141 @rem Skip msi generation if not requested
 142 if not defined msi goto run
 143 call :getnodeversion
 144
 145 if not defined NIGHTLY goto msibuild
 146 set NODE_VERSION=%NODE_VERSION%.%NIGHTLY%
 147
 148 :msibuild
 149 echo Building iojs-%NODE_VERSION%
 150 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:Configuration=%config% /p:Platform=%msiplatform% /p:NodeVersion=%NODE_VERSION% %noetw_msi_arg% %noperfctr_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 151 if errorlevel 1 goto exit
 152
 153 if defined nosign goto run
 154 signtool sign /a /d "io.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\iojs-v%NODE_VERSION%-%msiplatform%.msi
 155 if errorlevel 1 echo Failed to sign msi&goto exit
 156
 157 :run
 158 @rem Run tests if requested.
 159
 160 :build-node-weak
 161 @rem Build node-weak if required
 162 if "%buildnodeweak%"=="" goto run-tests
 163 "%config%\iojs" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0."
 164 if errorlevel 1 goto build-node-weak-failed
 165 goto run-tests
 166
 167 :build-node-weak-failed
 168 echo Failed to build node-weak.
 169 goto exit
 170
 171 :run-tests
 172 if "%test_args%"=="" goto jslint
 173 if "%config%"=="Debug" set test_args=--mode=debug %test_args%
 174 if "%config%"=="Release" set test_args=--mode=release %test_args%
 175 echo running 'cctest'
 176 "%config%\cctest"
 177 echo running 'python tools/test.py %test_args%'
 178 python tools/test.py %test_args%
 179 goto jslint
 180
 181 :jslint
 182 if not defined jslint goto exit
 183 echo running jslint
 184 set PYTHONPATH=tools/closure_linter/;tools/gflags/
 185 python tools/closure_linter/closure_linter/gjslint.py --unix_mode --strict --nojsdoc -r lib/ -r src/ --exclude_files lib/punycode.js
 186 goto exit
 187
 188 :create-msvs-files-failed
 189 echo Failed to create vc project files.
 190 goto exit
 191
 192 :help
 193 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [small-icu/full-icu/intl-none] [nobuild] [nosign] [x86/x64] [download-all]
 194 echo Examples:
 195 echo   vcbuild.bat                : builds release build
 196 echo   vcbuild.bat debug          : builds debug build
 197 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 198 echo   vcbuild.bat test           : builds debug build and runs tests
 199 goto exit
 200
 201 :exit
 202 goto :EOF
 203
 204 rem ***************
 205 rem   Subroutines
 206 rem ***************
 207
 208 :getnodeversion
 209 set NODE_VERSION=
 210 for /F "usebackq tokens=*" %%i in (`python "%~dp0tools\getnodeversion.py"`) do set NODE_VERSION=%%i
 211 if not defined NODE_VERSION echo Cannot determine current version of io.js & exit /b 1
 212 goto :EOF