sysdeps/powerpc/submul_1.S

   1 /* Multiply a limb vector by a single limb, for PowerPC.
   2    Copyright (C) 1993, 1994, 1995, 1997 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Library General Public License as
   7    published by the Free Software Foundation; either version 2 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Library General Public License for more details.
  14
  15    You should have received a copy of the GNU Library General Public
  16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  18    Boston, MA 02111-1307, USA.  */
  19
  20 #include <sysdep.h>
  21
  22 /* mp_limb_t mpn_submul_1 (mp_ptr res_ptr, mp_srcptr s1_ptr,
  23                            mp_size_t s1_size, mp_limb_t s2_limb)
  24    Calculate res-s1*s2 and put result back in res; return carry.  */
  25
  26 ENTRY(__mpn_submul_1)
  27         mtctr   %r5
  28
  29         lwz     %r0,0(%r4)
  30         mullw   %r7,%r0,%r6
  31         mulhwu  %r10,%r0,%r6
  32         lwz     %r9,0(%r3)
  33         subf    %r8,%r7,%r9
  34         addc    %r7,%r7,%r8             # invert cy (r7 is junk)
  35         addi    %r3,%r3,-4              # adjust res_ptr
  36         bdz     1f
  37
  38 0:      lwzu    %r0,4(%r4)
  39         stwu    %r8,4(%r3)
  40         mullw   %r8,%r0,%r6
  41         adde    %r7,%r8,%r10
  42         mulhwu  %r10,%r0,%r6
  43         lwz     %r9,4(%r3)
  44         addze   %r10,%r10
  45         subf    %r8,%r7,%r9
  46         addc    %r7,%r7,%r8             # invert cy (r7 is junk)
  47         bdnz    0b
  48
  49 1:      stw     %r8,4(%r3)
  50         addze   %r3,%r10
  51         blr
  52 END(__mpn_submul_1)