sysdeps/s390/s390-32/elf/start.S

   1 /* Startup code compliant to the ELF s390 ABI.
   2    Copyright (C) 2000, 2001, 2002, 2003, 2004, 2006
   3    Free Software Foundation, Inc.
   4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   5    This file is part of the GNU C Library.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    In addition to the permissions in the GNU Lesser General Public
  13    License, the Free Software Foundation gives you unlimited
  14    permission to link the compiled version of this file with other
  15    programs, and to distribute those programs without any restriction
  16    coming from the use of this file. (The GNU Lesser General Public
  17    License restrictions do apply in other respects; for example, they
  18    cover modification of the file, and distribution when not linked
  19    into another program.)
  20
  21    Note that people who make modified versions of this file are not
  22    obligated to grant this special exception for their modified
  23    versions; it is their choice whether to do so. The GNU Lesser
  24    General Public License gives permission to release a modified
  25    version without this exception; this exception also makes it
  26    possible to release a modified version which carries forward this
  27    exception.
  28
  29    The GNU C Library is distributed in the hope that it will be useful,
  30    but WITHOUT ANY WARRANTY; without even the implied warranty of
  31    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  32    Lesser General Public License for more details.
  33
  34    You should have received a copy of the GNU Lesser General Public
  35    License along with the GNU C Library; if not, write to the Free
  36    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  37    02111-1307 USA.  */
  38
  39 /*
  40    This is the canonical entry point, usually the first thing in the text
  41    segment. Most registers' values are unspecified, except for:
  42
  43    %r14         Contains a function pointer to be registered with `atexit'.
  44                 This is how the dynamic linker arranges to have DT_FINI
  45                 functions called for shared libraries that have been loaded
  46                 before this code runs.
  47
  48    %r15         The stack contains the arguments and environment:
  49                 0(%r15)                 argc
  50                 4(%r15)                 argv[0]
  51                 ...
  52                 (4*argc)(%r15)          NULL
  53                 (4*(argc+1))(%r15)      envp[0]
  54                 ...
  55                                         NULL
  56 */
  57
  58         .text
  59         .globl _start
  60         .type _start,@function
  61 _start:
  62         /* Check if the kernel provides highgprs facility if needed by
  63            the binary.  */
  64
  65         lr      %r6,%r15
  66         la      %r6,4(%r6)     /* Skip the argument counter.  */
  67
  68 .L11:   l       %r5,0(%r6)     /* Skip the argument vector.  */
  69         la      %r6,4(%r6)
  70         ltr     %r5,%r5
  71         jne     .L11
  72
  73 .L12:   l       %r5,0(%r6)     /* Skip the environment vector.  */
  74         la      %r6,4(%r6)
  75         ltr     %r5,%r5
  76         jne     .L12
  77
  78         /* Obtain the needed values from the auxiliary vector.  */
  79
  80         lhi     %r7,16         /* AT_HWCAP */
  81         lhi     %r8,3          /* AT_PHDR */
  82         lhi     %r9,5          /* AT_PHNUM */
  83         lhi     %r2,4          /* AT_PHENT */
  84 .L13:   l       %r5,0(%r6)
  85         clr     %r5,%r7
  86         jne     .L15
  87         l       %r10,4(%r6)    /* r10 = AT_HWCAP value.  */
  88 .L15:   clr     %r5,%r8
  89         jne     .L16
  90         l       %r11,4(%r6)    /* r11 = AT_PHDR value.  */
  91 .L16:   clr     %r5,%r9
  92         jne     .L17
  93         l       %r12,4(%r6)    /* r12 = AT_PHNUM value.  */
  94 .L17:   clr     %r5,%r2
  95         jne     .L18
  96         l       %r0,4(%r6)     /* r0 = AT_PHENT value.  */
  97 .L18:   ltr     %r5,%r5
  98         la      %r6,8(%r6)
  99         jnz     .L13
 100
 101         /* Locate the ELF header by looking for the first PT_LOAD
 102            segment with a p_offset of zero.  */
 103
 104         lr      %r4,%r11       /* Backup AT_PHDR.  */
 105         lhi     %r7,1          /* PT_LOAD id */
 106         lhi     %r8,0
 107 .L19:   cl      %r7,0(%r4)     /* p_type == PT_LOAD? */
 108         jne     .L20
 109         cl      %r8,4(%r4)     /* p_offset == 0? */
 110         jne     .L20
 111         l       %r9,8(%r4)     /* r9 = p_vaddr <- ELF header address  */
 112         j       .L24
 113 .L20:   alr     %r4,%r0        /* r4 += AT_PHENT value */
 114         brct    %r12,.L19
 115
 116         j       .+2            /* Trap, there must be such a phdr.  */
 117
 118 .L24:   lr      %r4,%r11       /* Backup AT_PHDR.  */
 119         lhi     %r2,6          /* PT_PHDR id */
 120 .L23:   cl      %r2,0(%r4)
 121         jne     .L22
 122         l       %r3,8(%r4)     /* r3 = PT_PHDR p_vaddr */
 123         j       .L25
 124 .L22:   alr     %r4,%r0        /* r4 += AT_PHENT value */
 125         brct    %r12,.L23
 126
 127         ltr     %r9,%r9        /* Load address == 0? */
 128         jz      .L14           /* No checking for PIE without PT_PHDR.  */
 129         j       .L21
 130
 131 .L25:   clr     %r3,%r11       /* PT_PHDR p_vaddr == AT_PHDR? */
 132         je      .L21
 133         lr      %r9,%r11
 134         slr     %r9,%r3        /* elf_header_addr = AT_PHDR - PT_PHDR.p_vaddr */
 135
 136 .L21:   l       %r5,36(%r9)    /* Load the e_flags field.  */
 137         tml     %r5,1
 138         jz      .L14           /* Binary does not require highgprs facility.  */
 139
 140         tml     %r10,512       /* Check the AT_HWCAP value.  */
 141         jz      2              /* Trap if no highgprs facility available.  */
 142 .L14:
 143
 144         /* Setup pointer to literal pool of _start */
 145         basr    %r13,0
 146 .L0:    ahi     %r13,.Llit-.L0
 147
 148         /* load argc and argv from stack */
 149         la      %r4,4(%r15)             # get argv
 150         l       %r3,0(%r15)             # get argc
 151
 152         /* align the stack to a double word boundary */
 153         lhi     %r0,-8
 154         nr      %r15,%r0
 155
 156         /* Setup a stack frame and a parameter area */
 157         ahi     %r15,-104               # make room on stack
 158         xc      0(4,%r15),0(%r15)       # clear back-chain
 159
 160         /* set up arguments for __libc_start_main:
 161            main, argc, argv, envp, _init, _fini, rtld_fini, stack_end
 162            Note that envp will be determined later in __libc_start_main
 163          */
 164         stm     %r14,%r15,96(%r15)      # store rtld_fini/stack_end to parameter area
 165         la      %r7,96(%r15)
 166         l       %r6,.L2-.Llit(%r13)     # load pointer to __libc_csu_fini
 167         l       %r5,.L1-.Llit(%r13)     # load pointer to __libc_csu_init
 168         l       %r2,.L3-.Llit(%r13)     # load pointer to main
 169         l       %r1,.L4-.Llit(%r13)     # load pointer to __libc_start_main
 170 #ifdef PIC
 171         l       %r12,.L5-.Llit(%r13)    # load .got pointer
 172         la      %r6,0(%r13,%r6)
 173         la      %r5,0(%r13,%r5)
 174         la      %r12,0(%r13,%r12)
 175         l       %r2,0(%r12,%r2)
 176         la      %r1,0(%r13,%r1)
 177 #endif
 178
 179         /* ok, now branch to the libc main routine */
 180         basr    %r14,%r1
 181
 182         /* crash if __libc_start_main returns */
 183         .word   0
 184
 185 .Llit:
 186 #ifndef PIC
 187 .L1:    .long  __libc_csu_init
 188 .L2:    .long  __libc_csu_fini
 189 .L3:    .long  main
 190 .L4:    .long  __libc_start_main
 191 #else
 192 .L1:    .long  __libc_csu_init-.Llit
 193 .L2:    .long  __libc_csu_fini-.Llit
 194 .L3:    .long  main@GOT
 195 .L4:    .long  __libc_start_main@plt-.Llit
 196 .L5:    .long  _GLOBAL_OFFSET_TABLE_-.Llit
 197 #endif
 198
 199 /* Define a symbol for the first piece of initialized data.  */
 200         .data
 201         .globl __data_start
 202 __data_start:
 203         .long 0
 204         .weak data_start
 205         data_start = __data_start