testsuite/lib/libffi.exp

   1 #   Copyright (C) 2003, 2005, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; see the file COPYING3.  If not see
  15 # <http://www.gnu.org/licenses/>.
  16
  17 proc load_gcc_lib { filename } {
  18     global srcdir
  19     load_file $srcdir/lib/$filename
  20 }
  21
  22 load_lib dg.exp
  23 load_lib libgloss.exp
  24 load_gcc_lib target-libpath.exp
  25 load_gcc_lib wrapper.exp
  26
  27
  28 # Define libffi callbacks for dg.exp.
  29
  30 proc libffi-dg-test-1 { target_compile prog do_what extra_tool_flags } {
  31
  32     # To get all \n in dg-output test strings to match printf output
  33     # in a system that outputs it as \015\012 (i.e. not just \012), we
  34     # need to change all \n into \r?\n.  As there is no dejagnu flag
  35     # or hook to do that, we simply change the text being tested.
  36     # Unfortunately, we have to know that the variable is called
  37     # dg-output-text and lives in the caller of libffi-dg-test, which
  38     # is two calls up.  Overriding proc dg-output would be longer and
  39     # would necessarily have the same assumption.
  40     upvar 2 dg-output-text output_match
  41
  42     if { [llength $output_match] > 1 } {
  43         regsub -all "\n" [lindex $output_match 1] "\r?\n" x
  44         set output_match [lreplace $output_match 1 1 $x]
  45     }
  46
  47     # Set up the compiler flags, based on what we're going to do.
  48
  49     set options [list]
  50     switch $do_what {
  51         "compile" {
  52             set compile_type "assembly"
  53             set output_file "[file rootname [file tail $prog]].s"
  54         }
  55         "link" {
  56             set compile_type "executable"
  57             set output_file "[file rootname [file tail $prog]].exe"
  58             # The following line is needed for targets like the i960 where
  59             # the default output file is b.out.  Sigh.
  60         }
  61         "run" {
  62             set compile_type "executable"
  63             # FIXME: "./" is to cope with "." not being in $PATH.
  64             # Should this be handled elsewhere?
  65             # YES.
  66             set output_file "./[file rootname [file tail $prog]].exe"
  67             # This is the only place where we care if an executable was
  68             # created or not.  If it was, dg.exp will try to run it.
  69             remote_file build delete $output_file;
  70         }
  71         default {
  72             perror "$do_what: not a valid dg-do keyword"
  73             return ""
  74         }
  75     }
  76
  77     if { $extra_tool_flags != "" } {
  78         lappend options "additional_flags=$extra_tool_flags"
  79     }
  80
  81     set comp_output [libffi_target_compile "$prog" "$output_file" "$compile_type" $options];
  82
  83
  84     return [list $comp_output $output_file]
  85 }
  86
  87
  88 proc libffi-dg-test { prog do_what extra_tool_flags } {
  89     return [libffi-dg-test-1 target_compile $prog $do_what $extra_tool_flags]
  90 }
  91
  92 proc libffi-init { args } {
  93     global gluefile wrap_flags;
  94     global srcdir
  95     global blddirffi
  96     global objdir
  97     global TOOL_OPTIONS
  98     global tool
  99     global libffi_include
 100     global libffi_link_flags
 101     global tool_root_dir
 102     global ld_library_path
 103
 104     set blddirffi [pwd]/..
 105     verbose "libffi $blddirffi"
 106
 107     set gccdir [lookfor_file $tool_root_dir gcc/libgcc.a]
 108     if {$gccdir != ""} {
 109         set gccdir [file dirname $gccdir]
 110     }
 111     verbose "gccdir $gccdir"
 112
 113     set ld_library_path "."
 114     append ld_library_path ":${gccdir}"
 115
 116     set compiler "${gccdir}/xgcc"
 117     if { [is_remote host] == 0 && [which $compiler] != 0 } {
 118         foreach i "[exec $compiler --print-multi-lib]" {
 119             set mldir ""
 120             regexp -- "\[a-z0-9=_/\.-\]*;" $i mldir
 121             set mldir [string trimright $mldir "\;@"]
 122             if { "$mldir" == "." } {
 123                 continue
 124             }
 125             if { [llength [glob -nocomplain ${gccdir}/${mldir}/libgcc_s*.so.*]] >= 1 } {
 126                 append ld_library_path ":${gccdir}/${mldir}"
 127             }
 128         }
 129     }
 130     # add the library path for libffi.
 131     append ld_library_path ":${blddirffi}/.libs"
 132
 133     verbose "ld_library_path: $ld_library_path"
 134
 135     # Point to the Libffi headers in libffi.
 136     set libffi_include "${blddirffi}/include"
 137     verbose "libffi_include $libffi_include"
 138
 139     set libffi_dir  "${blddirffi}/.libs"
 140     verbose "libffi_dir $libffi_dir"
 141     if { $libffi_dir != "" } {
 142         set libffi_dir [file dirname ${libffi_dir}]
 143         set libffi_link_flags "-L${libffi_dir}/.libs"
 144     }
 145
 146     set_ld_library_path_env_vars
 147     libffi_maybe_build_wrapper "${objdir}/testglue.o"
 148 }
 149
 150 proc libffi_exit { } {
 151     global gluefile;
 152
 153     if [info exists gluefile] {
 154         file_on_build delete $gluefile;
 155         unset gluefile;
 156     }
 157 }
 158
 159 proc libffi_target_compile { source dest type options } {
 160     global gluefile wrap_flags;
 161     global srcdir
 162     global blddirffi
 163     global TOOL_OPTIONS
 164     global libffi_link_flags
 165     global libffi_include
 166     global target_triplet
 167
 168
 169     if { [target_info needs_status_wrapper]!="" && [info exists gluefile] } {
 170         lappend options "libs=${gluefile}"
 171         lappend options "ldflags=$wrap_flags"
 172     }
 173
 174     # TOOL_OPTIONS must come first, so that it doesn't override testcase
 175     # specific options.
 176     if [info exists TOOL_OPTIONS] {
 177         lappend  options [concat "additional_flags=$TOOL_OPTIONS" $options];
 178     }
 179
 180     # search for ffi_mips.h in srcdir, too
 181     lappend options "additional_flags=-I${libffi_include} -I${srcdir}/../include  -I${libffi_include}/.."
 182     lappend options "additional_flags=${libffi_link_flags}"
 183
 184     # Darwin needs a stack execution allowed flag.
 185
 186     if { [istarget "*-*-darwin9*"] || [istarget "*-*-darwin1*"]
 187          || [istarget "*-*-darwin2*"] } {
 188         lappend options "additional_flags=-Wl,-allow_stack_execute"
 189     }
 190
 191     # If you're building the compiler with --prefix set to a place
 192     # where it's not yet installed, then the linker won't be able to
 193     # find the libgcc used by libffi.dylib.  We could pass the
 194     # -dylib_file option, but that's complicated, and it's much easier
 195     # to just make the linker find libgcc using -L options.
 196     if { [string match "*-*-darwin*" $target_triplet] } {
 197         lappend options "libs= -shared-libgcc"
 198     }
 199
 200     if { [string match "*-*-openbsd*" $target_triplet] } {
 201         lappend options "libs= -lpthread"
 202     }
 203
 204     lappend options "libs= -lffi"
 205
 206     if { [string match "aarch64*-*-linux*" $target_triplet] } {
 207         lappend options "libs= -lpthread"
 208     }
 209
 210     verbose "options: $options"
 211     return [target_compile $source $dest $type $options]
 212 }
 213
 214 # Utility routines.
 215
 216 #
 217 # search_for -- looks for a string match in a file
 218 #
 219 proc search_for { file pattern } {
 220     set fd [open $file r]
 221     while { [gets $fd cur_line]>=0 } {
 222         if [string match "*$pattern*" $cur_line] then {
 223             close $fd
 224             return 1
 225         }
 226     }
 227     close $fd
 228     return 0
 229 }
 230
 231 # Modified dg-runtest that can cycle through a list of optimization options
 232 # as c-torture does.
 233 proc libffi-dg-runtest { testcases default-extra-flags } {
 234     global runtests
 235
 236     foreach test $testcases {
 237         # If we're only testing specific files and this isn't one of
 238         # them, skip it.
 239         if ![runtest_file_p $runtests $test] {
 240             continue
 241         }
 242
 243         # Look for a loop within the source code - if we don't find one,
 244         # don't pass -funroll[-all]-loops.
 245         global torture_with_loops torture_without_loops
 246         if [expr [search_for $test "for*("]+[search_for $test "while*("]] {
 247             set option_list $torture_with_loops
 248         } else {
 249             set option_list $torture_without_loops
 250         }
 251
 252         set nshort [file tail [file dirname $test]]/[file tail $test]
 253
 254         foreach flags $option_list {
 255             verbose "Testing $nshort, $flags" 1
 256             dg-test $test $flags ${default-extra-flags}
 257         }
 258     }
 259 }
 260
 261
 262 # Like check_conditional_xfail, but callable from a dg test.
 263
 264 proc dg-xfail-if { args } {
 265     set args [lreplace $args 0 0]
 266     set selector "target [join [lindex $args 1]]"
 267     if { [dg-process-target $selector] == "S" } {
 268         global compiler_conditional_xfail_data
 269         set compiler_conditional_xfail_data $args
 270     }
 271 }
 272
 273 proc check-flags { args } {
 274
 275     # The args are within another list; pull them out.
 276     set args [lindex $args 0]
 277
 278     # The next two arguments are optional.  If they were not specified,
 279     # use the defaults.
 280     if { [llength $args] == 2 } {
 281         lappend $args [list "*"]
 282     }
 283     if { [llength $args] == 3 } {
 284         lappend $args [list ""]
 285     }
 286
 287     # If the option strings are the defaults, or the same as the
 288     # defaults, there is no need to call check_conditional_xfail to
 289     # compare them to the actual options.
 290     if { [string compare [lindex $args 2] "*"] == 0
 291          && [string compare [lindex $args 3] "" ] == 0 } {
 292         set result 1
 293     } else {
 294         # The target list might be an effective-target keyword, so replace
 295         # the original list with "*-*-*", since we already know it matches.
 296         set result [check_conditional_xfail [lreplace $args 1 1 "*-*-*"]]
 297     }
 298
 299     return $result
 300 }
 301
 302 proc dg-skip-if { args } {
 303     # Verify the number of arguments.  The last two are optional.
 304     set args [lreplace $args 0 0]
 305     if { [llength $args] < 2 || [llength $args] > 4 } {
 306         error "dg-skip-if 2: need 2, 3, or 4 arguments"
 307     }
 308
 309     # Don't bother if we're already skipping the test.
 310     upvar dg-do-what dg-do-what
 311     if { [lindex ${dg-do-what} 1] == "N" } {
 312       return
 313     }
 314
 315     set selector [list target [lindex $args 1]]
 316     if { [dg-process-target $selector] == "S" } {
 317         if [check-flags $args] {
 318             upvar dg-do-what dg-do-what
 319             set dg-do-what [list [lindex ${dg-do-what} 0] "N" "P"]
 320         }
 321     }
 322 }
 323
 324 # We need to make sure that additional_files and additional_sources
 325 # are both cleared out after every test.  It is not enough to clear
 326 # them out *before* the next test run because gcc-target-compile gets
 327 # run directly from some .exp files (outside of any test).  (Those
 328 # uses should eventually be eliminated.)
 329
 330 # Because the DG framework doesn't provide a hook that is run at the
 331 # end of a test, we must replace dg-test with a wrapper.
 332
 333 if { [info procs saved-dg-test] == [list] } {
 334     rename dg-test saved-dg-test
 335
 336     proc dg-test { args } {
 337         global additional_files
 338         global additional_sources
 339         global errorInfo
 340
 341         if { [ catch { eval saved-dg-test $args } errmsg ] } {
 342             set saved_info $errorInfo
 343             set additional_files ""
 344             set additional_sources ""
 345             error $errmsg $saved_info
 346         }
 347         set additional_files ""
 348         set additional_sources ""
 349     }
 350 }
 351
 352 # Local Variables:
 353 # tcl-indent-level:4
 354 # End: