test/tcl/repmgr010.tcl

   1 # See the file LICENSE for redistribution information.
   2 #
   3 # Copyright (c) 2007, 2012 Oracle and/or its affiliates.  All rights reserved.
   4 #
   5 # $Id$
   6 #
   7 # TEST  repmgr010
   8 # TEST  Acknowledgement policy and timeout test.
   9 # TEST
  10 # TEST  Verify that "quorum" acknowledgement policy succeeds with fewer than
  11 # TEST  nsites running. Verify that "all" acknowledgement policy results in
  12 # TEST  ack failures with fewer than nsites running.
  13 # TEST
  14 # TEST  Run for btree only because access method shouldn't matter.
  15 # TEST
  16 proc repmgr010 { { niter 100 } { tnum "010" } args } {
  17
  18         source ./include.tcl
  19
  20         if { $is_freebsd_test == 1 } {
  21                 puts "Skipping replication manager test on FreeBSD platform."
  22                 return
  23         }
  24
  25         set method "btree"
  26         set args [convert_args $method $args]
  27
  28         puts "Repmgr$tnum ($method): repmgr ack policy and timeout test."
  29         repmgr010_sub $method $niter $tnum $args
  30 }
  31
  32 proc repmgr010_sub { method niter tnum largs } {
  33         global testdir
  34         global rep_verbose
  35         global verbose_type
  36         set nsites 3
  37
  38         set small_iter [expr $niter / 10]
  39
  40         set verbargs ""
  41         if { $rep_verbose == 1 } {
  42                 set verbargs " -verbose {$verbose_type on} "
  43         }
  44
  45         env_cleanup $testdir
  46         set ports [available_ports $nsites]
  47
  48         set masterdir $testdir/MASTERDIR
  49         set clientdir $testdir/CLIENTDIR
  50         set clientdir2 $testdir/CLIENTDIR2
  51
  52         file mkdir $masterdir
  53         file mkdir $clientdir
  54         file mkdir $clientdir2
  55
  56         puts "\tRepmgr$tnum.a: Start master, two clients, ack policy quorum."
  57         # Open a master.
  58         set ma_envcmd "berkdb_env_noerr -create $verbargs \
  59             -errpfx MASTER -home $masterdir -txn -rep -thread"
  60         set masterenv [eval $ma_envcmd]
  61         $masterenv repmgr -ack quorum \
  62             -timeout {ack 5000000} \
  63             -local [list 127.0.0.1 [lindex $ports 0]] \
  64             -start master
  65
  66         # Open first client
  67         set cl_envcmd "berkdb_env_noerr -create $verbargs \
  68             -errpfx CLIENT -home $clientdir -txn -rep -thread"
  69         set clientenv [eval $cl_envcmd]
  70         $clientenv repmgr -ack quorum \
  71             -local [list 127.0.0.1 [lindex $ports 1]] \
  72             -remote [list 127.0.0.1 [lindex $ports 0]] \
  73             -remote [list 127.0.0.1 [lindex $ports 2]] \
  74             -start client
  75         await_startup_done $clientenv
  76
  77         # Open second client
  78         set cl2_envcmd "berkdb_env_noerr -create $verbargs \
  79             -errpfx CLIENT2 -home $clientdir2 -txn -rep -thread"
  80         set clientenv2 [eval $cl2_envcmd]
  81         $clientenv2 repmgr -ack quorum \
  82             -local [list 127.0.0.1 [lindex $ports 2]] \
  83             -remote [list 127.0.0.1 [lindex $ports 0]] \
  84             -remote [list 127.0.0.1 [lindex $ports 1]] \
  85             -start client
  86         await_startup_done $clientenv2
  87
  88         puts "\tRepmgr$tnum.b: Run first set of transactions at master."
  89         set start 0
  90         eval rep_test $method $masterenv NULL $niter $start 0 0 $largs
  91         incr start $niter
  92
  93         #
  94         # Special verification needed for quorum ack policy. Wait
  95         # longer than ack timeout (default 1 second) then check for
  96         # ack failures (perm_failed events). Quorum only guarantees
  97         # that transactions replicated to one site or the other, so
  98         # test for this condition instead of both sites.
  99         #
 100         puts "\tRepmgr$tnum.c: Verify both client databases, no ack failures."
 101         error_check_good quorum_perm_failed1 \
 102             [stat_field $masterenv repmgr_stat "Acknowledgement failures"] 0
 103         catch {rep_verify\
 104             $masterdir $masterenv $clientdir $clientenv 1 1 1} ver1
 105         catch {rep_verify\
 106             $masterdir $masterenv $clientdir2 $clientenv2 1 1 1} ver2
 107         error_check_good onesite [expr [string length $ver1] == 0 || \
 108             [string length $ver2] == 0] 1
 109
 110         puts "\tRepmgr$tnum.d: Shut down first client."
 111         error_check_good client_close [$clientenv close] 0
 112
 113         puts "\tRepmgr$tnum.e: Run second set of transactions at master."
 114         eval rep_test $method $masterenv NULL $small_iter $start 0 0 $largs
 115         incr start $niter
 116
 117         puts "\tRepmgr$tnum.f: Verify client database, no ack failures."
 118         error_check_good quorum_perm_failed2 \
 119             [stat_field $masterenv repmgr_stat "Acknowledgement failures"] 0
 120         rep_verify $masterdir $masterenv $clientdir2 $clientenv2 1 1 1
 121
 122         puts "\tRepmgr$tnum.g: Adjust all sites to ack policy all."
 123         # Reopen first client with ack policy all
 124         set cl_envcmd "berkdb_env_noerr -create $verbargs \
 125             -errpfx CLIENT -home $clientdir -txn -rep -thread"
 126         # Open -recover to clear env region, including startup_done value.
 127         set clientenv [eval $cl_envcmd -recover]
 128         $clientenv repmgr -ack all \
 129             -local [list 127.0.0.1 [lindex $ports 1]] \
 130             -remote [list 127.0.0.1 [lindex $ports 0]] \
 131             -remote [list 127.0.0.1 [lindex $ports 2]] \
 132             -start client
 133         await_startup_done $clientenv
 134
 135         # Adjust other sites to ack policy all
 136         $masterenv repmgr -ack all
 137         $clientenv2 repmgr -ack all
 138
 139         puts "\tRepmgr$tnum.h: Shut down first client."
 140         error_check_good client_close [$clientenv close] 0
 141         set init_perm_failed \
 142             [stat_field $masterenv repmgr_stat "Acknowledgement failures"]
 143
 144         #
 145         # Use of -ack all guarantees replication complete before repmgr send
 146         # function returns and rep_test finishes.
 147         #
 148         puts "\tRepmgr$tnum.i: Run third set of transactions at master."
 149         eval rep_test $method $masterenv NULL $small_iter $start 0 0 $largs
 150
 151         puts "\tRepmgr$tnum.j: Verify client database, some ack failures."
 152         rep_verify $masterdir $masterenv $clientdir2 $clientenv2 1 1 1
 153         error_check_good all_perm_failed [expr \
 154             [stat_field $masterenv repmgr_stat "Acknowledgement failures"] \
 155             > $init_perm_failed] 1
 156
 157         error_check_good client2_close [$clientenv2 close] 0
 158         error_check_good masterenv_close [$masterenv close] 0
 159 }