sysdeps/x86_64/strlen.S

   1 /* strlen(str) -- determine the length of the string STR.
   2    Copyright (C) 2009 Free Software Foundation, Inc.
   3    Contributed by Ulrich Drepper <drepper@redhat.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22
  23
  24 ENTRY(strlen)
  25         movq    %rdi, %rcx
  26         movq    %rdi, %r8
  27         andq    $~15, %rdi
  28         pxor    %xmm1, %xmm1
  29         orl     $0xffffffff, %esi
  30         movdqa  (%rdi), %xmm0
  31         subq    %rdi, %rcx
  32         leaq    16(%rdi), %rdi
  33         pcmpeqb %xmm1, %xmm0
  34         shl     %cl, %esi
  35         pmovmskb %xmm0, %edx
  36         xorl    %eax, %eax
  37         negq    %r8
  38         andl    %esi, %edx
  39         jnz     1f
  40
  41 2:      movdqa  (%rdi), %xmm0
  42         leaq    16(%rdi), %rdi
  43         pcmpeqb %xmm1, %xmm0
  44         pmovmskb %xmm0, %edx
  45         testl   %edx, %edx
  46         jz      2b
  47
  48 1:      leaq    -16(%rdi,%r8), %rdi
  49         bsfl    %edx, %eax
  50         addq    %rdi, %rax
  51         ret
  52 END(strlen)
  53 libc_hidden_builtin_def (strlen)