tests/testapplications/elements/content/TrailEmitterElement.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the test suite of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:LGPL$
   9 ** GNU Lesser General Public License Usage
  10 ** This file may be used under the terms of the GNU Lesser General Public
  11 ** License version 2.1 as published by the Free Software Foundation and
  12 ** appearing in the file LICENSE.LGPL included in the packaging of this
  13 ** file. Please review the following information to ensure the GNU Lesser
  14 ** General Public License version 2.1 requirements will be met:
  15 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  16 **
  17 ** In addition, as a special exception, Nokia gives you certain additional
  18 ** rights. These rights are described in the Nokia Qt LGPL Exception
  19 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  20 **
  21 ** GNU General Public License Usage
  22 ** Alternatively, this file may be used under the terms of the GNU General
  23 ** Public License version 3.0 as published by the Free Software Foundation
  24 ** and appearing in the file LICENSE.GPL included in the packaging of this
  25 ** file. Please review the following information to ensure the GNU General
  26 ** Public License version 3.0 requirements will be met:
  27 ** http://www.gnu.org/copyleft/gpl.html.
  28 **
  29 ** Other Usage
  30 ** Alternatively, this file may be used in accordance with the terms and
  31 ** conditions contained in a signed written agreement between you and Nokia.
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 2.0
  43 import QtQuick.Particles 2.0
  44
  45 Item {
  46     id: trailemitterelementtest
  47     anchors.fill: parent
  48     property string testtext: ""
  49
  50     ParticleSystem {
  51         id: particlesystem
  52         anchors.fill: parent
  53         Image {
  54             id: backgroundpic
  55             anchors.fill: parent
  56             source: "pics/logo.png"
  57             opacity: 0
  58             Behavior on opacity { NumberAnimation { duration: 1000 } }
  59         }
  60         ImageParticle {
  61             id: omissile
  62             source: "pics/star.png"
  63             color: "orange"
  64             entryEffect: ImageParticle.None
  65             groups: ["orangemissile"]
  66         }
  67         ImageParticle {
  68             id: gmissile
  69             source: "pics/star.png"
  70             color: "green"
  71             entryEffect: ImageParticle.None
  72             groups: ["greenmissile"]
  73         }
  74         ImageParticle {
  75             id: sparks
  76             source: "pics/star.png"
  77             color: "red"
  78             colorVariation: .5
  79             entryEffect: ImageParticle.None
  80             groups: ["sparks"]
  81         }
  82         Emitter {
  83             id: emitter
  84             anchors.bottom: parent.bottom
  85             anchors.bottomMargin: 5
  86             anchors.horizontalCenter: parent.horizontalCenter
  87             emitRate: 1
  88             lifeSpan: 3000
  89             size: 20
  90             velocity: AngleDirection { angle: 270; angleVariation: 25; magnitude: 150 }
  91             group: "orangemissile"
  92         }
  93         Emitter {
  94             id: emitter2
  95             anchors.bottom: parent.bottom
  96             anchors.bottomMargin: 5
  97             anchors.horizontalCenter: parent.horizontalCenter
  98             emitRate: 1
  99             lifeSpan: 3000
 100             size: 20
 101             velocity: AngleDirection { angle: 270; angleVariation: 25; magnitude: 150 }
 102             group: "greenmissile"
 103         }
 104         Gravity {
 105             anchors.fill: parent
 106             angle: 90
 107             acceleration: 30
 108         }
 109         TrailEmitter {
 110             id: trailemitterelement
 111             follow: "orangemissile"
 112             group:"sparks"
 113             anchors.fill: parent
 114             emitRatePerParticle: 50
 115             lifeSpan: 1000
 116             velocityFromMovement: .2
 117             velocity: AngleDirection { angle: 0; angleVariation: 360; magnitude: 5 }
 118             maximumEmitted: 500
 119             shape: basicshape
 120         }
 121
 122         RectangleShape { id: basicshape }
 123
 124         MaskShape {
 125             id: maskshape
 126             source: "pics/logo-hollowed.png"
 127         }
 128
 129     }
 130
 131     SystemTestHelp { id: helpbubble; visible: statenum != 0
 132         anchors { top: parent.top; horizontalCenter: parent.horizontalCenter; topMargin: 50 }
 133     }
 134     BugPanel { id: bugpanel }
 135
 136     states: [
 137         State { name: "start"; when: statenum == 1
 138             PropertyChanges { target: trailemitterelementtest
 139                 testtext: "This is a TrailEmitter, with particles following the orange particles.\n"+
 140                 "The green particles should not be followed by other particles.\n"+
 141                 "Next, let's change the sparks to follow the green particles." }
 142         },
 143         State { name: "followgreen"; when: statenum == 2
 144             PropertyChanges { target: trailemitterelement; follow: "greenmissile" }
 145             PropertyChanges { target: trailemitterelementtest
 146                 testtext: "The particles should be following the green particles.\n"+
 147                 "Next, let's add a shape to emit within." }
 148         },
 149         State { name: "onlyinshape"; when: statenum == 3
 150             PropertyChanges { target: trailemitterelement; follow: "greenmissile"; shape: maskshape }
 151             PropertyChanges { target: backgroundpic; opacity: .5 }
 152             PropertyChanges { target: trailemitterelementtest
 153             testtext: "The particles should now be only emitted when they pass through the 'Qt' text.\n"+
 154                 "Next, let's create small Qt missiles." }
 155         },
 156         State { name: "emittingashape"; when: statenum == 4
 157             PropertyChanges { target: trailemitterelement; follow: "greenmissile"; shape: basicshape
 158                 emitHeight: 60; emitWidth: 60; emitRatePerParticle: 1500; emitShape: maskshape; maximumEmitted: 1500; lifeSpan: 50
 159             }
 160             PropertyChanges { target: trailemitterelementtest
 161                 testtext: "The particles should now be Qt text shaped particles.\n"+
 162                 "Advance to restart the test." }
 163         }
 164     ]
 165 }