third_party/pigweed/repo/bootstrap.bat

   1 :<<"::WINDOWS_ONLY"
   2 @echo off
   3 :: Copyright 2020 The Pigweed Authors
   4 ::
   5 :: Licensed under the Apache License, Version 2.0 (the "License"); you may not
   6 :: use this file except in compliance with the License. You may obtain a copy of
   7 :: the License at
   8 ::
   9 ::     https://www.apache.org/licenses/LICENSE-2.0
  10 ::
  11 :: Unless required by applicable law or agreed to in writing, software
  12 :: distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
  13 :: WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
  14 :: License for the specific language governing permissions and limitations under
  15 :: the License.
  16 ::WINDOWS_ONLY
  17 :; echo "ERROR: Attempting to run Windows .bat from a Unix/POSIX shell!"
  18 :; echo "Instead, run the following command."
  19 :; echo ""
  20 :; echo "    source ./bootstrap.sh"
  21 :; echo ""
  22 :<<"::WINDOWS_ONLY"
  23
  24 :: Pigweed Windows environment setup.
  25
  26 :: WARNING: Multi-line "if" statements can be dangerous!
  27 ::
  28 :: Example:
  29 ::  call do_foo
  30 ::  if [expression] (
  31 ::    call cmd_a
  32 ::    set my_var = %ERRORLEVEL%
  33 ::    call final_script --flag %my_var%
  34 ::  )
  35 :: Batch evaluates these expressions in a way that will produce unexpected
  36 :: behavior. It appears that when each line is executed, it does not affect
  37 :: local context until the entire expression is complete. In this example,
  38 :: ERRORLEVEL does not reflect `call cmd_a`, but whatever residual state was
  39 :: present from `do_foo`. Similarly, in the call to `final_script`, `my_var`
  40 :: will NOT be valid as the variable `set` doesn't apply until the entire `if`
  41 :: expression completes.
  42 :: This script only uses multi-line if statements to `goto` after an operation.
  43
  44 :: If PW_CHECKOUT_ROOT is set, use it. Users should not set this variable.
  45 :: It's used because when one batch script invokes another the Powershell magic
  46 :: below doesn't work. To reinforce that users should not be using
  47 :: PW_CHECKOUT_ROOT, it is cleared here after it is used, and other pw tools
  48 :: will complain if they see that variable set.
  49 :: TODO(mohrr) find out a way to do this without PW_CHECKOUT_ROOT.
  50
  51 :: ~dp0 is the batchism for the directory in which a .bat file resides.
  52 if "%PW_CHECKOUT_ROOT%"=="" ^
  53 set "PW_ROOT=%~dp0." &^
  54 goto select_python
  55
  56 :: Since PW_CHECKOUT_ROOT is set, use it.
  57 set "PW_ROOT=%PW_CHECKOUT_ROOT%"
  58 set "PW_CHECKOUT_ROOT="
  59
  60 :select_python
  61 :: Allow forcing a specific Python version through the environment variable
  62 :: PW_BOOTSTRAP_PYTHON. Otherwise, use the system Python if one exists.
  63 if not "%PW_BOOTSTRAP_PYTHON%" == "" (
  64   set "python=%PW_BOOTSTRAP_PYTHON%"
  65   goto find_environment_root
  66 )
  67
  68 :: Detect python installation.
  69 where python >NUL 2>&1
  70 if %ERRORLEVEL% EQU 0 (
  71   set "python=python"
  72   goto find_environment_root
  73 )
  74
  75 echo.
  76 echo Error: no system Python present
  77 echo.
  78 echo   Pigweed's bootstrap process requires a local system Python.
  79 echo   Please install Python on your system, add it to your PATH
  80 echo   and re-try running bootstrap.
  81 goto finish
  82
  83
  84 :find_environment_root
  85 :: PW_ENVIRONMENT_ROOT allows developers to specify where the environment should
  86 :: be installed. _PW_ACTUAL_ENVIRONMENT_ROOT is where Pigweed keeps that
  87 :: information. This separation allows Pigweed to assume PW_ENVIRONMENT_ROOT
  88 :: came from the developer and not from a previous bootstrap possibly from
  89 :: another workspace.
  90
  91 :: Not prefixing environment with "." since that doesn't hide it anyway.
  92 if "%PW_ENVIRONMENT_ROOT%"=="" (
  93   set "_PW_ACTUAL_ENVIRONMENT_ROOT=%PW_ROOT%\environment"
  94 ) else (
  95   set "_PW_ACTUAL_ENVIRONMENT_ROOT=%PW_ENVIRONMENT_ROOT%"
  96 )
  97
  98 set "shell_file=%_PW_ACTUAL_ENVIRONMENT_ROOT%\activate.bat"
  99
 100 set "_pw_start_script=%PW_ROOT%\pw_env_setup\py\pw_env_setup\windows_env_start.py"
 101
 102 if "%PW_PROJECT_ROOT%"=="" set "PW_PROJECT_ROOT=%PW_ROOT%"
 103
 104 :: If PW_SKIP_BOOTSTRAP is set, only run the activation stage instead of the
 105 :: complete env_setup.
 106 if not "%PW_SKIP_BOOTSTRAP%" == "" goto skip_bootstrap
 107
 108 :: Without the trailing slash in %PW_ROOT%/, batch combines that token with
 109 :: the --shell-file argument.
 110 call "%python%" "%PW_ROOT%\pw_env_setup\py\pw_env_setup\env_setup.py" ^
 111     --pw-root "%PW_ROOT%" ^
 112     --shell-file "%shell_file%" ^
 113     --install-dir "%_PW_ACTUAL_ENVIRONMENT_ROOT%" ^
 114     --use-pigweed-defaults ^
 115     --virtualenv-gn-target "%PW_ROOT%#:target_support_packages.install" ^
 116     --project-root "%PW_PROJECT_ROOT%"
 117 goto activate_shell
 118
 119 :skip_bootstrap
 120 if exist "%shell_file%" (
 121   call "%python%" "%_pw_start_script%"
 122 ) else (
 123   call "%python%" "%_pw_start_script%" --no-shell-file
 124   goto finish
 125 )
 126
 127 :activate_shell
 128 call "%shell_file%"
 129
 130 :finish
 131 ::WINDOWS_ONLY