sysdeps/x86_64/fpu/s_fmaxf.S

   1 /* Compute maximum of two numbers, regarding NaN as missing argument.
   2    Copyright (C) 2002-2019 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Andreas Jaeger <aj@suse.de>, 2002.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <https://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <libm-alias-float.h>
  22
  23         .text
  24 ENTRY(__fmaxf)
  25         ucomiss %xmm0, %xmm1
  26         jp      1f              // jump if unordered
  27         maxss   %xmm1, %xmm0
  28         jmp     2f
  29
  30 1:      ucomiss %xmm1, %xmm1    // Is xmm1 a NaN?
  31         jp      3f
  32         // xmm0 is a NaN; xmm1 is not.  Test if xmm0 is signaling.
  33         movss   %xmm0, -4(%rsp)
  34         testb   $0x40, -2(%rsp)
  35         jz      4f
  36         movss   %xmm1, %xmm0    // otherwise return xmm1
  37         ret
  38
  39 3:      // xmm1 is a NaN; xmm0 may or may not be.
  40         ucomiss %xmm0, %xmm0
  41         jp      4f
  42         // xmm1 is a NaN; xmm0 is not.  Test if xmm1 is signaling.
  43         movss   %xmm1, -4(%rsp)
  44         testb   $0x40, -2(%rsp)
  45         jz      4f
  46         ret
  47
  48 4:      // Both arguments are NaNs, or one is a signaling NaN.
  49         addss   %xmm1, %xmm0
  50
  51 2:      ret
  52 END(__fmaxf)
  53 libm_alias_float (__fmax, fmax)