vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set msiplatform=x86
  17 set target=Build
  18 set target_arch=ia32
  19 set debug_arg=
  20 set nosnapshot_arg=
  21 set noprojgen=
  22 set nobuild=
  23 set nosign=
  24 set nosnapshot=
  25 set test=
  26 set test_args=
  27 set msi=
  28 set licensertf=
  29 set upload=
  30 set jslint=
  31 set buildnodeweak=
  32 set noetw=
  33 set noetw_arg=
  34 set noetw_msi_arg=
  35 set noperfctr=
  36 set noperfctr_arg=
  37 set noperfctr_msi_arg=
  38
  39 :next-arg
  40 if "%1"=="" goto args-done
  41 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  42 if /i "%1"=="release"       set config=Release&goto arg-ok
  43 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  44 if /i "%1"=="ia32"          set target_arch=ia32&goto arg-ok
  45 if /i "%1"=="x86"           set target_arch=ia32&goto arg-ok
  46 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  47 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  48 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  49 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  50 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  51 if /i "%1"=="noetw"         set noetw=1&goto arg-ok
  52 if /i "%1"=="noperfctr"     set noperfctr=1&goto arg-ok
  53 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  54 if /i "%1"=="test-uv"       set test=test-uv&goto arg-ok
  55 if /i "%1"=="test-internet" set test=test-internet&goto arg-ok
  56 if /i "%1"=="test-pummel"   set test=test-pummel&goto arg-ok
  57 if /i "%1"=="test-simple"   set test=test-simple&goto arg-ok
  58 if /i "%1"=="test-message"  set test=test-message&goto arg-ok
  59 if /i "%1"=="test-gc"       set test=test-gc&set buildnodeweak=1&goto arg-ok
  60 if /i "%1"=="test-all"      set test=test-all&set buildnodeweak=1&goto arg-ok
  61 if /i "%1"=="test"          set test=test&goto arg-ok
  62 if /i "%1"=="msi"           set msi=1&set licensertf=1&goto arg-ok
  63 if /i "%1"=="upload"        set upload=1&goto arg-ok
  64 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  65
  66 echo Warning: ignoring invalid command line option `%1`.
  67
  68 :arg-ok
  69 :arg-ok
  70 shift
  71 goto next-arg
  72
  73 :args-done
  74 if defined upload goto upload
  75 if defined jslint goto jslint
  76
  77 if "%config%"=="Debug" set debug_arg=--debug
  78 if "%target_arch%"=="x64" set msiplatform=x64
  79 if defined nosnapshot set nosnapshot_arg=--without-snapshot
  80 if defined noetw set noetw_arg=--without-etw& set noetw_msi_arg=/p:NoETW=1
  81 if defined noperfctr set noperfctr_arg=--without-perfctr& set noperfctr_msi_arg=/p:NoPerfCtr=1
  82
  83 :project-gen
  84 @rem Skip project generation if requested.
  85 if defined noprojgen goto msbuild
  86
  87 if defined NIGHTLY set TAG=nightly-%NIGHTLY%
  88
  89 @rem Generate the VS project.
  90 SETLOCAL
  91   if defined VS100COMNTOOLS call "%VS100COMNTOOLS%\VCVarsQueryRegistry.bat"
  92   python configure %debug_arg% %nosnapshot_arg% %noetw_arg% %noperfctr_arg% --dest-cpu=%target_arch% --tag=%TAG%
  93   if errorlevel 1 goto create-msvs-files-failed
  94   if not exist node.sln goto create-msvs-files-failed
  95   echo Project files generated.
  96 ENDLOCAL
  97
  98 :msbuild
  99 @rem Skip project generation if requested.
 100 if defined nobuild goto sign
 101
 102 @rem Look for Visual Studio 2013
 103 if not defined VS120COMNTOOLS goto vc-set-2012
 104 if not exist "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" goto vc-set-2012
 105 call "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat"
 106 if not defined VCINSTALLDIR goto msbuild-not-found
 107 set GYP_MSVS_VERSION=2013
 108 goto msbuild-found
 109
 110 :vc-set-2012
 111 @rem Look for Visual Studio 2012
 112 if not defined VS110COMNTOOLS goto vc-set-2010
 113 if not exist "%VS110COMNTOOLS%\..\..\vc\vcvarsall.bat" goto vc-set-2010
 114 call "%VS110COMNTOOLS%\..\..\vc\vcvarsall.bat"
 115 if not defined VCINSTALLDIR goto msbuild-not-found
 116 set GYP_MSVS_VERSION=2012
 117 goto msbuild-found
 118
 119 :vc-set-2010
 120 if not defined VS100COMNTOOLS goto msbuild-not-found
 121 if not exist "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
 122 call "%VS100COMNTOOLS%\..\..\vc\vcvarsall.bat"
 123 if not defined VCINSTALLDIR goto msbuild-not-found
 124 goto msbuild-found
 125
 126 :msbuild-not-found
 127 echo Build skipped. To build, this file needs to run from VS cmd prompt.
 128 goto run
 129
 130 :msbuild-found
 131 @rem Build the sln with msbuild.
 132 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 133 if errorlevel 1 goto exit
 134
 135 :sign
 136 @rem Skip signing if the `nosign` option was specified.
 137 if defined nosign goto licensertf
 138
 139 signtool sign /a Release\node.exe
 140
 141 :licensertf
 142 @rem Skip license.rtf generation if not requested.
 143 if not defined licensertf goto msi
 144
 145 %config%\node tools\license2rtf.js < LICENSE > %config%\license.rtf
 146 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 147
 148 :msi
 149 @rem Skip msi generation if not requested
 150 if not defined msi goto run
 151 call :getnodeversion
 152
 153 if not defined NIGHTLY goto msibuild
 154 set NODE_VERSION=%NODE_VERSION%.%NIGHTLY%
 155
 156 :msibuild
 157 echo Building node-%NODE_VERSION%
 158 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:Configuration=%config% /p:Platform=%msiplatform% /p:NodeVersion=%NODE_VERSION% %noetw_msi_arg% %noperfctr_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 159 if errorlevel 1 goto exit
 160
 161 if defined nosign goto run
 162 signtool sign /a Release\node-v%NODE_VERSION%-%msiplatform%.msi
 163
 164 :run
 165 @rem Run tests if requested.
 166 if "%test%"=="" goto exit
 167
 168 if "%config%"=="Debug" set test_args=--mode=debug
 169 if "%config%"=="Release" set test_args=--mode=release
 170
 171 if "%test%"=="test" set test_args=%test_args% simple message
 172 if "%test%"=="test-internet" set test_args=%test_args% internet
 173 if "%test%"=="test-pummel" set test_args=%test_args% pummel
 174 if "%test%"=="test-simple" set test_args=%test_args% simple
 175 if "%test%"=="test-message" set test_args=%test_args% message
 176 if "%test%"=="test-gc" set test_args=%test_args% gc
 177 if "%test%"=="test-all" set test_args=%test_args%
 178
 179 :build-node-weak
 180 @rem Build node-weak if required
 181 if "%buildnodeweak%"=="" goto run-tests
 182 "%config%\node" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0."
 183 if errorlevel 1 goto build-node-weak-failed
 184 goto run-tests
 185
 186 :build-node-weak-failed
 187 echo Failed to build node-weak.
 188 goto exit
 189
 190 :run-tests
 191 echo running 'python tools/test.py %test_args%'
 192 python tools/test.py %test_args%
 193 if "%test%"=="test" goto jslint
 194 goto exit
 195
 196 :create-msvs-files-failed
 197 echo Failed to create vc project files.
 198 goto exit
 199
 200 :upload
 201 echo uploading .exe .msi .pdb to nodejs.org
 202 call :getnodeversion
 203 @echo on
 204 ssh node@nodejs.org mkdir -p web/nodejs.org/dist/v%NODE_VERSION%
 205 scp Release\node.msi node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node-v%NODE_VERSION%.msi
 206 scp Release\node.exe node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.exe
 207 scp Release\node.pdb node@nodejs.org:~/web/nodejs.org/dist/v%NODE_VERSION%/node.pdb
 208 @echo off
 209 goto exit
 210
 211 :jslint
 212 echo running jslint
 213 set PYTHONPATH=tools/closure_linter/
 214 python tools/closure_linter/closure_linter/gjslint.py --unix_mode --strict --nojsdoc -r lib/ -r src/ --exclude_files lib/punycode.js
 215 goto exit
 216
 217 :help
 218 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [nobuild] [nosign] [x86/x64]
 219 echo Examples:
 220 echo   vcbuild.bat                : builds release build
 221 echo   vcbuild.bat debug          : builds debug build
 222 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 223 echo   vcbuild.bat test           : builds debug build and runs tests
 224 goto exit
 225
 226 :exit
 227 goto :EOF
 228
 229 rem ***************
 230 rem   Subroutines
 231 rem ***************
 232
 233 :getnodeversion
 234 set NODE_VERSION=
 235 for /F "usebackq tokens=*" %%i in (`python "%~dp0tools\getnodeversion.py"`) do set NODE_VERSION=%%i
 236 if not defined NODE_VERSION echo Cannot determine current version of node.js & exit /b 1
 237 goto :EOF