test/calc2.y

   1 %parse-param { int regs[26] }
   2 %parse-param { int *base }
   3
   4 %lex-param { int *base }
   5
   6 %{
   7 # include <stdio.h>
   8 # include <ctype.h>
   9
  10 %}
  11
  12 %start list
  13
  14 %token DIGIT LETTER
  15
  16 %left '|'
  17 %left '&'
  18 %left '+' '-'
  19 %left '*' '/' '%'
  20 %left UMINUS   /* supplies precedence for unary minus */
  21
  22 %% /* beginning of rules section */
  23
  24 list  :  /* empty */
  25       |  list stat '\n'
  26       |  list error '\n'
  27             {  yyerrok ; }
  28       ;
  29
  30 stat  :  expr
  31             {  printf("%d\n",$1);}
  32       |  LETTER '=' expr
  33             {  regs[$1] = $3; }
  34       ;
  35
  36 expr  :  '(' expr ')'
  37             {  $$ = $2; }
  38       |  expr '+' expr
  39             {  $$ = $1 + $3; }
  40       |  expr '-' expr
  41             {  $$ = $1 - $3; }
  42       |  expr '*' expr
  43             {  $$ = $1 * $3; }
  44       |  expr '/' expr
  45             {  $$ = $1 / $3; }
  46       |  expr '%' expr
  47             {  $$ = $1 % $3; }
  48       |  expr '&' expr
  49             {  $$ = $1 & $3; }
  50       |  expr '|' expr
  51             {  $$ = $1 | $3; }
  52       |  '-' expr %prec UMINUS
  53             {  $$ = - $2; }
  54       |  LETTER
  55             {  $$ = regs[$1]; }
  56       |  number
  57       ;
  58
  59 number:  DIGIT
  60          {  $$ = $1; (*base) = ($1==0) ? 8 : 10; }
  61       |  number DIGIT
  62          {  $$ = (*base) * $1 + $2; }
  63       ;
  64
  65 %% /* start of programs */
  66
  67 #ifdef YYBYACC
  68 extern int YYLEX_DECL();
  69 static void YYERROR_DECL();
  70 #endif
  71
  72 int
  73 main (void)
  74 {
  75     int regs[26];
  76     int base = 10;
  77
  78     while(!feof(stdin)) {
  79         yyparse(regs, &base);
  80     }
  81     return 0;
  82 }
  83
  84 static void
  85 YYERROR_DECL()
  86 {
  87     fprintf(stderr, "%s\n", s);
  88 }
  89
  90 int
  91 yylex(int *base)
  92 {
  93         /* lexical analysis routine */
  94         /* returns LETTER for a lower case letter, yylval = 0 through 25 */
  95         /* return DIGIT for a digit, yylval = 0 through 9 */
  96         /* all other characters are returned immediately */
  97
  98     int c;
  99
 100     while( (c=getchar()) == ' ' )   { /* skip blanks */ }
 101
 102     /* c is now nonblank */
 103
 104     if( islower( c )) {
 105         yylval = c - 'a';
 106         return ( LETTER );
 107     }
 108     if( isdigit( c )) {
 109         yylval = (c - '0') % (*base);
 110         return ( DIGIT );
 111     }
 112     return( c );
 113 }