tests/ctest-default.cmake

   1 ## The directory to run ctest in.
   2 set(CTEST_DIRECTORY "$ENV{HOME}/workspace/tmp/dashboards/cmocka")
   3
   4 ## The hostname of the machine
   5 set(CTEST_SITE "host.cmocka.org")
   6 ## The buildname
   7 set(CTEST_BUILD_NAME "Linux_GCC_x86_64_default")
   8
   9 ## The Makefile generator to use
  10 set(CTEST_CMAKE_GENERATOR "Unix Makefiles")
  11
  12 ## The Build configuration to use.
  13 set(CTEST_BUILD_CONFIGURATION "Debug")
  14
  15 ## The build options for the project
  16 set(CTEST_BUILD_OPTIONS "-DUNIT_TESTING=ON -DWITH_CMOCKERY_SUPPORT=ON")
  17
  18 #set(CTEST_CUSTOM_MEMCHECK_IGNORE torture_rand)
  19
  20 ## The Model to set: Nightly, Continous, Experimental
  21 set(CTEST_MODEL "Experimental")
  22
  23 ## The URL to the git repository
  24 set(CTEST_GIT_REPOSITORY "git://git.cryptomilk.org/projects/cmocka.git")
  25
  26 ## The branch
  27 #set(CTEST_GIT_BRANCH "--branch v0-5")
  28
  29 ## Wether to enable memory checking.
  30 set(WITH_MEMCHECK FALSE)
  31
  32 ## Wether to enable code coverage.
  33 set(WITH_COVERAGE FALSE)
  34
  35 #######################################################################
  36
  37 if (WITH_COVERAGE AND NOT WIN32)
  38     set(CTEST_BUILD_CONFIGURATION "Profiling")
  39 endif (WITH_COVERAGE AND NOT WIN32)
  40
  41 set(CTEST_SOURCE_DIRECTORY "${CTEST_DIRECTORY}/${CTEST_BUILD_NAME}/source")
  42 set(CTEST_BINARY_DIRECTORY "${CTEST_DIRECTORY}/${CTEST_BUILD_NAME}/build")
  43
  44 set(CTEST_MEMORYCHECK_SUPPRESSIONS_FILE ${CMAKE_SOURCE_DIR}/tests/valgrind.supp)
  45
  46 find_program(CTEST_GIT_COMMAND NAMES git)
  47 find_program(CTEST_COVERAGE_COMMAND NAMES gcov)
  48 find_program(CTEST_MEMORYCHECK_COMMAND NAMES valgrind)
  49
  50 if(NOT EXISTS "${CTEST_SOURCE_DIRECTORY}")
  51     set(CTEST_CHECKOUT_COMMAND "${CTEST_GIT_COMMAND} clone ${CTEST_GIT_BRANCH} ${CTEST_GIT_REPOSITORY} ${CTEST_SOURCE_DIRECTORY}")
  52 endif()
  53
  54 set(CTEST_UPDATE_COMMAND "${CTEST_GIT_COMMAND}")
  55
  56 set(CTEST_CONFIGURE_COMMAND "${CMAKE_COMMAND} -DCMAKE_BUILD_TYPE:STRING=${CTEST_BUILD_CONFIGURATION}")
  57 set(CTEST_CONFIGURE_COMMAND "${CTEST_CONFIGURE_COMMAND} ${CTEST_BUILD_OPTIONS}")
  58 set(CTEST_CONFIGURE_COMMAND "${CTEST_CONFIGURE_COMMAND} \"-G${CTEST_CMAKE_GENERATOR}\"")
  59 set(CTEST_CONFIGURE_COMMAND "${CTEST_CONFIGURE_COMMAND} \"${CTEST_SOURCE_DIRECTORY}\"")
  60
  61 ctest_empty_binary_directory(${CTEST_BINARY_DIRECTORY})
  62
  63 ctest_start(${CTEST_MODEL} TRACK ${CTEST_MODEL})
  64 ctest_update(SOURCE ${CTEST_SOURCE_DIRECTORY})
  65 ctest_configure(BUILD ${CTEST_BINARY_DIRECTORY})
  66 ctest_build(BUILD ${CTEST_BINARY_DIRECTORY})
  67 ctest_test(BUILD ${CTEST_BINARY_DIRECTORY})
  68 if (WITH_MEMCHECK AND CTEST_COVERAGE_COMMAND)
  69   ctest_coverage(BUILD ${CTEST_BINARY_DIRECTORY})
  70 endif (WITH_MEMCHECK AND CTEST_COVERAGE_COMMAND)
  71 if (WITH_MEMCHECK AND CTEST_MEMORYCHECK_COMMAND)
  72   ctest_memcheck(BUILD ${CTEST_BINARY_DIRECTORY})
  73 endif (WITH_MEMCHECK AND CTEST_MEMORYCHECK_COMMAND)
  74 ctest_submit()