vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set target=Build
  17 set target_arch=x86
  18 set noprojgen=
  19 set nobuild=
  20 set nosign=
  21 set nosnapshot=
  22 set test_args=
  23 set msi=
  24 set upload=
  25 set licensertf=
  26 set jslint=
  27 set buildnodeweak=
  28 set noetw=
  29 set noetw_msi_arg=
  30 set noperfctr=
  31 set noperfctr_msi_arg=
  32 set i18n_arg=
  33 set download_arg=
  34 set release_urls_arg=
  35 set build_release=
  36 set configure_flags=
  37
  38 :next-arg
  39 if "%1"=="" goto args-done
  40 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  41 if /i "%1"=="release"       set config=Release&goto arg-ok
  42 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  43 if /i "%1"=="ia32"          set target_arch=x86&goto arg-ok
  44 if /i "%1"=="x86"           set target_arch=x86&goto arg-ok
  45 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  46 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  47 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  48 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  49 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  50 if /i "%1"=="noetw"         set noetw=1&goto arg-ok
  51 if /i "%1"=="noperfctr"     set noperfctr=1&goto arg-ok
  52 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  53 if /i "%1"=="test"          set test_args=%test_args% sequential parallel message -J&set jslint=1&goto arg-ok
  54 if /i "%1"=="test-ci"       set test_args=%test_args% %test_ci_args% -p tap --logfile test.tap message sequential parallel&goto arg-ok
  55 if /i "%1"=="test-simple"   set test_args=%test_args% sequential parallel -J&goto arg-ok
  56 if /i "%1"=="test-message"  set test_args=%test_args% message&goto arg-ok
  57 if /i "%1"=="test-gc"       set test_args=%test_args% gc&set buildnodeweak=1&goto arg-ok
  58 if /i "%1"=="test-internet" set test_args=%test_args% internet&goto arg-ok
  59 if /i "%1"=="test-pummel"   set test_args=%test_args% pummel&goto arg-ok
  60 if /i "%1"=="test-all"      set test_args=%test_args% sequential parallel message gc internet pummel&set buildnodeweak=1&set jslint=1&goto arg-ok
  61 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  62 if /i "%1"=="msi"           set msi=1&set licensertf=1&set download_arg="--download=all"&set i18n_arg=small-icu&goto arg-ok
  63 if /i "%1"=="build-release" set build_release=1&goto arg-ok
  64 if /i "%1"=="upload"        set upload=1&goto arg-ok
  65 if /i "%1"=="small-icu"     set i18n_arg=%1&goto arg-ok
  66 if /i "%1"=="full-icu"      set i18n_arg=%1&goto arg-ok
  67 if /i "%1"=="intl-none"     set i18n_arg=%1&goto arg-ok
  68 if /i "%1"=="download-all"  set download_arg="--download=all"&goto arg-ok
  69 if /i "%1"=="ignore-flaky"  set test_args=%test_args% --flaky-tests=dontcare&goto arg-ok
  70
  71 echo Warning: ignoring invalid command line option `%1`.
  72
  73 :arg-ok
  74 :arg-ok
  75 shift
  76 goto next-arg
  77
  78 :args-done
  79
  80 if defined build_release (
  81   set config=Release
  82   set msi=1
  83   set licensertf=1
  84   set download_arg="--download=all"
  85   set i18n_arg=small-icu
  86 )
  87
  88 if "%config%"=="Debug" set configure_flags=%configure_flags% --debug
  89 if defined nosnapshot set configure_flags=%configure_flags% --without-snapshot
  90 if defined noetw set configure_flags=%configure_flags% --without-etw& set noetw_msi_arg=/p:NoETW=1
  91 if defined noperfctr set configure_flags=%configure_flags% --without-perfctr& set noperfctr_msi_arg=/p:NoPerfCtr=1
  92 if defined release_urlbase set release_urlbase_arg=--release-urlbase=%release_urlbase%
  93 if defined download_arg set configure_flags=%configure_flags% %download_arg%
  94
  95 if "%i18n_arg%"=="full-icu" set configure_flags=%configure_flags% --with-intl=full-icu
  96 if "%i18n_arg%"=="small-icu" set configure_flags=%configure_flags% --with-intl=small-icu
  97 if "%i18n_arg%"=="intl-none" set configure_flags=%configure_flags% --with-intl=none
  98
  99 if defined config_flags set configure_flags=%configure_flags% %config_flags%
 100
 101 if not exist "%~dp0deps\icu" goto no-depsicu
 102 if "%target%"=="Clean" echo deleting %~dp0deps\icu
 103 if "%target%"=="Clean" rmdir /S /Q %~dp0deps\icu
 104 :no-depsicu
 105
 106 call :getnodeversion || exit /b 1
 107
 108 @rem Set environment for msbuild
 109
 110 @rem Look for Visual Studio 2015
 111 echo Looking for Visual Studio 2015
 112 if not defined VS140COMNTOOLS goto vc-set-2013
 113 if not exist "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat" goto vc-set-2013
 114 echo Found Visual Studio 2015
 115 if defined msi (
 116   echo Looking for WiX installation for Visual Studio 2015...
 117   if not exist "%WIX%\SDK\VS2015" (
 118     echo Failed to find WiX install for Visual Studio 2015
 119     echo VS2015 support for WiX is only present starting at version 3.10
 120     goto vc-set-2013
 121   )
 122 )
 123 if "%VCVARS_VER%" NEQ "140" (
 124   call "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat"
 125   SET VCVARS_VER=140
 126 )
 127 if not defined VCINSTALLDIR goto vc-set-2013
 128 set GYP_MSVS_VERSION=2015
 129 set PLATFORM_TOOLSET=v140
 130 goto msbuild-found
 131
 132 :vc-set-2013
 133 @rem Look for Visual Studio 2013
 134 echo Looking for Visual Studio 2013
 135 if not defined VS120COMNTOOLS goto msbuild-not-found
 136 if not exist "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
 137 echo Found Visual Studio 2013
 138 if defined msi (
 139   echo Looking for WiX installation for Visual Studio 2013...
 140   if not exist "%WIX%\SDK\VS2013" (
 141     echo Failed to find WiX install for Visual Studio 2013
 142     echo VS2013 support for WiX is only present starting at version 3.8
 143     goto vc-set-2012
 144   )
 145 )
 146 if "%VCVARS_VER%" NEQ "120" (
 147   call "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat"
 148   SET VCVARS_VER=120
 149 )
 150 if not defined VCINSTALLDIR goto msbuild-not-found
 151 set GYP_MSVS_VERSION=2013
 152 set PLATFORM_TOOLSET=v120
 153 goto msbuild-found
 154
 155 :msbuild-not-found
 156 echo Failed to find Visual Studio installation.
 157 goto exit
 158
 159 :wix-not-found
 160 echo Build skipped. To generate installer, you need to install Wix.
 161 goto run
 162
 163 :msbuild-found
 164
 165 :project-gen
 166 @rem Skip project generation if requested.
 167 if defined noprojgen goto msbuild
 168
 169 @rem Generate the VS project.
 170 echo configure %configure_flags% --dest-cpu=%target_arch% --tag=%TAG%
 171 python configure %configure_flags% --dest-cpu=%target_arch% --tag=%TAG%
 172 if errorlevel 1 goto create-msvs-files-failed
 173 if not exist node.sln goto create-msvs-files-failed
 174 echo Project files generated.
 175
 176 :msbuild
 177 @rem Skip build if requested.
 178 if defined nobuild goto sign
 179
 180 @rem Build the sln with msbuild.
 181 set "msbplatform=Win32"
 182 if "%target_arch%"=="x64" set "msbplatform=x64"
 183 msbuild node.sln /m /t:%target% /p:Configuration=%config% /p:Platform=%msbplatform% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 184 if errorlevel 1 goto exit
 185 if "%target%" == "Clean" goto exit
 186
 187 :sign
 188 @rem Skip signing if the `nosign` option was specified.
 189 if defined nosign goto licensertf
 190
 191 signtool sign /a /d "Node.js" /du "https://nodejs.org" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\node.exe
 192 if errorlevel 1 echo Failed to sign exe&goto exit
 193
 194 :licensertf
 195 @rem Skip license.rtf generation if not requested.
 196 if not defined licensertf goto msi
 197
 198 %config%\node tools\license2rtf.js < LICENSE > %config%\license.rtf
 199 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 200
 201 :msi
 202 @rem Skip msi generation if not requested
 203 if not defined msi goto run
 204
 205 :msibuild
 206 echo Building node-v%FULLVERSION%-%target_arch%.msi
 207 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:PlatformToolset=%PLATFORM_TOOLSET% /p:GypMsvsVersion=%GYP_MSVS_VERSION% /p:Configuration=%config% /p:Platform=%target_arch% /p:NodeVersion=%NODE_VERSION% /p:FullVersion=%FULLVERSION% /p:DistTypeDir=%DISTTYPEDIR% %noetw_msi_arg% %noperfctr_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 208 if errorlevel 1 goto exit
 209
 210 if defined nosign goto upload
 211 signtool sign /a /d "Node.js" /du "https://nodejs.org" /t http://timestamp.globalsign.com/scripts/timestamp.dll node-v%FULLVERSION%-%target_arch%.msi
 212 if errorlevel 1 echo Failed to sign msi&goto exit
 213
 214 :upload
 215 @rem Skip upload if not requested
 216 if not defined upload goto run
 217
 218 if not defined SSHCONFIG (
 219   echo SSHCONFIG is not set for upload
 220   exit /b 1
 221 )
 222 if not defined STAGINGSERVER set STAGINGSERVER=node-www
 223 ssh -F %SSHCONFIG% %STAGINGSERVER% "mkdir -p nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%"
 224 scp -F %SSHCONFIG% Release\node.exe %STAGINGSERVER%:nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/node.exe
 225 scp -F %SSHCONFIG% Release\node.lib %STAGINGSERVER%:nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/node.lib
 226 scp -F %SSHCONFIG% node-v%FULLVERSION%-%target_arch%.msi %STAGINGSERVER%:nodejs/%DISTTYPEDIR%/v%FULLVERSION%/
 227 ssh -F %SSHCONFIG% %STAGINGSERVER% "touch nodejs/%DISTTYPEDIR%/v%FULLVERSION%/node-v%FULLVERSION%-%target_arch%.msi.done nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%.done && chmod -R ug=rw-x+X,o=r+X nodejs/%DISTTYPEDIR%/v%FULLVERSION%/node-v%FULLVERSION%-%target_arch%.msi* nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%*"
 228
 229 :run
 230 @rem Run tests if requested.
 231
 232 :build-node-weak
 233 @rem Build node-weak if required
 234 if "%buildnodeweak%"=="" goto run-tests
 235 "%config%\node" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0."
 236 if errorlevel 1 goto build-node-weak-failed
 237 goto run-tests
 238
 239 :build-node-weak-failed
 240 echo Failed to build node-weak.
 241 goto exit
 242
 243 :run-tests
 244 if "%test_args%"=="" goto jslint
 245 if "%config%"=="Debug" set test_args=--mode=debug %test_args%
 246 if "%config%"=="Release" set test_args=--mode=release %test_args%
 247 echo running 'cctest'
 248 "%config%\cctest"
 249 echo running 'python tools\test.py %test_args%'
 250 python tools\test.py %test_args%
 251 goto jslint
 252
 253 :jslint
 254 if not defined jslint goto exit
 255 echo running jslint
 256 %config%\node tools\eslint\bin\eslint.js lib src test tools\doc tools\eslint-rules --rulesdir tools\eslint-rules --quiet
 257 goto exit
 258
 259 :create-msvs-files-failed
 260 echo Failed to create vc project files.
 261 goto exit
 262
 263 :help
 264 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [small-icu/full-icu/intl-none] [nobuild] [nosign] [x86/x64] [download-all]
 265 echo Examples:
 266 echo   vcbuild.bat                : builds release build
 267 echo   vcbuild.bat debug          : builds debug build
 268 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 269 echo   vcbuild.bat test           : builds debug build and runs tests
 270 echo   vcbuild.bat build-release  : builds the release distribution as used by nodejs.org
 271 goto exit
 272
 273 :exit
 274 goto :EOF
 275
 276 rem ***************
 277 rem   Subroutines
 278 rem ***************
 279
 280 :getnodeversion
 281 set NODE_VERSION=
 282 set TAG=
 283 set FULLVERSION=
 284
 285 for /F "usebackq tokens=*" %%i in (`python "%~dp0tools\getnodeversion.py"`) do set NODE_VERSION=%%i
 286 if not defined NODE_VERSION (
 287   echo Cannot determine current version of Node.js
 288   exit /b 1
 289 )
 290
 291 if not defined DISTTYPE set DISTTYPE=release
 292 if "%DISTTYPE%"=="release" (
 293   set FULLVERSION=%NODE_VERSION%
 294   goto exit
 295 )
 296 if "%DISTTYPE%"=="custom" (
 297   if not defined CUSTOMTAG (
 298     echo "CUSTOMTAG is not set for DISTTYPE=custom"
 299     exit /b 1
 300   )
 301   set TAG=%CUSTOMTAG%
 302 )
 303 if not "%DISTTYPE%"=="custom" (
 304   if not defined DATESTRING (
 305     echo "DATESTRING is not set for nightly"
 306     exit /b 1
 307   )
 308   if not defined COMMIT (
 309     echo "COMMIT is not set for nightly"
 310     exit /b 1
 311   )
 312   if not "%DISTTYPE%"=="nightly" (
 313     if not "%DISTTYPE%"=="next-nightly" (
 314       echo "DISTTYPE is not release, custom, nightly or next-nightly"
 315       exit /b 1
 316     )
 317   )
 318   set TAG=%DISTTYPE%%DATESTRING%%COMMIT%
 319 )
 320 set FULLVERSION=%NODE_VERSION%-%TAG%
 321
 322 :exit
 323 if not defined DISTTYPEDIR set DISTTYPEDIR=%DISTTYPE%
 324 goto :EOF