vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Debug
  16 set target=Build
  17 set noprojgen=
  18 set nobuild=
  19 set test=
  20 set test_args=
  21 set msi=
  22
  23 :next-arg
  24 if "%1"=="" goto args-done
  25 if /i "%1"=="debug"        set config=Debug&goto arg-ok
  26 if /i "%1"=="release"      set config=Release&goto arg-ok
  27 if /i "%1"=="clean"        set target=Clean&goto arg-ok
  28 if /i "%1"=="noprojgen"    set noprojgen=1&goto arg-ok
  29 if /i "%1"=="nobuild"      set nobuild=1&goto arg-ok
  30 if /i "%1"=="test-uv"      set test=test-uv&goto arg-ok
  31 if /i "%1"=="test-internet"set test=test-internet&goto arg-ok
  32 if /i "%1"=="test-pummel"  set test=test-pummel&goto arg-ok
  33 if /i "%1"=="test-simple"  set test=test-simple&goto arg-ok
  34 if /i "%1"=="test-message" set test=test-message&goto arg-ok
  35 if /i "%1"=="test-all"     set test=test-all&goto arg-ok
  36 if /i "%1"=="test"         set test=test&goto arg-ok
  37 if /i "%1"=="msi"          set msi=1&goto arg-ok
  38 :arg-ok
  39 shift
  40 goto next-arg
  41 :args-done
  42
  43
  44 :project-gen
  45 @rem Skip project generation if requested.
  46 if defined noprojgen goto msbuild
  47
  48 @rem Generate the VS project.
  49 python tools\gyp_node -f msvs -G msvs_version=2010
  50 if errorlevel 1 goto create-msvs-files-failed
  51 if not exist node.sln goto create-msvs-files-failed
  52 echo Project files generated.
  53
  54 :msbuild
  55 @rem Skip project generation if requested.
  56 if defined nobuild goto msi
  57
  58 @rem Bail out early if not running in VS build env.
  59 if defined VCINSTALLDIR goto msbuild-found
  60 if not defined VS100COMNTOOLS goto msbuild-not-found
  61 if not exist "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
  62 call "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat"
  63 if not defined VCINSTALLDIR goto msbuild-not-found
  64 goto msbuild-found
  65
  66 :msbuild-not-found
  67 echo Build skipped. To build, this file needs to run from VS cmd prompt.
  68 goto run
  69
  70 :msbuild-found
  71 @rem Build the sln with msbuild.
  72 msbuild node.sln /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
  73 if errorlevel 1 goto exit
  74
  75 :msi
  76 @rem Skip msi generation if not requested
  77 if not defined msi goto run
  78 python "%~dp0tools\msi\getnodeversion.py" < "%~dp0src\node_version.h" > "%temp%\node_version.txt"
  79 if not errorlevel 0 echo Cannot determine current version of node.js & goto exit
  80 for /F "tokens=*" %%i in (%temp%\node_version.txt) do set NODE_VERSION=%%i
  81 msbuild "%~dp0tools\msi\nodemsi.sln" /t:Clean,Build /p:Configuration=%config% /p:NodeVersion=%NODE_VERSION% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
  82 if errorlevel 1 goto exit
  83
  84 :run
  85 @rem Run tests if requested.
  86 if "%test%"=="" goto exit
  87
  88 if "%config%"=="Debug" set test_args=--mode=debug
  89 if "%config%"=="Release" set test_args=--mode=release
  90
  91 if "%test%"=="test" set test_args=%test_args% simple message
  92 if "%test%"=="test-uv" set test_args=%test_args% --libuv simple
  93 if "%test%"=="test-internet" set test_args=%test_args% internet
  94 if "%test%"=="test-pummel" set test_args=%test_args% pummel
  95 if "%test%"=="test-simple" set test_args=%test_args% simple
  96 if "%test%"=="test-message" set test_args=%test_args% message
  97 if "%test%"=="test-all" set test_args=%test_args%
  98
  99 echo running 'python tools/test.py %test_args%'
 100 python tools/test.py %test_args%
 101 goto exit
 102
 103 :create-msvs-files-failed
 104 echo Failed to create vc project files.
 105 goto exit
 106
 107 :help
 108 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [nobuild]
 109 echo Examples:
 110 echo   vcbuild.bat                : builds debug build
 111 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 112 echo   vcbuild.bat test           : builds debug build and runs tests
 113 echo   vcbuild.bat release test-uv: builds release build and runs --libuv tests
 114 goto exit
 115
 116 :exit