tests/check/meson.build

   1 # FIXME: use dependency('valgrind') once we have a method to get the includes
   2 if cc.has_header('valgrind/valgrind.h')
   3   cdata.set('HAVE_VALGRIND', 1)
   4 endif
   5
   6 # internal helper lib for unit testing audio parsers
   7 libparser = static_library('libparser', 'elements/parser.c',
   8   c_args : gst_plugins_good_args + ['-DGST_USE_UNSTABLE_API'],
   9   include_directories : [configinc],
  10   dependencies : [gstcheck_dep],
  11   install : false)
  12
  13 libparser_dep = declare_dependency(link_with : libparser,
  14   dependencies : gstcheck_dep)
  15
  16 # name, condition when to skip the test and extra dependencies
  17 good_tests = [
  18   [ 'elements/audioamplify' ],
  19   [ 'elements/audiochebband' ],
  20   [ 'elements/audiocheblimit' ],
  21   [ 'elements/audiodynamic' ],
  22   [ 'elements/audioecho' ],
  23   [ 'elements/audiofirfilter' ],
  24   [ 'elements/audioiirfilter' ],
  25   [ 'elements/audioinvert' ],
  26   [ 'elements/audiopanorama' ],
  27   [ 'elements/audiowsincband' ],
  28   [ 'elements/audiowsinclimit' ],
  29   [ 'elements/alphacolor' ],
  30   [ 'elements/alpha' ],
  31   [ 'elements/aacparse', false, [libparser_dep] ],
  32   [ 'elements/ac3parse', false, [libparser_dep] ],
  33   [ 'elements/amrparse', false, [libparser_dep] ],
  34   [ 'elements/flacparse', false, [libparser_dep] ],
  35   [ 'elements/mpegaudioparse', false, [libparser_dep] ],
  36   [ 'elements/wavpackparse' ],
  37   [ 'elements/autodetect' ],
  38   [ 'elements/avimux' ],
  39   [ 'elements/avisubtitle' ],
  40   [ 'elements/capssetter' ],
  41   [ 'elements/deinterlace' ],
  42   [ 'elements/dtmf' ],
  43   [ 'pipelines/flacdec', not flac_dep.found() ],
  44   [ 'elements/flvdemux' ],
  45   [ 'elements/flvmux' ],
  46   [ 'elements/qtmux' ],
  47   [ 'elements/qtdemux' ],
  48   [ 'elements/mulawdec' ],
  49   [ 'elements/mulawenc' ],
  50   [ 'elements/gdkpixbufsink', not gdkpixbuf_dep.found(), [gdkpixbuf_dep] ],
  51   [ 'elements/gdkpixbufoverlay', not gdkpixbuf_dep.found() ],
  52   [ 'elements/icydemux' ],
  53   [ 'elements/id3demux' ],
  54   [ 'elements/imagefreeze' ],
  55   [ 'elements/deinterleave' ],
  56   [ 'elements/interleave' ],
  57   [ 'elements/jpegdec', not jpeglib.found() ],
  58   [ 'elements/jpegenc', not jpeglib.found() ],
  59   [ 'elements/level' ],
  60   [ 'elements/matroskademux' ],
  61   [ 'elements/matroskamux' ],
  62   [ 'elements/matroskaparse' ],
  63   [ 'elements/multifile' ],
  64   [ 'elements/splitmux' ],
  65   [ 'elements/rganalysis' ],
  66   [ 'elements/rglimiter' ],
  67   [ 'elements/rgvolume' ],
  68   [ 'elements/rtp-payloading' ],
  69   [ 'elements/rtph261' ],
  70   [ 'elements/rtph263' ],
  71   [ 'elements/rtpvp9' ],
  72   [ 'elements/rtpaux' ],
  73   [ 'elements/rtpbin' ],
  74   [ 'elements/rtpbin_buffer_list' ],
  75   [ 'elements/rtpbundle' ],
  76   [ 'elements/rtpcollision' ],
  77   [ 'elements/rtpjitterbuffer' ],
  78   [ 'elements/rtpmux' ],
  79   [ 'elements/rtprtx' ],
  80   [ 'elements/rtpsession' ],
  81   [ 'elements/souphttpsrc', not libsoup_dep.found(), [libsoup_dep] ],
  82   [ 'elements/spectrum' ],
  83 #  [ 'elements/sunaudio' ],
  84   [ 'elements/shapewipe' ],
  85   [ 'elements/id3v2mux', not taglib_dep.found() ],
  86   [ 'elements/apev2mux', not taglib_dep.found() ],
  87   [ 'elements/udpsink' ],
  88   [ 'elements/udpsrc' ],
  89   [ 'elements/videobox' ],
  90   [ 'elements/aspectratiocrop' ],
  91   [ 'elements/videocrop' ],
  92   [ 'elements/videofilter' ],
  93   [ 'elements/videomixer' ],
  94   [ 'elements/vp8enc', not vpx_dep.found() or not have_vp8_encoder ],
  95   [ 'elements/vp8dec', not vpx_dep.found() or not have_vp8_decoder ],
  96   [ 'elements/vp9enc', not vpx_dep.found() or not have_vp9_encoder ],
  97   [ 'pipelines/wavenc' ],
  98   [ 'elements/wavpackdec', not wavpack_dep.found() ],
  99   [ 'elements/wavpackenc', not wavpack_dep.found() ],
 100   [ 'pipelines/wavpack', not wavpack_dep.found() ],
 101   [ 'elements/wavparse' ],
 102   [ 'elements/y4menc' ],
 103   [ 'pipelines/effectv' ],
 104   [ 'elements/equalizer' ],
 105   [ 'generic/states' ],
 106   [ 'pipelines/simple-launch-lines' ],
 107   [ 'pipelines/tagschecking' ],
 108 ]
 109
 110 # FIXME: valgrind elements/rtp-payloading - needs fixing
 111 # elements/videocrop should be disabled since it takes way too long in valgrind
 112
 113 foo='''
 114 if HAVE_ORC
 115 check_orc = orc/deinterlace orc/videomixer orc/videobox
 116 else
 117 check_orc =
 118 endif
 119 '''
 120
 121 test_defines = [
 122   '-UG_DISABLE_ASSERT',
 123   '-UG_DISABLE_CAST_CHECKS',
 124   '-DGST_CHECK_TEST_ENVIRONMENT_BEACON="GST_PLUGIN_LOADING_WHITELIST"',
 125   '-DGST_TEST_FILES_PATH="' + meson.current_source_dir() + '/../files"',
 126   '-DGST_USE_UNSTABLE_API',
 127 ]
 128
 129 pluginsdirs = [  ]
 130 # FIXME: Use if not gst_dep.is_internal() when avalaible as we only support the
 131 # case where GStreamer is another subproject here.
 132 if not meson.is_subproject()
 133   pkgconfig = find_program('pkg-config')
 134   runcmd = run_command(pkgconfig, '--variable=pluginsdir',
 135       'gstreamer-' + api_version, 'gstreamer-plugins-base-' + api_version)
 136
 137   if runcmd.returncode() == 0
 138       pluginsdirs = runcmd.stdout().split()
 139   else
 140     error('Could not determine GStreamer core plugins directory for unit tests.')
 141   endif
 142 endif
 143
 144 # fake device drivers: we could run hardware element tests against dummy drivers
 145 # v4l2: vivo (part of normal kernel)
 146 #   modprobe vivo;
 147 #   gst-launch v4l2src device="/dev/video1" ! xvimagesink;
 148 #   rmmod vivo
 149 #
 150 # alsa: snd-dummy (part of normal alsa, not removable)
 151 #   modprobe snd-dummy;
 152 #   gst-launch alsasrc device="hw:2" ! fakesink
 153 #   gst-launch fakesrc ! alsasink device="hw:2"
 154 #
 155 # need a way to figure out value for the device property
 156 state_ignore_elements = '''aasink autoaudiosrc autoaudiosink autovideosrc
 157  autovideosink cacasink cairotextoverlay jackaudiosrc jackaudiosink
 158  osssrc osssink osxaudiosink osxaudiosrc osxvideosrc osxvideosink
 159  pulsesink pulsesrc pulsemixer v4l2src'''
 160
 161 # FIXME: check, also + PTHREAD_CFLAGS
 162 test_deps = [gst_dep, gstbase_dep, gstnet_dep, gstcheck_dep, gstaudio_dep,
 163   gstvideo_dep, gstpbutils_dep, gstrtp_dep, gstrtsp_dep, gsttag_dep,
 164   gstapp_dep, gio_dep] + glib_deps
 165
 166 # FIXME: add valgrind suppression common/gst.supp gst-plugins-good.supp
 167 foreach t : good_tests
 168   test_name = t.get(0)
 169   extra_deps = [ ]
 170   if t.length() == 3
 171     extra_deps = t.get(2)
 172     skip_test = t.get(1)
 173   elif t.length() == 2
 174     skip_test = t.get(1)
 175   else
 176     skip_test = false
 177   endif
 178   if not skip_test
 179     env = environment()
 180     env.set('GST_PLUGIN_PATH_1_0', meson.build_root())
 181     env.set('GST_PLUGIN_SYSTEM_PATH_1_0', '')
 182     env.set('GST_STATE_IGNORE_ELEMENTS', state_ignore_elements)
 183     env.set('CK_DEFAULT_TIMEOUT', '20')
 184     env.set('GST_PLUGIN_LOADING_WHITELIST', 'gstreamer', 'gst-plugins-base',
 185       'gst-plugins-good@' + meson.build_root(), separator=':')
 186     env.set('GST_PLUGIN_PATH_1_0', meson.build_root())
 187     env.set('GSETTINGS_BACKEND', 'memory')
 188
 189     foreach plugindir: pluginsdirs
 190       env.append('GST_PLUGIN_PATH_1_0', plugindir)
 191     endforeach
 192     env.set('GST_REGISTRY', '@0@/@1@.registry'.format(meson.current_build_dir(), test_name))
 193     exe = executable(test_name, '@0@.c'.format(test_name),
 194       include_directories : [configinc],
 195       c_args : ['-DHAVE_CONFIG_H=1' ] + test_defines,
 196       dependencies : [libm] + test_deps + extra_deps,
 197     )
 198     test(test_name, exe, env: env, timeout: 3 * 60)
 199   endif
 200 endforeach
 201
 202 # FIXME: orc tests
 203 fixme_orc_tests='''
 204 orc_deinterlace_CFLAGS = $(ORC_CFLAGS)
 205 orc_deinterlace_LDADD = $(ORC_LIBS) -lorc-test-0.4
 206 nodist_orc_deinterlace_SOURCES = orc/deinterlace.c
 207 orc_videomixer_CFLAGS = $(ORC_CFLAGS)
 208 orc_videomixer_LDADD = $(ORC_LIBS) -lorc-test-0.4
 209 nodist_orc_videomixer_SOURCES = orc/videomixer.c
 210 orc_videobox_CFLAGS = $(ORC_CFLAGS)
 211 orc_videobox_LDADD = $(ORC_LIBS) -lorc-test-0.4
 212 nodist_orc_videobox_SOURCES = orc/videobox.c
 213
 214 orc/deinterlace.c: $(top_srcdir)/gst/deinterlace/tvtime.orc
 215         $(MKDIR_P) orc/
 216         $(ORCC) --test -o $@ $<
 217
 218 orc/videomixer.c: $(top_srcdir)/gst/videomixer/videomixerorc.orc
 219         $(MKDIR_P) orc/
 220         $(ORCC) --test -o $@ $<
 221
 222 orc/videobox.c: $(top_srcdir)/gst/videobox/gstvideoboxorc.orc
 223         $(MKDIR_P) orc/
 224         $(ORCC) --test -o $@ $<
 225 '''