tools/qmlviewer/startup/startup.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the QtDeclarative module of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:LGPL$
   9 ** GNU Lesser General Public License Usage
  10 ** This file may be used under the terms of the GNU Lesser General Public
  11 ** License version 2.1 as published by the Free Software Foundation and
  12 ** appearing in the file LICENSE.LGPL included in the packaging of this
  13 ** file. Please review the following information to ensure the GNU Lesser
  14 ** General Public License version 2.1 requirements will be met:
  15 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  16 **
  17 ** In addition, as a special exception, Nokia gives you certain additional
  18 ** rights. These rights are described in the Nokia Qt LGPL Exception
  19 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  20 **
  21 ** GNU General Public License Usage
  22 ** Alternatively, this file may be used under the terms of the GNU General
  23 ** Public License version 3.0 as published by the Free Software Foundation
  24 ** and appearing in the file LICENSE.GPL included in the packaging of this
  25 ** file. Please review the following information to ensure the GNU General
  26 ** Public License version 3.0 requirements will be met:
  27 ** http://www.gnu.org/copyleft/gpl.html.
  28 **
  29 ** Other Usage
  30 ** Alternatively, this file may be used in accordance with the terms and
  31 ** conditions contained in a signed written agreement between you and Nokia.
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 1.0
  43
  44 Rectangle {
  45     id: treatsApp
  46     width: 800
  47     height: 480
  48     color: "darkgrey"
  49     Component.onCompleted: treatsApp.state = "part1"
  50     signal animationFinished
  51
  52     Item {
  53         width: 800
  54         height: 480
  55         anchors.centerIn: parent
  56         clip: true
  57
  58         Logo {
  59             id: logo
  60             x: 165
  61             y: 35
  62             rotation: -15
  63             scale: 0.6
  64             opacity: 0
  65             onAnimationFinished: treatsApp.animationFinished();
  66         }
  67
  68         Item {
  69             id: quickblur
  70             x: 800//325
  71             y: 344
  72             Image {
  73                 id: blurText
  74                 source: "quick-blur.png"
  75             }
  76             Image {
  77                 id: quickregular
  78                 x: -1
  79                 y: 0
  80                 opacity: 0
  81                 source: "quick-regular.png"
  82             }
  83             Image {
  84                 id: star
  85                 x: -1
  86                 y: 0
  87                 opacity: 0
  88                 source: "white-star.png"
  89                 smooth: true
  90                 NumberAnimation on rotation {
  91                     from: 0
  92                     to: 360
  93                     loops: 3
  94                     running: true
  95                     duration: 2000
  96                 }
  97             }
  98         }
  99     }
 100
 101     states: [
 102         State {
 103             name: "part1"
 104             PropertyChanges {
 105                 target: logo
 106                 scale: 0.8
 107                 opacity: 1
 108                 rotation: 0
 109             }
 110             PropertyChanges {
 111                 target: treatsApp
 112                 color: "black"
 113             }
 114             PropertyChanges {
 115                 target: logo
 116                 y: 10
 117             }
 118             PropertyChanges {
 119                 target: quickblur
 120                 x: logo.x + 145
 121             }
 122             PropertyChanges {
 123                 target: blurText
 124                 opacity: 0
 125             }
 126             PropertyChanges {
 127                 target: quickregular
 128                 opacity: 1
 129             }
 130             PropertyChanges {
 131                 target: star
 132                 x: -7
 133                 y: -37
 134             }
 135         }
 136     ]
 137
 138     transitions: [
 139         Transition {
 140             ParallelAnimation {
 141                 NumberAnimation { target: logo; property: "opacity"; duration: 500 }
 142                 NumberAnimation { target: logo; property: "scale"; duration: 4000; }
 143                 NumberAnimation { target: logo; property: "rotation"; duration: 2000; easing.type: "OutBack"}
 144                 ColorAnimation { duration: 3000}
 145                 SequentialAnimation {
 146                     PauseAnimation { duration: 1000 }
 147                     ScriptAction { script: logo.logoState = "showBlueprint" }
 148                     PauseAnimation { duration: 800 }
 149                     ScriptAction { script: logo.logoState = "finale" }
 150                     PauseAnimation { duration: 800 }
 151                     ParallelAnimation {
 152                         NumberAnimation { target: quickblur; property: "x"; duration: 200;}
 153                         SequentialAnimation {
 154                             PauseAnimation { duration: 200}
 155                             ParallelAnimation {
 156                                 NumberAnimation { target: blurText; property: "opacity"; duration: 300;}
 157                                 NumberAnimation { target: quickregular; property: "opacity"; duration: 300;}
 158                             }
 159                             NumberAnimation { target: star; property: "opacity"; from: 0; to: 1; duration: 500 }
 160                             PauseAnimation { duration: 200 }
 161                             NumberAnimation { target: star; property: "opacity"; from: 1; to: 0; duration: 500 }
 162                         }
 163                         SequentialAnimation {
 164                             PauseAnimation { duration: 150}
 165                             NumberAnimation { target: logo; property: "y"; duration: 300; easing.type: "OutBounce" }
 166                         }
 167                     }
 168                 }
 169             }
 170         }
 171     ]
 172
 173 } // treatsApp