targets/android/ndk-r11.cmake

   1 #-------------------------------------------------------------------------
   2 # drawElements CMake utilities
   3 # ----------------------------
   4 #
   5 # Copyright 2016 The Android Open Source Project
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #      http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 #
  19 #-------------------------------------------------------------------------
  20
  21 # Platform defines.
  22 set(CMAKE_SYSTEM_NAME Linux)
  23
  24 set_property(GLOBAL PROPERTY TARGET_SUPPORTS_SHARED_LIBS TRUE)
  25
  26 set(CMAKE_CROSSCOMPILING 1)
  27
  28 # NDK installation path
  29 if (NOT DEFINED ANDROID_NDK_PATH)
  30         message(FATAL_ERROR "Please provide ANDROID_NDK_PATH")
  31 endif ()
  32
  33 # Host os (for toolchain binaries)
  34 if (NOT DEFINED ANDROID_NDK_HOST_OS)
  35         message(FATAL_ERROR "Please provide ANDROID_NDK_HOST_OS")
  36 endif ()
  37
  38 # Compile target
  39 set(ANDROID_ABI                 "armeabi-v7a"                   CACHE STRING "Android ABI")
  40 set(ANDROID_NDK_TARGET  "android-${DE_ANDROID_API}")
  41
  42 # dE defines
  43 set(DE_OS "DE_OS_ANDROID")
  44
  45 if (NOT DEFINED DE_COMPILER)
  46         set(DE_COMPILER "DE_COMPILER_CLANG")
  47 endif ()
  48
  49 if (NOT DEFINED DE_ANDROID_API)
  50         set(DE_ANDROID_API 9)
  51 endif ()
  52
  53 set(COMMON_C_FLAGS              "-D__STDC_INT64__")
  54 set(COMMON_CXX_FLAGS    "${COMMON_C_FLAGS} -frtti -fexceptions")
  55 set(COMMON_LINKER_FLAGS "")
  56
  57 # ABI-dependent bits
  58 if (ANDROID_ABI STREQUAL "x86")
  59         set(DE_CPU                                      "DE_CPU_X86")
  60         set(CMAKE_SYSTEM_PROCESSOR      i686-android-linux)
  61
  62         set(ANDROID_CC_PATH                     "${ANDROID_NDK_PATH}/toolchains/x86-4.9/prebuilt/${ANDROID_NDK_HOST_OS}/")
  63         set(CROSS_COMPILE                       "${ANDROID_CC_PATH}bin/i686-linux-android-")
  64         set(ANDROID_SYSROOT                     "${ANDROID_NDK_PATH}/platforms/${ANDROID_NDK_TARGET}/arch-x86")
  65
  66         set(CMAKE_FIND_ROOT_PATH
  67                 "${ANDROID_CC_PATH}i686-linux-android"
  68                 "${ANDROID_CC_PATH}lib/gcc/i686-linux-android/4.9"
  69                 )
  70
  71         set(TARGET_C_FLAGS                      "-march=i686 -msse3 -mstackrealign -mfpmath=sse")
  72         set(TARGET_LINKER_FLAGS         "")
  73         set(LLVM_TRIPLE                         "i686-none-linux-android")
  74
  75 elseif (ANDROID_ABI STREQUAL "armeabi" OR
  76                 ANDROID_ABI STREQUAL "armeabi-v7a")
  77         set(DE_CPU                                      "DE_CPU_ARM")
  78         set(CMAKE_SYSTEM_PROCESSOR      arm-linux-androideabi)
  79
  80         set(ANDROID_CC_PATH     "${ANDROID_NDK_PATH}/toolchains/arm-linux-androideabi-4.9/prebuilt/${ANDROID_NDK_HOST_OS}/")
  81         set(CROSS_COMPILE       "${ANDROID_CC_PATH}bin/arm-linux-androideabi-")
  82         set(ANDROID_SYSROOT     "${ANDROID_NDK_PATH}/platforms/${ANDROID_NDK_TARGET}/arch-arm")
  83         set(ARM_C_FLAGS         "-D__ARM_ARCH_5__ -D__ARM_ARCH_5T__ -D__ARM_ARCH_5E__ -D__ARM_ARCH_5TE__ ")
  84
  85         if (ANDROID_ABI STREQUAL "armeabi-v7a")
  86                 set(TARGET_C_FLAGS              "${ARM_C_FLAGS} -march=armv7-a -mfpu=vfpv3-d16 -mfloat-abi=softfp")
  87                 set(TARGET_LINKER_FLAGS "-Wl,--fix-cortex-a8 -march=armv7-a")
  88                 set(LLVM_TRIPLE                 "armv7-none-linux-androideabi")
  89
  90         else () # armeabi
  91                 set(TARGET_C_FLAGS              "${ARM_C_FLAGS} -march=armv5te -mfloat-abi=softfp")
  92                 set(TARGET_LINKER_FLAGS "-Wl,--fix-cortex-a8 -march=armv5te")
  93                 set(LLVM_TRIPLE                 "armv5te-none-linux-androideabi")
  94         endif ()
  95
  96         set(CMAKE_FIND_ROOT_PATH
  97                 "${ANDROID_CC_PATH}arm-linux-androideabi"
  98                 )
  99
 100 elseif (ANDROID_ABI STREQUAL "arm64-v8a")
 101         set(DE_CPU                                      "DE_CPU_ARM_64")
 102         set(CMAKE_SYSTEM_PROCESSOR      aarch64-linux-android)
 103         set(CMAKE_SIZEOF_VOID_P         8)
 104
 105         set(ANDROID_CC_PATH     "${ANDROID_NDK_PATH}/toolchains/aarch64-linux-android-4.9/prebuilt/${ANDROID_NDK_HOST_OS}/")
 106         set(CROSS_COMPILE       "${ANDROID_CC_PATH}bin/aarch64-linux-android-")
 107         set(ANDROID_SYSROOT     "${ANDROID_NDK_PATH}/platforms/${ANDROID_NDK_TARGET}/arch-arm64")
 108
 109         set(CMAKE_FIND_ROOT_PATH
 110                 "${ANDROID_CC_PATH}arm-linux-androideabi"
 111                 )
 112
 113         set(TARGET_C_FLAGS              "-march=armv8-a")
 114         set(TARGET_LINKER_FLAGS "-Wl,--fix-cortex-a53-835769 -Wl,--fix-cortex-a53-835769 -march=armv8-a")
 115         set(LLVM_TRIPLE                 "aarch64-none-linux-android")
 116
 117         if (DE_COMPILER STREQUAL "DE_COMPILER_GCC")
 118                 set(TARGET_C_FLAGS "${TARGET_C_FLAGS} -mabi=lp64")
 119         endif ()
 120
 121 elseif (ANDROID_ABI STREQUAL "x86_64")
 122         set(DE_CPU                                      "DE_CPU_X86_64")
 123         set(CMAKE_SYSTEM_PROCESSOR      x86_64-linux-android)
 124         set(CMAKE_SIZEOF_VOID_P         8)
 125
 126         set(CMAKE_LIBRARY_PATH "/usr/lib64")
 127
 128         set(ANDROID_CC_PATH     "${ANDROID_NDK_PATH}/toolchains/x86_64-4.9/prebuilt/${ANDROID_NDK_HOST_OS}/")
 129         set(CROSS_COMPILE       "${ANDROID_CC_PATH}bin/x86_64-linux-android-")
 130         set(ANDROID_SYSROOT     "${ANDROID_NDK_PATH}/platforms/${ANDROID_NDK_TARGET}/arch-x86_64")
 131
 132         set(CMAKE_FIND_ROOT_PATH
 133                 "${ANDROID_CC_PATH}x86_64-linux-android"
 134                 )
 135
 136         set(LLVM_TRIPLE                 "x86_64-none-linux-android")
 137
 138 else ()
 139         message(FATAL_ERROR "Unknown ABI \"${ANDROID_ABI}\"")
 140 endif ()
 141
 142 # Use LLVM libc++ for full C++11 support
 143 set(ANDROID_CXX_LIBRARY         "${ANDROID_NDK_PATH}/sources/cxx-stl/llvm-libc++/libs/${ANDROID_ABI}/libc++_static.a")
 144 set(CXX_INCLUDES                        "-I${ANDROID_NDK_PATH}/sources/cxx-stl/llvm-libc++/libcxx/include")
 145 set(CMAKE_FIND_ROOT_PATH        "" ${CMAKE_FIND_ROOT_PATH})
 146
 147 set(CMAKE_FIND_ROOT_PATH ${CMAKE_FIND_ROOT_PATH} ${ANDROID_SYSROOT})
 148
 149 include(CMakeForceCompiler)
 150
 151 if (ANDROID_NDK_HOST_OS STREQUAL "windows" OR
 152         ANDROID_NDK_HOST_OS STREQUAL "windows-x86_64")
 153         set(BIN_EXT ".exe")
 154 else ()
 155         set(BIN_EXT "")
 156 endif ()
 157
 158 if (DE_COMPILER STREQUAL "DE_COMPILER_GCC")
 159         set(CMAKE_C_COMPILER    "${CROSS_COMPILE}gcc${BIN_EXT}"         CACHE FILEPATH "C Compiler")
 160         set(CMAKE_CXX_COMPILER  "${CROSS_COMPILE}g++${BIN_EXT}"         CACHE FILEPATH "C++ Compiler")
 161
 162         set(TARGET_C_FLAGS              "-mandroid ${TARGET_C_FLAGS}")
 163
 164 elseif (DE_COMPILER STREQUAL "DE_COMPILER_CLANG")
 165         set(LLVM_PATH "${ANDROID_NDK_PATH}/toolchains/llvm/prebuilt/${ANDROID_NDK_HOST_OS}/")
 166
 167         set(CMAKE_C_COMPILER    "${LLVM_PATH}bin/clang${BIN_EXT}"       CACHE FILEPATH "C Compiler")
 168         set(CMAKE_CXX_COMPILER  "${LLVM_PATH}bin/clang++${BIN_EXT}"     CACHE FILEPATH "C++ Compiler")
 169         set(CMAKE_AR                    "${CROSS_COMPILE}ar${BIN_EXT}"          CACHE FILEPATH "Archiver")
 170         set(CMAKE_RANLIB                "${CROSS_COMPILE}ranlib${BIN_EXT}"      CACHE FILEPATH "Indexer")
 171
 172         set(TARGET_C_FLAGS              "-target ${LLVM_TRIPLE} -gcc-toolchain ${ANDROID_CC_PATH} ${TARGET_C_FLAGS}")
 173         set(TARGET_LINKER_FLAGS "-target ${LLVM_TRIPLE} -gcc-toolchain ${ANDROID_CC_PATH} ${TARGET_LINKER_FLAGS}")
 174
 175 endif ()
 176
 177 set(CMAKE_SHARED_LIBRARY_C_FLAGS        "")
 178 set(CMAKE_SHARED_LIBRARY_CXX_FLAGS      "")
 179
 180 set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
 181 set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
 182 set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
 183
 184 # \note Without CACHE STRING FORCE cmake ignores these.
 185 set(CMAKE_C_FLAGS                               "--sysroot=${ANDROID_SYSROOT} ${CMAKE_C_FLAGS} ${COMMON_C_FLAGS} ${TARGET_C_FLAGS}" CACHE STRING "" FORCE)
 186 set(CMAKE_CXX_FLAGS                             "--sysroot=${ANDROID_SYSROOT} ${CMAKE_CXX_FLAGS} ${COMMON_CXX_FLAGS} ${TARGET_C_FLAGS} ${CXX_INCLUDES} -I${ANDROID_NDK_PATH}/sources/android/support/include" CACHE STRING "" FORCE)
 187 set(CMAKE_SHARED_LINKER_FLAGS   "-nodefaultlibs -Wl,-shared,-Bsymbolic -Wl,--no-undefined ${COMMON_LINKER_FLAGS} ${TARGET_LINKER_FLAGS}" CACHE STRING "" FORCE)
 188 set(CMAKE_EXE_LINKER_FLAGS              "-nodefaultlibs ${COMMON_LINKER_FLAGS} ${TARGET_LINKER_FLAGS}" CACHE STRING "" FORCE)