sysdeps/x86_64/fpu/s_expm1l.S

   1 /* ix87 specific implementation of exp(x)-1.
   2    Copyright (C) 1996,1997,2001,2002,2008,2009,2012 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5    Based on code by John C. Bowman <bowman@ipp-garching.mpg.de>.
   6    Corrections by H.J. Lu (hjl@gnu.ai.mit.edu), 1997.
   7
   8    The GNU C Library is free software; you can redistribute it and/or
   9    modify it under the terms of the GNU Lesser General Public
  10    License as published by the Free Software Foundation; either
  11    version 2.1 of the License, or (at your option) any later version.
  12
  13    The GNU C Library is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16    Lesser General Public License for more details.
  17
  18    You should have received a copy of the GNU Lesser General Public
  19    License along with the GNU C Library; if not, write to the Free
  20    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  21    02111-1307 USA.  */
  22
  23         /* Using: e^x - 1 = 2^(x * log2(e)) - 1 */
  24
  25 #include <machine/asm.h>
  26
  27         .section .rodata
  28
  29         .align ALIGNARG(4)
  30         ASM_TYPE_DIRECTIVE(minus1,@object)
  31 minus1: .double -1.0
  32         ASM_SIZE_DIRECTIVE(minus1)
  33         ASM_TYPE_DIRECTIVE(one,@object)
  34 one:    .double 1.0
  35         ASM_SIZE_DIRECTIVE(one)
  36         ASM_TYPE_DIRECTIVE(l2e,@object)
  37 l2e:    .tfloat 1.442695040888963407359924681002
  38         ASM_SIZE_DIRECTIVE(l2e)
  39
  40 #ifdef PIC
  41 #define MO(op) op##(%rip)
  42 #else
  43 #define MO(op) op
  44 #endif
  45
  46         .text
  47 ENTRY(__expm1l)
  48         movzwl  8+8(%rsp), %eax // load sign bit and 15-bit exponent
  49         xorb    $0x80, %ah      // invert sign bit (now 1 is "positive")
  50         cmpl    $0xc006, %eax   // is num positive and exp >= 6 (number is >= 128.0)?
  51         jae     __expl          // (if num is denormal, it is at least >= 64.0)
  52
  53         fldt    8(%rsp)         // x
  54         fxam                    // Is NaN or +-Inf?
  55         fstsw   %ax
  56         movb    $0x45, %ch
  57         andb    %ah, %ch
  58         cmpb    $0x40, %ch
  59         je      3f              // If +-0, jump.
  60         cmpb    $0x05, %ch
  61         je      2f              // If +-Inf, jump.
  62
  63         fldt    MO(l2e)         // log2(e) : x
  64         fmulp                   // log2(e)*x
  65         fld     %st             // log2(e)*x : log2(e)*x
  66         frndint                 // int(log2(e)*x) : log2(e)*x
  67         fsubr   %st, %st(1)     // int(log2(e)*x) : fract(log2(e)*x)
  68         fxch                    // fract(log2(e)*x) : int(log2(e)*x)
  69         f2xm1                   // 2^fract(log2(e)*x)-1 : int(log2(e)*x)
  70         fscale                  // 2^(log2(e)*x)-2^int(log2(e)*x) : int(log2(e)*x)
  71         fxch                    // int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  72         fldl    MO(one)         // 1 : int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  73         fscale                  // 2^int(log2(e)*x) : int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  74         fsubrl  MO(one)         // 1-2^int(log2(e)*x) : int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  75         fstp    %st(1)          // 1-2^int(log2(e)*x) : 2^(log2(e)*x)-2^int(log2(e)*x)
  76         fsubrp  %st, %st(1)     // 2^(log2(e)*x)-1
  77         ret
  78
  79 2:      testl   $0x200, %eax    // Test sign.
  80         jz      3f              // If positive, jump.
  81         fstp    %st
  82         fldl    MO(minus1)      // Set result to -1.0.
  83 3:      ret
  84 END(__expm1l)
  85 libm_hidden_def (__expm1l)
  86 weak_alias (__expm1l, expm1l)