vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set msiplatform=x86
  17 set target=Build
  18 set target_arch=ia32
  19 set debug_arg=
  20 set nosnapshot_arg=
  21 set noprojgen=
  22 set nobuild=
  23 set nosign=
  24 set nosnapshot=
  25 set test=
  26 set test_args=
  27 set msi=
  28 set licensertf=
  29 set upload=
  30 set jslint=
  31 set buildnodeweak=
  32 set noetw=
  33 set noetw_arg=
  34 set noetw_msi_arg=
  35 set noperfctr=
  36 set noperfctr_arg=
  37 set noperfctr_msi_arg=
  38 set i18n_arg=
  39 set download_arg=
  40
  41 :next-arg
  42 if "%1"=="" goto args-done
  43 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  44 if /i "%1"=="release"       set config=Release&goto arg-ok
  45 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  46 if /i "%1"=="ia32"          set target_arch=ia32&goto arg-ok
  47 if /i "%1"=="x86"           set target_arch=ia32&goto arg-ok
  48 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  49 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  50 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  51 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  52 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  53 if /i "%1"=="noetw"         set noetw=1&goto arg-ok
  54 if /i "%1"=="noperfctr"     set noperfctr=1&goto arg-ok
  55 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  56 if /i "%1"=="test-uv"       set test=test-uv&goto arg-ok
  57 if /i "%1"=="test-internet" set test=test-internet&goto arg-ok
  58 if /i "%1"=="test-pummel"   set test=test-pummel&goto arg-ok
  59 if /i "%1"=="test-simple"   set test=test-simple&goto arg-ok
  60 if /i "%1"=="test-message"  set test=test-message&goto arg-ok
  61 if /i "%1"=="test-gc"       set test=test-gc&set buildnodeweak=1&goto arg-ok
  62 if /i "%1"=="test-all"      set test=test-all&set buildnodeweak=1&goto arg-ok
  63 if /i "%1"=="test"          set test=test&goto arg-ok
  64 if /i "%1"=="msi"           set msi=1&set licensertf=1&goto arg-ok
  65 if /i "%1"=="upload"        set upload=1&goto arg-ok
  66 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  67 if /i "%1"=="small-icu"     set i18n_arg=%1&goto arg-ok
  68 if /i "%1"=="full-icu"      set i18n_arg=%1&goto arg-ok
  69 if /i "%1"=="intl-none"     set i18n_arg=%1&goto arg-ok
  70 if /i "%1"=="download-all"  set download_arg="--download=all"&goto arg-ok
  71
  72 echo Warning: ignoring invalid command line option `%1`.
  73
  74 :arg-ok
  75 :arg-ok
  76 shift
  77 goto next-arg
  78
  79 :args-done
  80 if defined upload goto upload
  81 if defined jslint goto jslint
  82
  83 if "%config%"=="Debug" set debug_arg=--debug
  84 if "%target_arch%"=="x64" set msiplatform=x64
  85 if defined nosnapshot set nosnapshot_arg=--without-snapshot
  86 if defined noetw set noetw_arg=--without-etw& set noetw_msi_arg=/p:NoETW=1
  87 if defined noperfctr set noperfctr_arg=--without-perfctr& set noperfctr_msi_arg=/p:NoPerfCtr=1
  88
  89 if "%i18n_arg%"=="full-icu" set i18n_arg=--with-intl=full-icu
  90 if "%i18n_arg%"=="small-icu" set i18n_arg=--with-intl=small-icu
  91 if "%i18n_arg%"=="intl-none" set i18n_arg=--with-intl=none
  92
  93 :project-gen
  94 @rem Skip project generation if requested.
  95 if defined noprojgen goto msbuild
  96
  97 if defined NIGHTLY set TAG=nightly-%NIGHTLY%
  98
  99 @rem Generate the VS project.
 100 SETLOCAL
 101   if defined VS100COMNTOOLS call "%VS100COMNTOOLS%\VCVarsQueryRegistry.bat"
 102   python configure %download_arg% %i18n_arg% %debug_arg% %nosnapshot_arg% %noetw_arg% %noperfctr_arg% --dest-cpu=%target_arch% --tag=%TAG%
 103   if errorlevel 1 goto create-msvs-files-failed
 104   if not exist node.sln goto create-msvs-files-failed
 105   echo Project files generated.
 106 ENDLOCAL
 107
 108 :msbuild
 109 @rem Skip project generation if requested.
 110 if defined nobuild goto sign
 111
 112 @rem Look for Visual Studio 2013
 113 if not defined VS120COMNTOOLS goto msbuild-not-found
 114 if not exist "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
 115 if "%VCVARS_VER%" NEQ "120" (
 116   call "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat"
 117   SET VCVARS_VER=120
 118 )
 119 if not defined VCINSTALLDIR goto msbuild-not-found
 120 set GYP_MSVS_VERSION=2013
 121 goto msbuild-found
 122
 123 :msbuild-not-found
 124 echo Build skipped. To build, this file needs to run from VS cmd prompt.
 125 goto run
 126
 127 :msbuild-found
 128 @rem Build the sln with msbuild.
 129 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 130 if errorlevel 1 goto exit
 131
 132 :sign
 133 @rem Skip signing if the `nosign` option was specified.
 134 if defined nosign goto licensertf
 135
 136 signtool sign /a /d "Node.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\node.exe
 137 if errorlevel 1 echo Failed to sign exe&goto exit
 138
 139 :licensertf
 140 @rem Skip license.rtf generation if not requested.
 141 if not defined licensertf goto msi
 142
 143 %config%\node tools\license2rtf.js < LICENSE > %config%\license.rtf
 144 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 145
 146 :msi
 147 @rem Skip msi generation if not requested
 148 if not defined msi goto run
 149 call :getnodeversion
 150
 151 if not defined NIGHTLY goto msibuild
 152 set NODE_VERSION=%NODE_VERSION%.%NIGHTLY%
 153
 154 :msibuild
 155 echo Building node-%NODE_VERSION%
 156 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:Configuration=%config% /p:Platform=%msiplatform% /p:NodeVersion=%NODE_VERSION% %noetw_msi_arg% %noperfctr_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 157 if errorlevel 1 goto exit
 158
 159 if defined nosign goto run
 160 signtool sign /a /d "Node.js" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\node-v%NODE_VERSION%-%msiplatform%.msi
 161 if errorlevel 1 echo Failed to sign msi&goto exit
 162
 163 :run
 164 @rem Run tests if requested.
 165 if "%test%"=="" goto exit
 166
 167 if "%config%"=="Debug" set test_args=--mode=debug
 168 if "%config%"=="Release" set test_args=--mode=release
 169
 170 if "%test%"=="test" set test_args=%test_args% sequential parallel message -J
 171 if "%test%"=="test-internet" set test_args=%test_args% internet
 172 if "%test%"=="test-pummel" set test_args=%test_args% pummel
 173 if "%test%"=="test-simple" set test_args=%test_args% sequential parallel
 174 if "%test%"=="test-message" set test_args=%test_args% message
 175 if "%test%"=="test-gc" set test_args=%test_args% gc
 176 if "%test%"=="test-all" set test_args=%test_args%
 177
 178 :build-node-weak
 179 @rem Build node-weak if required
 180 if "%buildnodeweak%"=="" goto run-tests
 181 "%config%\node" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0."
 182 if errorlevel 1 goto build-node-weak-failed
 183 goto run-tests
 184
 185 :build-node-weak-failed
 186 echo Failed to build node-weak.
 187 goto exit
 188
 189 :run-tests
 190 echo running 'python tools/test.py %test_args%'
 191 python tools/test.py %test_args%
 192 if "%test%"=="test" goto jslint
 193 goto exit
 194
 195 :create-msvs-files-failed
 196 echo Failed to create vc project files.
 197 goto exit
 198
 199 :upload
 200 echo uploading .exe .msi .pdb to nodejs.org
 201 call :getnodeversion
 202 @echo on
 203 ssh node@nodejs.org mkdir -p web/nodejs.org/dist/v%NODE_VERSION%
 204 scp Release\node.msi node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node-v%NODE_VERSION%.msi
 205 scp Release\node.exe node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.exe
 206 scp Release\node.pdb node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.pdb
 207 @echo off
 208 goto exit
 209
 210 :jslint
 211 echo running jslint
 212 set PYTHONPATH=tools/closure_linter/
 213 python tools/closure_linter/closure_linter/gjslint.py --unix_mode --strict --nojsdoc -r lib/ -r src/ --exclude_files lib/punycode.js
 214 goto exit
 215
 216 :help
 217 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [small-icu/full-icu/intl-none] [nobuild] [nosign] [x86/x64] [download-all]
 218 echo Examples:
 219 echo   vcbuild.bat                : builds release build
 220 echo   vcbuild.bat debug          : builds debug build
 221 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 222 echo   vcbuild.bat test           : builds debug build and runs tests
 223 goto exit
 224
 225 :exit
 226 goto :EOF
 227
 228 rem ***************
 229 rem   Subroutines
 230 rem ***************
 231
 232 :getnodeversion
 233 set NODE_VERSION=
 234 for /F "usebackq tokens=*" %%i in (`python "%~dp0tools\getnodeversion.py"`) do set NODE_VERSION=%%i
 235 if not defined NODE_VERSION echo Cannot determine current version of node.js & exit /b 1
 236 goto :EOF