vcbuild.bat

   1 @echo off
   2
   3 cd %~dp0
   4
   5 if /i "%1"=="help" goto help
   6 if /i "%1"=="--help" goto help
   7 if /i "%1"=="-help" goto help
   8 if /i "%1"=="/help" goto help
   9 if /i "%1"=="?" goto help
  10 if /i "%1"=="-?" goto help
  11 if /i "%1"=="--?" goto help
  12 if /i "%1"=="/?" goto help
  13
  14 @rem Process arguments.
  15 set config=Release
  16 set target=Build
  17 set target_arch=x86
  18 set debug_arg=
  19 set snapshot_arg=
  20 set noprojgen=
  21 set nobuild=
  22 set nosign=
  23 set nosnapshot=
  24 set test_args=
  25 set msi=
  26 set upload=
  27 set licensertf=
  28 set jslint=
  29 set buildnodeweak=
  30 set noetw=
  31 set noetw_arg=
  32 set noetw_msi_arg=
  33 set noperfctr=
  34 set noperfctr_arg=
  35 set noperfctr_msi_arg=
  36 set i18n_arg=
  37 set download_arg=
  38 set release_urls_arg=
  39
  40 :next-arg
  41 set build_release=
  42 if "%1"=="" goto args-done
  43 if /i "%1"=="debug"         set config=Debug&goto arg-ok
  44 if /i "%1"=="release"       set config=Release&goto arg-ok
  45 if /i "%1"=="clean"         set target=Clean&goto arg-ok
  46 if /i "%1"=="ia32"          set target_arch=x86&goto arg-ok
  47 if /i "%1"=="x86"           set target_arch=x86&goto arg-ok
  48 if /i "%1"=="x64"           set target_arch=x64&goto arg-ok
  49 if /i "%1"=="noprojgen"     set noprojgen=1&goto arg-ok
  50 if /i "%1"=="nobuild"       set nobuild=1&goto arg-ok
  51 if /i "%1"=="nosign"        set nosign=1&goto arg-ok
  52 if /i "%1"=="nosnapshot"    set nosnapshot=1&goto arg-ok
  53 if /i "%1"=="noetw"         set noetw=1&goto arg-ok
  54 if /i "%1"=="noperfctr"     set noperfctr=1&goto arg-ok
  55 if /i "%1"=="licensertf"    set licensertf=1&goto arg-ok
  56 if /i "%1"=="test"          set test_args=%test_args% sequential parallel message -J&set jslint=1&goto arg-ok
  57 if /i "%1"=="test-ci"       set test_args=%test_args% -p tap --logfile test.tap message sequential parallel&goto arg-ok
  58 if /i "%1"=="test-simple"   set test_args=%test_args% sequential parallel -J&goto arg-ok
  59 if /i "%1"=="test-message"  set test_args=%test_args% message&goto arg-ok
  60 if /i "%1"=="test-gc"       set test_args=%test_args% gc&set buildnodeweak=1&goto arg-ok
  61 if /i "%1"=="test-internet" set test_args=%test_args% internet&goto arg-ok
  62 if /i "%1"=="test-pummel"   set test_args=%test_args% pummel&goto arg-ok
  63 if /i "%1"=="test-all"      set test_args=%test_args% sequential parallel message gc internet pummel&set buildnodeweak=1&set jslint=1&goto arg-ok
  64 if /i "%1"=="jslint"        set jslint=1&goto arg-ok
  65 @rem Include small-icu support with MSI installer
  66 if /i "%1"=="msi"           set msi=1&set licensertf=1&set download_arg="--download=all"&set i18n_arg=small-icu&goto arg-ok
  67 if /i "%1"=="build-release" set build_release=1&goto arg-ok
  68 if /i "%1"=="upload"        set upload=1&goto arg-ok
  69 if /i "%1"=="small-icu"     set i18n_arg=%1&goto arg-ok
  70 if /i "%1"=="full-icu"      set i18n_arg=%1&goto arg-ok
  71 if /i "%1"=="intl-none"     set i18n_arg=%1&goto arg-ok
  72 if /i "%1"=="download-all"  set download_arg="--download=all"&goto arg-ok
  73
  74 echo Warning: ignoring invalid command line option `%1`.
  75
  76 :arg-ok
  77 :arg-ok
  78 shift
  79 goto next-arg
  80 if defined build_release (
  81   set nosnapshot=1
  82   set config=Release
  83   set msi=1
  84   set licensertf=1
  85   set download_arg="--download=all"
  86   set i18n_arg=small-icu
  87 )
  88
  89
  90 :args-done
  91 if "%config%"=="Debug" set debug_arg=--debug
  92 if defined nosnapshot set snapshot_arg=--without-snapshot
  93 if defined noetw set noetw_arg=--without-etw& set noetw_msi_arg=/p:NoETW=1
  94 if defined noperfctr set noperfctr_arg=--without-perfctr& set noperfctr_msi_arg=/p:NoPerfCtr=1
  95 if defined RELEASE_URLBASE set release_urlbase_arg=--release-urlbase=%RELEASE_URLBASE%
  96
  97 if "%i18n_arg%"=="full-icu" set i18n_arg=--with-intl=full-icu
  98 if "%i18n_arg%"=="small-icu" set i18n_arg=--with-intl=small-icu
  99 if "%i18n_arg%"=="intl-none" set i18n_arg=--with-intl=none
 100
 101 call :getnodeversion || exit /b 1
 102
 103 @rem Set environment for msbuild
 104
 105 @rem Look for Visual Studio 2015
 106 echo Looking for Visual Studio 2015
 107 if not defined VS140COMNTOOLS goto vc-set-2013
 108 if not exist "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat" goto vc-set-2013
 109 echo Found Visual Studio 2015
 110 if defined msi (
 111   echo Looking for WiX installation for Visual Studio 2015...
 112   if not exist "%WIX%\SDK\VS2015" (
 113     echo Failed to find WiX install for Visual Studio 2015
 114     echo VS2015 support for WiX is only present starting at version 3.10
 115     goto vc-set-2013
 116   )
 117 )
 118 if "%VCVARS_VER%" NEQ "140" (
 119   call "%VS140COMNTOOLS%\..\..\vc\vcvarsall.bat"
 120   SET VCVARS_VER=140
 121 )
 122 if not defined VCINSTALLDIR goto vc-set-2013
 123 set GYP_MSVS_VERSION=2015
 124 set PLATFORM_TOOLSET=v140
 125 goto msbuild-found
 126
 127 :vc-set-2013
 128 @rem Look for Visual Studio 2013
 129 echo Looking for Visual Studio 2013
 130 if not defined VS120COMNTOOLS goto msbuild-not-found
 131 if not exist "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat" goto msbuild-not-found
 132 echo Found Visual Studio 2013
 133 if defined msi (
 134   echo Looking for WiX installation for Visual Studio 2013...
 135   if not exist "%WIX%\SDK\VS2013" (
 136     echo Failed to find WiX install for Visual Studio 2013
 137     echo VS2013 support for WiX is only present starting at version 3.8
 138     goto vc-set-2012
 139   )
 140 )
 141 if "%VCVARS_VER%" NEQ "120" (
 142   call "%VS120COMNTOOLS%\..\..\vc\vcvarsall.bat"
 143   SET VCVARS_VER=120
 144 )
 145 if not defined VCINSTALLDIR goto msbuild-not-found
 146 set GYP_MSVS_VERSION=2013
 147 set PLATFORM_TOOLSET=v120
 148 goto msbuild-found
 149
 150 :msbuild-not-found
 151 echo Failed to find Visual Studio installation.
 152 goto exit
 153
 154 :wix-not-found
 155 echo Build skipped. To generate installer, you need to install Wix.
 156 goto run
 157
 158 :msbuild-found
 159
 160 :project-gen
 161 @rem Skip project generation if requested.
 162 if defined noprojgen goto msbuild
 163
 164 @rem Generate the VS project.
 165 python configure %download_arg% %i18n_arg% %debug_arg% %snapshot_arg% %noetw_arg% %noperfctr_arg% --dest-cpu=%target_arch% --tag=%TAG%
 166 if errorlevel 1 goto create-msvs-files-failed
 167 if not exist node.sln goto create-msvs-files-failed
 168 echo Project files generated.
 169
 170 :msbuild
 171 @rem Skip build if requested.
 172 if defined nobuild goto sign
 173
 174 @rem Build the sln with msbuild.
 175 msbuild node.sln /m /t:%target% /p:Configuration=%config% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 176 if errorlevel 1 goto exit
 177 if "%target%" == "Clean" goto exit
 178
 179 :sign
 180 @rem Skip signing if the `nosign` option was specified.
 181 if defined nosign goto licensertf
 182
 183 signtool sign /a /d "node" /t http://timestamp.globalsign.com/scripts/timestamp.dll Release\node.exe
 184 if errorlevel 1 echo Failed to sign exe&goto exit
 185
 186 :licensertf
 187 @rem Skip license.rtf generation if not requested.
 188 if not defined licensertf goto msi
 189
 190 %config%\node tools\license2rtf.js < LICENSE > %config%\license.rtf
 191 if errorlevel 1 echo Failed to generate license.rtf&goto exit
 192
 193 :msi
 194 @rem Skip msi generation if not requested
 195 if not defined msi goto run
 196
 197 :msibuild
 198 echo Building node-v%FULLVERSION%-%target_arch%.msi
 199 msbuild "%~dp0tools\msvs\msi\nodemsi.sln" /m /t:Clean,Build /p:PlatformToolset=%PLATFORM_TOOLSET% /p:GypMsvsVersion=%GYP_MSVS_VERSION% /p:Configuration=%config% /p:Platform=%target_arch% /p:NodeVersion=%NODE_VERSION% /p:FullVersion=%FULLVERSION% /p:DistTypeDir=%DISTTYPEDIR% %noetw_msi_arg% %noperfctr_msi_arg% /clp:NoSummary;NoItemAndPropertyList;Verbosity=minimal /nologo
 200 if errorlevel 1 goto exit
 201
 202 if defined nosign goto upload
 203 signtool sign /a /d "node" /t http://timestamp.globalsign.com/scripts/timestamp.dll node-v%FULLVERSION%-%target_arch%.msi
 204 if errorlevel 1 echo Failed to sign msi&goto exit
 205
 206 :upload
 207 @rem Skip upload if not requested
 208 if not defined upload goto run
 209
 210 if not defined SSHCONFIG (
 211   echo SSHCONFIG is not set for upload
 212   exit /b 1
 213 )
 214 if not defined STAGINGSERVER set STAGINGSERVER=node-www
 215 ssh -F %SSHCONFIG% %STAGINGSERVER% "mkdir -p staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%"
 216 scp -F %SSHCONFIG% Release\node.exe %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/node.exe
 217 scp -F %SSHCONFIG% Release\node.lib %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%/node.lib
 218 scp -F %SSHCONFIG% node-v%FULLVERSION%-%target_arch%.msi %STAGINGSERVER%:staging/%DISTTYPEDIR%/v%FULLVERSION%/
 219 ssh -F %SSHCONFIG% %STAGINGSERVER% "touch staging/%DISTTYPEDIR%/v%FULLVERSION%/node-v%FULLVERSION%-%target_arch%.msi.done staging/%DISTTYPEDIR%/v%FULLVERSION%/win-%target_arch%.done"
 220
 221 :run
 222 @rem Run tests if requested.
 223
 224 :build-node-weak
 225 @rem Build node-weak if required
 226 if "%buildnodeweak%"=="" goto run-tests
 227 "%config%\node" deps\npm\node_modules\node-gyp\bin\node-gyp rebuild --directory="%~dp0test\gc\node_modules\weak" --nodedir="%~dp0."
 228 if errorlevel 1 goto build-node-weak-failed
 229 goto run-tests
 230
 231 :build-node-weak-failed
 232 echo Failed to build node-weak.
 233 goto exit
 234
 235 :run-tests
 236 if "%test_args%"=="" goto jslint
 237 if "%config%"=="Debug" set test_args=--mode=debug %test_args%
 238 if "%config%"=="Release" set test_args=--mode=release %test_args%
 239 echo running 'cctest'
 240 "%config%\cctest"
 241 echo running 'python tools\test.py %test_args%'
 242 python tools\test.py %test_args%
 243 goto jslint
 244
 245 :jslint
 246 if not defined jslint goto exit
 247 echo running jslint
 248 %config%\node tools\eslint\bin\eslint.js src lib test --rulesdir tools\eslint-rules --reset --quiet
 249 goto exit
 250
 251 :create-msvs-files-failed
 252 echo Failed to create vc project files.
 253 goto exit
 254
 255 :help
 256 echo vcbuild.bat [debug/release] [msi] [test-all/test-uv/test-internet/test-pummel/test-simple/test-message] [clean] [noprojgen] [small-icu/full-icu/intl-none] [nobuild] [nosign] [x86/x64] [download-all]
 257 echo Examples:
 258 echo   vcbuild.bat                : builds release build
 259 echo   vcbuild.bat debug          : builds debug build
 260 echo   vcbuild.bat release msi    : builds release build and MSI installer package
 261 echo   vcbuild.bat test           : builds debug build and runs tests
 262 goto exit
 263
 264 :exit
 265 echo   vcbuild.bat build-release  : builds the release distribution as used by nodejs.org
 266 goto :EOF
 267
 268 rem ***************
 269 rem   Subroutines
 270 rem ***************
 271
 272 :getnodeversion
 273 set NODE_VERSION=
 274 set TAG=
 275 set FULLVERSION=
 276
 277 for /F "usebackq tokens=*" %%i in (`python "%~dp0tools\getnodeversion.py"`) do set NODE_VERSION=%%i
 278 if not defined NODE_VERSION (
 279   echo Cannot determine current version of Node.js
 280   exit /b 1
 281 )
 282
 283 if not defined DISTTYPE set DISTTYPE=release
 284 if "%DISTTYPE%"=="release" (
 285   set FULLVERSION=%NODE_VERSION%
 286   goto exit
 287 )
 288 if "%DISTTYPE%"=="custom" (
 289   if not defined CUSTOMTAG (
 290     echo "CUSTOMTAG is not set for DISTTYPE=custom"
 291     exit /b 1
 292   )
 293   set TAG=%CUSTOMTAG%
 294 )
 295 if not "%DISTTYPE%"=="custom" (
 296   if not defined DATESTRING (
 297     echo "DATESTRING is not set for nightly"
 298     exit /b 1
 299   )
 300   if not defined COMMIT (
 301     echo "COMMIT is not set for nightly"
 302     exit /b 1
 303   )
 304   if not "%DISTTYPE%"=="nightly" (
 305     if not "%DISTTYPE%"=="next-nightly" (
 306       echo "DISTTYPE is not release, custom, nightly or next-nightly"
 307       exit /b 1
 308     )
 309   )
 310   set TAG=%DISTTYPE%%DATESTRING%%COMMIT%
 311 )
 312 set FULLVERSION=%NODE_VERSION%-%TAG%
 313
 314 :exit
 315 if not defined DISTTYPEDIR set DISTTYPEDIR=%DISTTYPE%
 316 goto :EOF