ui.inc

   1 ;; $Id$
   2 ;; -----------------------------------------------------------------------
   3 ;;
   4 ;;   Copyright 1994-2002 H. Peter Anvin - All Rights Reserved
   5 ;;
   6 ;;   This program is free software; you can redistribute it and/or modify
   7 ;;   it under the terms of the GNU General Public License as published by
   8 ;;   the Free Software Foundation, Inc., 53 Temple Place Ste 330,
   9 ;;   Bostom MA 02111-1307, USA; either version 2 of the License, or
  10 ;;   (at your option) any later version; incorporated herein by reference.
  11 ;;
  12 ;; -----------------------------------------------------------------------
  13
  14 ;
  15 ; This file should be entered with the config file open (for getc)
  16 ;
  17                 call parse_config               ; Parse configuration file
  18 no_config_file:
  19 ;
  20 ; Check whether or not we are supposed to display the boot prompt.
  21 ;
  22 check_for_key:
  23                 cmp word [ForcePrompt],byte 0   ; Force prompt?
  24                 jnz enter_command
  25                 test byte [KbdFlags],5Bh        ; Caps, Scroll, Shift, Alt
  26                 jz auto_boot                    ; If neither, default boot
  27
  28 enter_command:
  29                 mov si,boot_prompt
  30                 call cwritestr
  31
  32                 mov byte [FuncFlag],0           ; <Ctrl-F> not pressed
  33                 mov di,command_line
  34 ;
  35 ; get the very first character -- we can either time
  36 ; out, or receive a character press at this time.  Some dorky BIOSes stuff
  37 ; a return in the buffer on bootup, so wipe the keyboard buffer first.
  38 ;
  39 clear_buffer:   mov ah,11h                      ; Check for pending char
  40                 int 16h
  41                 jz get_char_time
  42                 mov ah,10h                      ; Get char
  43                 int 16h
  44                 jmp short clear_buffer
  45 get_char_time:
  46                 call vgashowcursor
  47                 RESET_IDLE
  48                 mov cx,[KbdTimeOut]
  49                 and cx,cx
  50                 jz get_char                     ; Timeout == 0 -> no timeout
  51                 inc cx                          ; The first loop will happen
  52                                                 ; immediately as we don't
  53                                                 ; know the appropriate DX value
  54 time_loop:      push cx
  55 tick_loop:      push dx
  56                 call pollchar
  57                 jnz get_char_pop
  58                 mov dx,[BIOS_timer]             ; Get time "of day"
  59                 pop ax
  60                 cmp dx,ax                       ; Has the timer advanced?
  61                 je tick_loop
  62                 pop cx
  63                 DO_IDLE
  64                 loop time_loop                  ; If so, decrement counter
  65
  66                 ; Timeout!!!!
  67                 call vgahidecursor
  68                 mov si,Ontimeout                ; Copy ontimeout command
  69                 mov cx,[OntimeoutLen]           ; if we have one...
  70                 rep movsb
  71 .stddefault:
  72                 jmp command_done
  73
  74 get_char_pop:   pop eax                         ; Clear stack
  75 get_char:
  76                 call vgashowcursor
  77                 call getchar
  78                 call vgahidecursor
  79                 and al,al
  80                 jz func_key
  81
  82 got_ascii:      cmp al,7Fh                      ; <DEL> == <BS>
  83                 je backspace
  84                 cmp al,' '                      ; ASCII?
  85                 jb not_ascii
  86                 ja enter_char
  87                 cmp di,command_line             ; Space must not be first
  88                 je short get_char
  89 enter_char:     test byte [FuncFlag],1
  90                 jz .not_ctrl_f
  91                 mov byte [FuncFlag],0
  92                 cmp al,'0'
  93                 jb .not_ctrl_f
  94                 je ctrl_f_0
  95                 cmp al,'9'
  96                 jbe ctrl_f
  97 .not_ctrl_f:    cmp di,max_cmd_len+command_line ; Check there's space
  98                 jnb short get_char
  99                 stosb                           ; Save it
 100                 call writechr                   ; Echo to screen
 101                 jmp short get_char
 102 not_ascii:      mov byte [FuncFlag],0
 103                 cmp al,0Dh                      ; Enter
 104                 je command_done
 105                 cmp al,06h                      ; <Ctrl-F>
 106                 je set_func_flag
 107                 cmp al,15h                      ; <Ctrl-U>
 108                 je kill_command                 ; Kill input line
 109                 cmp al,16h                      ; <Ctrl-V>
 110                 je print_version
 111                 cmp al,08h                      ; Backspace
 112                 jne get_char
 113 backspace:      cmp di,command_line             ; Make sure there is anything
 114                 je get_char                     ; to erase
 115                 dec di                          ; Unstore one character
 116                 mov si,wipe_char                ; and erase it from the screen
 117                 call cwritestr
 118                 jmp short get_char_2
 119
 120 kill_command:
 121                 call crlf
 122                 jmp enter_command
 123
 124 set_func_flag:
 125                 mov byte [FuncFlag],1
 126 get_char_2:
 127                 jmp short get_char
 128
 129 ctrl_f_0:       add al,10                       ; <Ctrl-F>0 == F10
 130 ctrl_f:         sub al,'1'
 131                 xor ah,ah
 132                 jmp short show_help
 133
 134 func_key:
 135                 ; AL = 0 if we get here
 136                 xchg al,ah
 137                 cmp al,68                       ; F10
 138                 ja short get_char_2
 139                 sub al,59                       ; F1
 140                 jb short get_char_2
 141 show_help:      ; AX = func key # (0 = F1, 9 = F10)
 142                 push di                         ; Save end-of-cmdline pointer
 143                 shl ax,FILENAME_MAX_LG2         ; Convert to pointer
 144                 add ax,FKeyName
 145                 xchg di,ax
 146                 cmp byte [di],NULLFILE
 147                 je short fk_nofile              ; Undefined F-key
 148                 call searchdir
 149                 jz short fk_nofile              ; File not found
 150                 push si
 151                 call crlf
 152                 pop si
 153                 call get_msg_file
 154                 jmp short fk_wrcmd
 155
 156 print_version:
 157                 push di                         ; Command line write pointer
 158                 mov si,syslinux_banner
 159                 call cwritestr
 160                 mov si,copyright_str
 161                 call cwritestr
 162
 163                 ; ... fall through ...
 164
 165                 ; Write the boot prompt and command line again and
 166                 ; wait for input.  Note that this expects the cursor
 167                 ; to already have been CRLF'd, and that the old value
 168                 ; of DI (the command line write pointer) is on the stack.
 169 fk_wrcmd:
 170                 mov si,boot_prompt
 171                 call cwritestr
 172                 pop di                          ; Command line write pointer
 173                 push di
 174                 mov byte [di],0                 ; Null-terminate command line
 175                 mov si,command_line
 176                 call cwritestr                  ; Write command line so far
 177 fk_nofile:      pop di
 178                 jmp short get_char_2
 179 auto_boot:
 180                 mov si,default_cmd
 181                 mov di,command_line
 182                 mov cx,(max_cmd_len+4) >> 2
 183                 rep movsd
 184                 jmp short load_kernel
 185 command_done:
 186                 call crlf
 187                 cmp di,command_line             ; Did we just hit return?
 188                 je auto_boot
 189                 xor al,al                       ; Store a final null
 190                 stosb
 191
 192 load_kernel:                                    ; Load the kernel now
 193 ;
 194 ; First we need to mangle the kernel name the way DOS would...
 195 ;
 196                 mov si,command_line
 197                 mov di,KernelName
 198                 push si
 199                 push di
 200                 call mangle_name
 201                 pop di
 202                 pop si
 203 ;
 204 ; Fast-forward to first option (we start over from the beginning, since
 205 ; mangle_name doesn't necessarily return a consistent ending state.)
 206 ;
 207 clin_non_wsp:   lodsb
 208                 cmp al,' '
 209                 ja clin_non_wsp
 210 clin_is_wsp:    and al,al
 211                 jz clin_opt_ptr
 212                 lodsb
 213                 cmp al,' '
 214                 jbe clin_is_wsp
 215 clin_opt_ptr:   dec si                          ; Point to first nonblank
 216                 mov [CmdOptPtr],si              ; Save ptr to first option
 217 ;
 218 ; If "allowoptions 0", put a null character here in order to ignore any
 219 ; user-specified options.
 220 ;
 221                 mov ax,[AllowOptions]
 222                 and ax,ax
 223                 jnz clin_opt_ok
 224                 mov [si],al
 225 clin_opt_ok:
 226
 227 ;
 228 ; Now check if it is a "virtual kernel"
 229 ;
 230                 mov cx,[VKernelCtr]
 231                 push ds
 232                 push word vk_seg
 233                 pop ds
 234                 cmp cx,byte 0
 235                 je not_vk
 236                 xor si,si                       ; Point to first vkernel
 237 vk_check:       pusha
 238                 mov cx,FILENAME_MAX
 239                 repe cmpsb                      ; Is this it?
 240                 je vk_found
 241                 popa
 242                 add si,vk_size
 243                 loop vk_check
 244 not_vk:         pop ds
 245 ;
 246 ; Not a "virtual kernel" - check that's OK and construct the command line
 247 ;
 248                 cmp word [AllowImplicit],byte 0
 249                 je bad_implicit
 250                 push es
 251                 push si
 252                 push di
 253                 mov di,real_mode_seg
 254                 mov es,di
 255                 mov si,AppendBuf
 256                 mov di,cmd_line_here
 257                 mov cx,[AppendLen]
 258                 rep movsb
 259                 mov [CmdLinePtr],di
 260                 pop di
 261                 pop si
 262                 pop es
 263 ;
 264 ; Find the kernel on disk
 265 ;
 266 get_kernel:     mov byte [KernelName+FILENAME_MAX],0    ; Zero-terminate filename/extension
 267 %if IS_SYSLINUX || IS_MDSLINUX                  ; SYSLINUX has to deal with DOS mangled names...
 268                 mov eax,[KernelName+8]          ; Save initial extension
 269                 mov [exten_table_end],eax       ; Last case == initial ext.
 270 %else
 271                 mov di,KernelName
 272                 xor al,al
 273                 mov cx,FILENAME_MAX-5           ; Need 4 chars + null
 274                 repne scasb                     ; Scan for final null
 275                 jne .no_skip
 276                 dec di                          ; Point to final null
 277 .no_skip:       mov [KernelExtPtr],di
 278 %endif
 279                 mov bx,exten_table
 280 .search_loop:   push bx
 281                 mov di,KernelName               ; Search on disk
 282                 call searchdir
 283                 pop bx
 284                 jnz kernel_good
 285                 mov eax,[bx]                    ; Try a different extension
 286 %if IS_SYSLINUX || IS_MDSLINUX
 287                 mov [KernelName+8],eax
 288 %else
 289                 mov si,[KernelExtPtr]
 290                 mov [si],eax
 291                 mov byte [si+4],0
 292 %endif
 293                 add bx,byte 4
 294                 cmp bx,exten_table_end
 295                 jna .search_loop                ; allow == case (final case)
 296                 ; Fall into bad_kernel
 297 ;
 298 ; bad_kernel: Kernel image not found
 299 ; bad_implicit: The user entered a nonvirtual kernel name, with "implicit 0"
 300 ;
 301 bad_implicit:
 302 bad_kernel:
 303                 mov cx,[OnerrorLen]
 304                 and cx,cx
 305                 jnz on_error
 306 .really:
 307                 mov si,KernelName
 308                 mov di,KernelCName
 309                 push di
 310                 call unmangle_name              ; Get human form
 311                 mov si,err_notfound             ; Complain about missing kernel
 312                 call cwritestr
 313                 pop si                          ; KernelCName
 314                 call cwritestr
 315                 mov si,crlf_msg
 316                 jmp abort_load                  ; Ask user for clue
 317
 318 ;
 319 ; on_error: bad kernel, but we have onerror set
 320 ;
 321 on_error:
 322                 mov si,Onerror
 323                 mov di,command_line
 324                 push si                         ; <A>
 325                 push di                         ; <B>
 326                 push cx                         ; <C>
 327                 push cx                         ; <D>
 328                 push di                         ; <E>
 329                 repe cmpsb
 330                 pop di                          ; <E> di == command_line
 331                 pop bx                          ; <D> bx == [OnerrorLen]
 332                 je bad_kernel.really            ; Onerror matches command_line already
 333                 neg bx                          ; bx == -[OnerrorLen]
 334                 lea cx,[max_cmd_len+bx]
 335                 ; CX == max_cmd_len-[OnerrorLen]
 336                 mov di,command_line+max_cmd_len-1
 337                 mov byte [di+1],0               ; Enforce null-termination
 338                 lea si,[di+bx]
 339                 std
 340                 rep movsb                       ; Make space in command_line
 341                 cld
 342                 pop cx                          ; <C> cx == [OnerrorLen]
 343                 pop di                          ; <B> di == command_line
 344                 pop si                          ; <A> si  == Onerror
 345                 rep movsb
 346                 jmp load_kernel
 347
 348 ;
 349 ; vk_found: We *are* using a "virtual kernel"
 350 ;
 351 vk_found:       popa
 352                 push di
 353                 mov di,VKernelBuf
 354                 mov cx,vk_size >> 2
 355                 rep movsd
 356                 push es                         ; Restore old DS
 357                 pop ds
 358                 push es
 359                 push word real_mode_seg
 360                 pop es
 361                 mov di,cmd_line_here
 362                 mov si,VKernelBuf+vk_append
 363                 mov cx,[VKernelBuf+vk_appendlen]
 364                 rep movsb
 365                 mov [CmdLinePtr],di             ; Where to add rest of cmd
 366                 pop es
 367                 pop di                          ; DI -> KernelName
 368                 push di
 369                 mov si,VKernelBuf+vk_rname
 370                 mov cx,FILENAME_MAX             ; We need ECX == CX later
 371                 rep movsb
 372                 pop di
 373 %if IS_PXELINUX
 374                 mov al,[VKernelBuf+vk_ipappend]
 375                 mov [IPAppend],al
 376 %endif
 377                 xor bx,bx                       ; Try only one version
 378
 379 %if IS_SYSLINUX || IS_MDSLINUX
 380                 jmp get_kernel
 381 %else
 382                 ; Is this a "localboot" pseudo-kernel?
 383                 cmp byte [VKernelBuf+vk_rname], 0
 384                 jne get_kernel          ; No, it's real, go get it
 385
 386                 mov ax, [VKernelBuf+vk_rname+1]
 387                 jmp local_boot
 388 %endif
 389
 390 ;
 391 ; kernel_corrupt: Called if the kernel file does not seem healthy
 392 ;
 393 kernel_corrupt: mov si,err_notkernel
 394                 jmp abort_load
 395 ;
 396 ; This is it!  We have a name (and location on the disk)... let's load
 397 ; that sucker!!  First we have to decide what kind of file this is; base
 398 ; that decision on the file extension.  The following extensions are
 399 ; recognized; case insensitive:
 400 ;
 401 ; .com  - COMBOOT image
 402 ; .cbt  - COMBOOT image
 403 ; .c32  - COM32 image
 404 ; .bs   - Boot sector
 405 ; .0    - PXE bootstrap program (PXELINUX only)
 406 ; .bin  - Boot sector
 407 ; .bss  - Boot sector, but transfer over DOS superblock (SYSLINUX only)
 408 ; .img  - Floppy image (ISOLINUX only)
 409 ;
 410 ; Anything else is assumed to be a Linux kernel.
 411 ;
 412 kernel_good:
 413                 pusha
 414                 mov si,KernelName
 415                 mov di,KernelCName
 416                 call unmangle_name
 417                 sub di,KernelCName
 418                 mov [KernelCNameLen],di
 419                 popa
 420
 421 %if IS_SYSLINUX || IS_MDSLINUX
 422                 mov ecx,[KernelName+7]
 423                 mov cl,'.'
 424 %else
 425                 push di
 426                 push ax
 427                 mov di,KernelName
 428                 xor al,al
 429                 mov cx,FILENAME_MAX
 430                 repne scasb
 431                 jne .one_step
 432                 dec di
 433 .one_step:      mov ecx,[di-4]                  ; 4 bytes before end
 434                 pop ax
 435                 pop di
 436 %endif
 437
 438 ;
 439 ; At this point, DX:AX contains the size of the kernel, and SI contains
 440 ; the file handle/cluster pointer.
 441 ;
 442                 or ecx,20202000h                ; Force lower case
 443
 444                 cmp ecx,'.com'
 445                 je is_comboot_image
 446                 cmp ecx,'.cbt'
 447                 je is_comboot_image
 448                 cmp ecx,'.c32'
 449                 je is_com32_image
 450 %if IS_ISOLINUX
 451                 cmp ecx,'.img'
 452                 je is_disk_image
 453 %endif
 454                 cmp ecx,'.bss'
 455                 je is_bss_sector
 456                 cmp ecx,'.bin'
 457                 je is_bootsector
 458 %if IS_SYSLINUX || IS_MDSLINUX
 459                 cmp ecx,'.bs '
 460                 je is_bootsector
 461                 cmp ecx,'.0  '
 462                 je is_bootsector
 463 %else
 464                 shr ecx,8
 465                 cmp ecx,'.bs'
 466                 je is_bootsector
 467                 shr ecx,8
 468                 cmp cx,'.0'
 469                 je is_bootsector
 470 %endif
 471                 ; Otherwise Linux kernel
 472