tests/icles/meson.build

   1 tests = [
   2   ['equalizer-test'],
   3   ['test-accurate-seek', gstapp_dep],
   4   ['test-segment-seeks'],
   5   ['videocrop-test'],
   6   ['videobox-test'],
   7   ['videocrop2-test'],
   8 ]
   9
  10 gtk_dep = dependency('gtk+-3.0', version : '>= 3.0.0', required : false)
  11 if gtk_dep.found()
  12   tests += [
  13     ['gdkpixbufsink-test', gtk_dep],
  14     ['gdkpixbufoverlay-test', [gstvideo_dep, gtk_dep]],
  15   ]
  16 endif
  17
  18 if cdata.has('HAVE_GST_V4L2')
  19   tests += [['v4l2src-test', gstvideo_dep]]
  20 endif
  21
  22 if get_variable('have_oss4', false)
  23   tests += [['test-oss4']]
  24 endif
  25
  26 if get_variable('x11_dep', dependency('', required: false)).found()
  27   tests += [['ximagesrc-test']]
  28 endif
  29
  30 foreach t : tests
  31   test_name = t.get(0)
  32   extra_deps = t.get(1, [])
  33   executable(test_name, test_name + '.c',
  34     dependencies: [gst_dep, libm, extra_deps],
  35     c_args : gst_plugins_good_args,
  36     include_directories : [configinc],
  37     install: false)
  38 endforeach