vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set target=Build
  17 set target_arch=x86
  18 set debug_arg=
  19 set snapshot_arg=
  20 set noprojgen=
  21 set nobuild=
  22 set nosign=
  23 set nosnapshot=
  24 set test_args=
  25 set msi=
  26 set upload=
  27 set licensertf=
  28 set jslint=
  29 set buildnodeweak=
  30 set noetw=
  31 set noetw_arg=
  32 set noetw_msi_arg=
  33 set noperfctr=
  34 set noperfctr_arg=
  35 set noperfctr_msi_arg=
  36 set i18n_arg=
  37 set download_arg=
  38 set release_urls_arg=
  39
  40 :next-arg
  41 if "%1"=="" goto args-done
  42 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  43 if /i "%1"=="release"       set config=Release&goto arg-ok
  44 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  45 if /i "%1"=="ia32"          set target_arch=x86&goto arg-ok
  46 if /i "%1"=="x86"           set target_arch=x86&goto arg-ok
  47 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  48 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  49 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  50 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  51 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  52 if /i "%1"=="noetw"         set noetw=1&goto arg-ok
  53 if /i "%1"=="noperfctr"     set noperfctr=1&goto arg-ok
  54 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  55 if /i "%1"=="test"          set test_args=%test_args% sequential parallel message -J&set jslint=1&goto arg-ok
  56 if /i "%1"=="test-ci"       set test_args=%test_args% -p tap --logfile test.tap message sequential parallel&goto arg-ok
  57 if /i "%1"=="test-simple"   set test_args=%test_args% sequential parallel -J&goto arg-ok
  58 if /i "%1"=="test-message"  set test_args=%test_args% message&goto arg-ok
  59 if /i "%1"=="test-gc"       set test_args=%test_args% gc&set buildnodeweak=1&goto arg-ok
  60 if /i "%1"=="test-internet" set test_args=%test_args% internet&goto arg-ok
  61 if /i "%1"=="test-pummel"   set test_args=%test_args% pummel&goto arg-ok
  62 if /i "%1"=="test-all"      set test_args=%test_args% sequential parallel message gc internet pummel&set buildnodeweak=1&set jslint=1&goto arg-ok
  63 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  64 if /i "%1"=="msi"           set msi=1&set licensertf=1&goto arg-ok
  65 if /i "%1"=="upload"        set upload=1&goto arg-ok
  66 if /i "%1"=="small-icu"     set i18n_arg=%1&goto arg-ok
  67 if /i "%1"=="full-icu"      set i18n_arg=%1&goto arg-ok
  68 if /i "%1"=="intl-none"     set i18n_arg=%1&goto arg-ok
  69 if /i "%1"=="download-all"  set download_arg="--download=all"&goto arg-ok
  70
  71 echo Warning: ignoring invalid command line option `%1`.
  72
  73 :arg-ok
  74 :arg-ok
  75 shift
  76 goto next-arg
  77
  78 :args-done
  79 if "%config%"=="Debug" set debug_arg=--debug
  80 if defined nosnapshot set snapshot_arg=--without-snapshot
  81 if defined noetw set noetw_arg=--without-etw& set noetw_msi_arg=/p:NoETW=1
  82 if defined noperfctr set noperfctr_arg=--without-perfctr& set noperfctr_msi_arg=/p:NoPerfCtr=1
  83 if defined RELEASE_URLBASE set release_urlbase_arg=--release-urlbase=%RELEASE_URLBASE%
  84
  85 if "%i18n_arg%"=="full-icu" set i18n_arg=--with-intl=full-icu
  86 if "%i18n_arg%"=="small-icu" set i18n_arg=--with-intl=small-icu
  87 if "%i18n_arg%"=="intl-none" set i18n_arg=--with-intl=none
  88
  89 call :getnodeversion || exit /b 1
  90
  91 @rem Set environment for msbuild
  92
  93 @rem Look for Visual Studio 2015
  94 if not defined VS140COMNTOOLS goto vc-set-2013
  95 if not exist "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat" goto vc-set-2013
  96 if "%VCVARS_VER%" NEQ "140" (
  97   call "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat"
  98   SET VCVARS_VER=140
  99 )
 100 if not defined VCINSTALLDIR goto vc-set-2013
 101 set GYP_MSVS_VERSION=2015
 102 goto msbuild-found
 103
 104 :vc-set-2013
 105 @rem Look for Visual Studio 2013
 106 if not defined VS120COMNTOOLS goto msbuild-not-found
 107 if not exist "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
 108 if "%VCVARS_VER%" NEQ "120" (
 109   call "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat"
 110   SET VCVARS_VER=120
 111 )
 112 if not defined VCINSTALLDIR goto msbuild-not-found
 113 set GYP_MSVS_VERSION=2013
 114 goto msbuild-found
 115
 116 :msbuild-not-found
 117 echo Failed to find Visual Studio installation.
 118 goto exit
 119
 120 :msbuild-found
 121
 122 :project-gen
 123 @rem Skip project generation if requested.
 124 if defined noprojgen goto msbuild
 125
 126 @rem Generate the VS project.
 127 python configure %download_arg% %i18n_arg% %debug_arg% %snapshot_arg% %noetw_arg% %noperfctr_arg% --dest-cpu=%target_arch% --tag=%TAG%
 128 if errorlevel 1 goto create-msvs-files-failed
 129 if not exist node.sln goto create-msvs-files-failed
 130 echo Project files generated.
 131
 132 :msbuild
 133 @rem Skip build if requested.
 134 if defined nobuild goto sign
 135
 136 @rem Build the sln with msbuild.
 137 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 138 if errorlevel 1 goto exit
 139 if "%target%" == "Clean" goto exit
 140
 141 :sign
 142 @rem Skip signing if the `nosign` option was specified.
 143 if defined nosign goto licensertf
 144
 145 signtool sign /a /d "io.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\iojs.exe
 146 if errorlevel 1 echo Failed to sign exe&goto exit
 147
 148 :licensertf
 149 @rem Skip license.rtf generation if not requested.
 150 if not defined licensertf goto msi
 151
 152 %config%\iojs tools\license2rtf.js < LICENSE > %config%\license.rtf
 153 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 154
 155 :msi
 156 @rem Skip msi generation if not requested
 157 if not defined msi goto run
 158
 159 :msibuild
 160 echo Building iojs-v%FULLVERSION%-%target_arch%.msi
 161 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:Configuration=%config% /p:Platform=%target_arch% /p:NodeVersion=%NODE_VERSION% /p:FullVersion=%FULLVERSION% /p:DistTypeDir=%DISTTYPEDIR% %noetw_msi_arg% %noperfctr_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 162 if errorlevel 1 goto exit
 163
 164 if defined nosign goto upload
 165 signtool sign /a /d "io.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll iojs-v%FULLVERSION%-%target_arch%.msi
 166 if errorlevel 1 echo Failed to sign msi&goto exit
 167
 168 :upload
 169 @rem Skip upload if not requested
 170 if not defined upload goto run
 171
 172 if not defined SSHCONFIG (
 173   echo SSHCONFIG is not set for upload
 174   exit /b 1
 175 )
 176 if not defined STAGINGSERVER set STAGINGSERVER=iojs-www
 177 ssh -F %SSHCONFIG% %STAGINGSERVER% "mkdir -p staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%"
 178 scp -F %SSHCONFIG% Release\iojs.exe %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/iojs.exe
 179 scp -F %SSHCONFIG% Release\iojs.lib %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/iojs.lib
 180 scp -F %SSHCONFIG% iojs-v%FULLVERSION%-%target_arch%.msi %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/
 181 ssh -F %SSHCONFIG% %STAGINGSERVER% "touch staging/%DISTTYPEDIR%/v%FULLVERSION%/iojs-v%FULLVERSION%-%target_arch%.msi.done staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%.done"
 182
 183 :run
 184 @rem Run tests if requested.
 185
 186 :build-node-weak
 187 @rem Build node-weak if required
 188 if "%buildnodeweak%"=="" goto run-tests
 189 "%config%\iojs" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0."
 190 if errorlevel 1 goto build-node-weak-failed
 191 goto run-tests
 192
 193 :build-node-weak-failed
 194 echo Failed to build node-weak.
 195 goto exit
 196
 197 :run-tests
 198 if "%test_args%"=="" goto jslint
 199 if "%config%"=="Debug" set test_args=--mode=debug %test_args%
 200 if "%config%"=="Release" set test_args=--mode=release %test_args%
 201 echo running 'cctest'
 202 "%config%\cctest"
 203 echo running 'python tools\test.py %test_args%'
 204 python tools\test.py %test_args%
 205 goto jslint
 206
 207 :jslint
 208 if not defined jslint goto exit
 209 echo running jslint
 210 %config%\iojs tools\eslint\bin\eslint.js src lib test --rulesdir tools\eslint-rules --reset --quiet
 211 goto exit
 212
 213 :create-msvs-files-failed
 214 echo Failed to create vc project files.
 215 goto exit
 216
 217 :help
 218 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [small-icu/full-icu/intl-none] [nobuild] [nosign] [x86/x64] [download-all]
 219 echo Examples:
 220 echo   vcbuild.bat                : builds release build
 221 echo   vcbuild.bat debug          : builds debug build
 222 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 223 echo   vcbuild.bat test           : builds debug build and runs tests
 224 goto exit
 225
 226 :exit
 227 goto :EOF
 228
 229 rem ***************
 230 rem   Subroutines
 231 rem ***************
 232
 233 :getnodeversion
 234 set NODE_VERSION=
 235 set TAG=
 236 set FULLVERSION=
 237
 238 for /F "usebackq tokens=*" %%i in (`python "%~dp0tools\getnodeversion.py"`) do set NODE_VERSION=%%i
 239 if not defined NODE_VERSION (
 240   echo Cannot determine current version of io.js
 241   exit /b 1
 242 )
 243
 244 if not defined DISTTYPE set DISTTYPE=release
 245 if "%DISTTYPE%"=="release" (
 246   set FULLVERSION=%NODE_VERSION%
 247   goto exit
 248 )
 249 if "%DISTTYPE%"=="custom" (
 250   if not defined CUSTOMTAG (
 251     echo "CUSTOMTAG is not set for DISTTYPE=custom"
 252     exit /b 1
 253   )
 254   set TAG=%CUSTOMTAG%
 255 )
 256 if not "%DISTTYPE%"=="custom" (
 257   if not defined DATESTRING (
 258     echo "DATESTRING is not set for nightly"
 259     exit /b 1
 260   )
 261   if not defined COMMIT (
 262     echo "COMMIT is not set for nightly"
 263     exit /b 1
 264   )
 265   if not "%DISTTYPE%"=="nightly" (
 266     if not "%DISTTYPE%"=="next-nightly" (
 267       echo "DISTTYPE is not release, custom, nightly or next-nightly"
 268       exit /b 1
 269     )
 270   )
 271   set TAG=%DISTTYPE%%DATESTRING%%COMMIT%
 272 )
 273 set FULLVERSION=%NODE_VERSION%-%TAG%
 274
 275 :exit
 276 if not defined DISTTYPEDIR set DISTTYPEDIR=%DISTTYPE%
 277 goto :EOF