sysdeps/unix/sysv/linux/powerpc/socket.S

   1 /* Copyright (C) 1995, 1996, 1997 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Library General Public License as
   6    published by the Free Software Foundation; either version 2 of the
   7    License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Library General Public License for more details.
  13
  14    You should have received a copy of the GNU Library General Public
  15    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  16    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  17    Boston, MA 02111-1307, USA.  */
  18
  19 #include <sysdep.h>
  20 #include <socketcall.h>
  21
  22 #define P(a, b) P2(a, b)
  23 #define P2(a, b) a##b
  24
  25 /* The socket-oriented system calls are handled unusally in Linux.
  26    They are all gated through the single `socketcall' system call number.
  27    `socketcall' takes two arguments: the first is the subcode, specifying
  28    which socket function is being called; and the second is a pointer to
  29    the arguments to the specific function.
  30
  31    The .S files for the other calls just #define socket and #include this.
  32    They also #define a 'number-of-arguments' word in NARGS, which
  33    defaults to 3.  */
  34
  35 #ifndef NARGS
  36 #ifdef socket
  37 #error NARGS not defined
  38 #endif
  39 #define NARGS 3
  40 #endif
  41
  42 #define stackblock 20
  43
  44         .text
  45 ENTRY(P(__,socket))
  46         stwu %r1,-48(%r1)
  47 #if NARGS >= 1
  48         stw  %r3,stackblock(%r1)
  49 #endif
  50 #if NARGS >= 2
  51         stw  %r4,4+stackblock(%r1)
  52 #endif
  53 #if NARGS >= 3
  54         stw  %r5,8+stackblock(%r1)
  55 #endif
  56 #if NARGS >= 4
  57         stw  %r6,12+stackblock(%r1)
  58 #endif
  59 #if NARGS >= 5
  60         stw  %r7,16+stackblock(%r1)
  61 #endif
  62 #if NARGS >= 6
  63         stw  %r8,20+stackblock(%r1)
  64 #endif
  65 #if NARGS >= 7
  66         stw  %r9,24+stackblock(%r1)
  67 #endif
  68 #if NARGS >= 8
  69         stw  %r10,28+stackblock(%r1)
  70 #endif
  71 #if NARGS >= 9
  72 #error too many arguments!
  73 #endif
  74         li      %r3,P(SOCKOP_,socket)
  75         addi    %r4,%r1,stackblock
  76         DO_CALL(SYS_ify(socketcall))
  77         addi    %r1,%r1,48
  78         PSEUDO_RET
  79 PSEUDO_END (P(__,socket))
  80
  81 weak_alias (P(__,socket), socket)