vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set target=Build
  17 set target_arch=ia32
  18 set debug_arg=
  19 set nosnapshot_arg=
  20 set noprojgen=
  21 set nobuild=
  22 set nosign=
  23 set nosnapshot=
  24 set test=
  25 set test_args=
  26 set msi=
  27 set licensertf=
  28 set upload=
  29 set jslint=
  30
  31 :next-arg
  32 if "%1"=="" goto args-done
  33 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  34 if /i "%1"=="release"       set config=Release&goto arg-ok
  35 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  36 if /i "%1"=="ia32"          set target_arch=ia32&goto arg-ok
  37 if /i "%1"=="x86"           set target_arch=ia32&goto arg-ok
  38 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  39 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  40 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  41 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  42 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  43 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  44 if /i "%1"=="test-uv"       set test=test-uv&goto arg-ok
  45 if /i "%1"=="test-internet" set test=test-internet&goto arg-ok
  46 if /i "%1"=="test-pummel"   set test=test-pummel&goto arg-ok
  47 if /i "%1"=="test-simple"   set test=test-simple&goto arg-ok
  48 if /i "%1"=="test-message"  set test=test-message&goto arg-ok
  49 if /i "%1"=="test-all"      set test=test-all&goto arg-ok
  50 if /i "%1"=="test"          set test=test&goto arg-ok
  51 if /i "%1"=="msi"           set msi=1&set licensertf=1&goto arg-ok
  52 if /i "%1"=="upload"        set upload=1&goto arg-ok
  53 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  54
  55 echo Warning: ignoring invalid command line option `%1`.
  56
  57 :arg-ok
  58 shift
  59 goto next-arg
  60 :args-done
  61 if defined upload goto upload
  62 if defined jslint goto jslint
  63
  64 if "%config%"=="Debug" set debug_arg=--debug
  65 if defined nosnapshot set nosnapshot_arg=--without-snapshot
  66
  67 :project-gen
  68 @rem Skip project generation if requested.
  69 if defined noprojgen goto msbuild
  70
  71 @rem Generate the VS project.
  72 python configure %debug_arg% %nosnapshot_arg% --dest-cpu=%target_arch%
  73 if errorlevel 1 goto create-msvs-files-failed
  74 if not exist node.sln goto create-msvs-files-failed
  75 echo Project files generated.
  76
  77 :msbuild
  78 @rem Skip project generation if requested.
  79 if defined nobuild goto sign
  80
  81 @rem Bail out early if not running in VS build env.
  82 if defined VCINSTALLDIR goto msbuild-found
  83 if not defined VS100COMNTOOLS goto msbuild-not-found
  84 if not exist "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
  85 call "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat"
  86 if not defined VCINSTALLDIR goto msbuild-not-found
  87 goto msbuild-found
  88
  89 :msbuild-not-found
  90 echo Build skipped. To build, this file needs to run from VS cmd prompt.
  91 goto run
  92
  93 :msbuild-found
  94 @rem Build the sln with msbuild.
  95 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
  96 if errorlevel 1 goto exit
  97
  98 :sign
  99 @rem Skip signing if the `nosign` option was specified.
 100 if defined nosign goto licensertf
 101
 102 signtool sign /a Release\node.exe
 103
 104 :licensertf
 105 @rem Skip license.rtf generation if not requested.
 106 if not defined licensertf goto msi
 107
 108 %config%\node tools\license2rtf.js < LICENSE > %config%\license.rtf
 109 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 110
 111 :msi
 112 @rem Skip msi generation if not requested
 113 if not defined msi goto run
 114 python "%~dp0tools\getnodeversion.py" > "%temp%\node_version.txt"
 115 if not errorlevel 0 echo Cannot determine current version of node.js & goto exit
 116 for /F "tokens=*" %%i in (%temp%\node_version.txt) do set NODE_VERSION=%%i
 117 heat dir deps\npm -var var.NPMSourceDir -dr NodeModulesFolder -cg NPMFiles -gg -template fragment -nologo -out npm.wxs
 118 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:Configuration=%config% /p:NodeVersion=%NODE_VERSION% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 119 if errorlevel 1 goto exit
 120
 121 if defined nosign goto run
 122 signtool sign /a Release\node.msi
 123
 124 :run
 125 @rem Run tests if requested.
 126 if "%test%"=="" goto exit
 127
 128 if "%config%"=="Debug" set test_args=--mode=debug
 129 if "%config%"=="Release" set test_args=--mode=release
 130
 131 if "%test%"=="test" set test_args=%test_args% simple message
 132 if "%test%"=="test-internet" set test_args=%test_args% internet
 133 if "%test%"=="test-pummel" set test_args=%test_args% pummel
 134 if "%test%"=="test-simple" set test_args=%test_args% simple
 135 if "%test%"=="test-message" set test_args=%test_args% message
 136 if "%test%"=="test-all" set test_args=%test_args%
 137
 138 echo running 'python tools/test.py %test_args%'
 139 python tools/test.py %test_args%
 140
 141 if "%test%"=="test" goto jslint
 142
 143 goto exit
 144
 145 :create-msvs-files-failed
 146 echo Failed to create vc project files.
 147 goto exit
 148
 149 :upload
 150 echo uploading .exe .msi .pdb to nodejs.org
 151 python "%~dp0tools\getnodeversion.py" > "%temp%\node_version.txt"
 152 if not errorlevel 0 echo Cannot determine current version of node.js & goto exit
 153 for /F "tokens=*" %%i in (%temp%\node_version.txt) do set NODE_VERSION=%%i
 154 @echo on
 155 ssh node@nodejs.org mkdir -p web/nodejs.org/dist/v%NODE_VERSION%
 156 scp Release\node.msi node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node-v%NODE_VERSION%.msi
 157 scp Release\node.exe node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.exe
 158 scp Release\node.pdb node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.pdb
 159 @echo off
 160 goto exit
 161
 162 :jslint
 163 echo running jslint
 164 set PYTHONPATH=tools/closure_linter/
 165 python tools/closure_linter/closure_linter/gjslint.py --unix_mode --strict --nojsdoc -r lib/ -r src/ -r test/ --exclude_files lib/punycode.js
 166 goto exit
 167
 168 :help
 169 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [nobuild] [nosign]
 170 echo Examples:
 171 echo   vcbuild.bat                : builds release build
 172 echo   vcbuild.bat debug          : builds debug build
 173 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 174 echo   vcbuild.bat test           : builds debug build and runs tests
 175 goto exit
 176
 177 :exit