vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set target=Build
  17 set target_arch=x86
  18 set debug_arg=
  19 set snapshot_arg=
  20 set noprojgen=
  21 set nobuild=
  22 set nosign=
  23 set nosnapshot=
  24 set test_args=
  25 set msi=
  26 set upload=
  27 set licensertf=
  28 set jslint=
  29 set buildnodeweak=
  30 set noetw=
  31 set noetw_arg=
  32 set noetw_msi_arg=
  33 set noperfctr=
  34 set noperfctr_arg=
  35 set noperfctr_msi_arg=
  36 set i18n_arg=
  37 set download_arg=
  38 set release_urls_arg=
  39 set build_release=
  40
  41 :next-arg
  42 if "%1"=="" goto args-done
  43 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  44 if /i "%1"=="release"       set config=Release&goto arg-ok
  45 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  46 if /i "%1"=="ia32"          set target_arch=x86&goto arg-ok
  47 if /i "%1"=="x86"           set target_arch=x86&goto arg-ok
  48 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  49 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  50 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  51 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  52 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  53 if /i "%1"=="noetw"         set noetw=1&goto arg-ok
  54 if /i "%1"=="noperfctr"     set noperfctr=1&goto arg-ok
  55 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  56 if /i "%1"=="test"          set test_args=%test_args% sequential parallel message -J&set jslint=1&goto arg-ok
  57 if /i "%1"=="test-ci"       set test_args=%test_args% %test_ci_args% -p tap --logfile test.tap message sequential parallel&goto arg-ok
  58 if /i "%1"=="test-simple"   set test_args=%test_args% sequential parallel -J&goto arg-ok
  59 if /i "%1"=="test-message"  set test_args=%test_args% message&goto arg-ok
  60 if /i "%1"=="test-gc"       set test_args=%test_args% gc&set buildnodeweak=1&goto arg-ok
  61 if /i "%1"=="test-internet" set test_args=%test_args% internet&goto arg-ok
  62 if /i "%1"=="test-pummel"   set test_args=%test_args% pummel&goto arg-ok
  63 if /i "%1"=="test-all"      set test_args=%test_args% sequential parallel message gc internet pummel&set buildnodeweak=1&set jslint=1&goto arg-ok
  64 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  65 @rem Include small-icu support with MSI installer
  66 if /i "%1"=="msi"           set msi=1&set licensertf=1&set download_arg="--download=all"&set i18n_arg=small-icu&goto arg-ok
  67 if /i "%1"=="build-release" set build_release=1&goto arg-ok
  68 if /i "%1"=="upload"        set upload=1&goto arg-ok
  69 if /i "%1"=="small-icu"     set i18n_arg=%1&goto arg-ok
  70 if /i "%1"=="full-icu"      set i18n_arg=%1&goto arg-ok
  71 if /i "%1"=="intl-none"     set i18n_arg=%1&goto arg-ok
  72 if /i "%1"=="download-all"  set download_arg="--download=all"&goto arg-ok
  73 if /i "%1"=="ignore-flaky"  set test_args=%test_args% --flaky-tests=dontcare&goto arg-ok
  74
  75 echo Warning: ignoring invalid command line option `%1`.
  76
  77 :arg-ok
  78 :arg-ok
  79 shift
  80 goto next-arg
  81
  82 :args-done
  83
  84 if defined build_release (
  85   set config=Release
  86   set msi=1
  87   set licensertf=1
  88   set download_arg="--download=all"
  89   set i18n_arg=small-icu
  90 )
  91
  92 if "%config%"=="Debug" set debug_arg=--debug
  93 if defined nosnapshot set snapshot_arg=--without-snapshot
  94 if defined noetw set noetw_arg=--without-etw& set noetw_msi_arg=/p:NoETW=1
  95 if defined noperfctr set noperfctr_arg=--without-perfctr& set noperfctr_msi_arg=/p:NoPerfCtr=1
  96 if defined RELEASE_URLBASE set release_urlbase_arg=--release-urlbase=%RELEASE_URLBASE%
  97
  98 if "%i18n_arg%"=="full-icu" set i18n_arg=--with-intl=full-icu
  99 if "%i18n_arg%"=="small-icu" set i18n_arg=--with-intl=small-icu
 100 if "%i18n_arg%"=="intl-none" set i18n_arg=--with-intl=none
 101
 102 call :getnodeversion || exit /b 1
 103
 104 @rem Set environment for msbuild
 105
 106 @rem Look for Visual Studio 2015
 107 echo Looking for Visual Studio 2015
 108 if not defined VS140COMNTOOLS goto vc-set-2013
 109 if not exist "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat" goto vc-set-2013
 110 echo Found Visual Studio 2015
 111 if defined msi (
 112   echo Looking for WiX installation for Visual Studio 2015...
 113   if not exist "%WIX%\SDK\VS2015" (
 114     echo Failed to find WiX install for Visual Studio 2015
 115     echo VS2015 support for WiX is only present starting at version 3.10
 116     goto vc-set-2013
 117   )
 118 )
 119 if "%VCVARS_VER%" NEQ "140" (
 120   call "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat"
 121   SET VCVARS_VER=140
 122 )
 123 if not defined VCINSTALLDIR goto vc-set-2013
 124 set GYP_MSVS_VERSION=2015
 125 set PLATFORM_TOOLSET=v140
 126 goto msbuild-found
 127
 128 :vc-set-2013
 129 @rem Look for Visual Studio 2013
 130 echo Looking for Visual Studio 2013
 131 if not defined VS120COMNTOOLS goto msbuild-not-found
 132 if not exist "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
 133 echo Found Visual Studio 2013
 134 if defined msi (
 135   echo Looking for WiX installation for Visual Studio 2013...
 136   if not exist "%WIX%\SDK\VS2013" (
 137     echo Failed to find WiX install for Visual Studio 2013
 138     echo VS2013 support for WiX is only present starting at version 3.8
 139     goto vc-set-2012
 140   )
 141 )
 142 if "%VCVARS_VER%" NEQ "120" (
 143   call "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat"
 144   SET VCVARS_VER=120
 145 )
 146 if not defined VCINSTALLDIR goto msbuild-not-found
 147 set GYP_MSVS_VERSION=2013
 148 set PLATFORM_TOOLSET=v120
 149 goto msbuild-found
 150
 151 :msbuild-not-found
 152 echo Failed to find Visual Studio installation.
 153 goto exit
 154
 155 :wix-not-found
 156 echo Build skipped. To generate installer, you need to install Wix.
 157 goto run
 158
 159 :msbuild-found
 160
 161 :project-gen
 162 @rem Skip project generation if requested.
 163 if defined noprojgen goto msbuild
 164
 165 @rem Generate the VS project.
 166 python configure %download_arg% %i18n_arg% %debug_arg% %snapshot_arg% %noetw_arg% %noperfctr_arg% --dest-cpu=%target_arch% --tag=%TAG%
 167 if errorlevel 1 goto create-msvs-files-failed
 168 if not exist node.sln goto create-msvs-files-failed
 169 echo Project files generated.
 170
 171 :msbuild
 172 @rem Skip build if requested.
 173 if defined nobuild goto sign
 174
 175 @rem Build the sln with msbuild.
 176 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 177 if errorlevel 1 goto exit
 178 if "%target%" == "Clean" goto exit
 179
 180 :sign
 181 @rem Skip signing if the `nosign` option was specified.
 182 if defined nosign goto licensertf
 183
 184 signtool sign /a /d "node" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\node.exe
 185 if errorlevel 1 echo Failed to sign exe&goto exit
 186
 187 :licensertf
 188 @rem Skip license.rtf generation if not requested.
 189 if not defined licensertf goto msi
 190
 191 %config%\node tools\license2rtf.js < LICENSE > %config%\license.rtf
 192 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 193
 194 :msi
 195 @rem Skip msi generation if not requested
 196 if not defined msi goto run
 197
 198 :msibuild
 199 echo Building node-v%FULLVERSION%-%target_arch%.msi
 200 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:PlatformToolset=%PLATFORM_TOOLSET% /p:GypMsvsVersion=%GYP_MSVS_VERSION% /p:Configuration=%config% /p:Platform=%target_arch% /p:NodeVersion=%NODE_VERSION% /p:FullVersion=%FULLVERSION% /p:DistTypeDir=%DISTTYPEDIR% %noetw_msi_arg% %noperfctr_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 201 if errorlevel 1 goto exit
 202
 203 if defined nosign goto upload
 204 signtool sign /a /d "node" /t http://timestamp.globalsign.com/scripts/timestamp.dll node-v%FULLVERSION%-%target_arch%.msi
 205 if errorlevel 1 echo Failed to sign msi&goto exit
 206
 207 :upload
 208 @rem Skip upload if not requested
 209 if not defined upload goto run
 210
 211 if not defined SSHCONFIG (
 212   echo SSHCONFIG is not set for upload
 213   exit /b 1
 214 )
 215 if not defined STAGINGSERVER set STAGINGSERVER=node-www
 216 ssh -F %SSHCONFIG% %STAGINGSERVER% "mkdir -p nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%"
 217 scp -F %SSHCONFIG% Release\node.exe %STAGINGSERVER%:nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/node.exe
 218 scp -F %SSHCONFIG% Release\node.lib %STAGINGSERVER%:nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/node.lib
 219 scp -F %SSHCONFIG% node-v%FULLVERSION%-%target_arch%.msi %STAGINGSERVER%:nodejs/%DISTTYPEDIR%/v%FULLVERSION%/
 220 ssh -F %SSHCONFIG% %STAGINGSERVER% "touch nodejs/%DISTTYPEDIR%/v%FULLVERSION%/node-v%FULLVERSION%-%target_arch%.msi.done nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%.done"
 221 ssh -F %SSHCONFIG% %STAGINGSERVER% "chmod -R ug=rw-x+X,o=r+X nodejs/%DISTTYPEDIR%/v%FULLVERSION%/node-v%FULLVERSION%-%target_arch%.msi* nodejs/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%*"
 222
 223 :run
 224 @rem Run tests if requested.
 225
 226 :build-node-weak
 227 @rem Build node-weak if required
 228 if "%buildnodeweak%"=="" goto run-tests
 229 "%config%\node" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0."
 230 if errorlevel 1 goto build-node-weak-failed
 231 goto run-tests
 232
 233 :build-node-weak-failed
 234 echo Failed to build node-weak.
 235 goto exit
 236
 237 :run-tests
 238 if "%test_args%"=="" goto jslint
 239 if "%config%"=="Debug" set test_args=--mode=debug %test_args%
 240 if "%config%"=="Release" set test_args=--mode=release %test_args%
 241 echo running 'cctest'
 242 "%config%\cctest"
 243 echo running 'python tools\test.py %test_args%'
 244 python tools\test.py %test_args%
 245 goto jslint
 246
 247 :jslint
 248 if not defined jslint goto exit
 249 echo running jslint
 250 %config%\node tools\eslint\bin\eslint.js src lib test --rulesdir tools\eslint-rules --reset --quiet
 251 goto exit
 252
 253 :create-msvs-files-failed
 254 echo Failed to create vc project files.
 255 goto exit
 256
 257 :help
 258 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [small-icu/full-icu/intl-none] [nobuild] [nosign] [x86/x64] [download-all]
 259 echo Examples:
 260 echo   vcbuild.bat                : builds release build
 261 echo   vcbuild.bat debug          : builds debug build
 262 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 263 echo   vcbuild.bat test           : builds debug build and runs tests
 264 echo   vcbuild.bat build-release  : builds the release distribution as used by nodejs.org
 265 goto exit
 266
 267 :exit
 268 goto :EOF
 269
 270 rem ***************
 271 rem   Subroutines
 272 rem ***************
 273
 274 :getnodeversion
 275 set NODE_VERSION=
 276 set TAG=
 277 set FULLVERSION=
 278
 279 for /F "usebackq tokens=*" %%i in (`python "%~dp0tools\getnodeversion.py"`) do set NODE_VERSION=%%i
 280 if not defined NODE_VERSION (
 281   echo Cannot determine current version of Node.js
 282   exit /b 1
 283 )
 284
 285 if not defined DISTTYPE set DISTTYPE=release
 286 if "%DISTTYPE%"=="release" (
 287   set FULLVERSION=%NODE_VERSION%
 288   goto exit
 289 )
 290 if "%DISTTYPE%"=="custom" (
 291   if not defined CUSTOMTAG (
 292     echo "CUSTOMTAG is not set for DISTTYPE=custom"
 293     exit /b 1
 294   )
 295   set TAG=%CUSTOMTAG%
 296 )
 297 if not "%DISTTYPE%"=="custom" (
 298   if not defined DATESTRING (
 299     echo "DATESTRING is not set for nightly"
 300     exit /b 1
 301   )
 302   if not defined COMMIT (
 303     echo "COMMIT is not set for nightly"
 304     exit /b 1
 305   )
 306   if not "%DISTTYPE%"=="nightly" (
 307     if not "%DISTTYPE%"=="next-nightly" (
 308       echo "DISTTYPE is not release, custom, nightly or next-nightly"
 309       exit /b 1
 310     )
 311   )
 312   set TAG=%DISTTYPE%%DATESTRING%%COMMIT%
 313 )
 314 set FULLVERSION=%NODE_VERSION%-%TAG%
 315
 316 :exit
 317 if not defined DISTTYPEDIR set DISTTYPEDIR=%DISTTYPE%
 318 goto :EOF