sysdeps/powerpc/sub_n.S

   1 /* Subtract two limb vectors of equal, non-zero length for PowerPC.
   2    Copyright (C) 1997 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Library General Public License as
   7    published by the Free Software Foundation; either version 2 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Library General Public License for more details.
  14
  15    You should have received a copy of the GNU Library General Public
  16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  18    Boston, MA 02111-1307, USA.  */
  19
  20 #include <sysdep.h>
  21
  22 /* mp_limb_t mpn_sub_n (mp_ptr res_ptr, mp_srcptr s1_ptr, mp_srcptr s2_ptr,
  23                         mp_size_t size)
  24    Calculate s1-s2 and put result in res_ptr; return borrow, 0 or 1.  */
  25
  26 /* Note on optimisation: This code is optimal for the 601.  Almost every other
  27    possible 2-unrolled inner loop will not be.  Also, watch out for the
  28    alignment...  */
  29
  30 EALIGN(__mpn_sub_n,3,1)
  31 /* Set up for loop below.  */
  32         mtcrf 0x01,%r6
  33         srwi. %r7,%r6,1
  34         mtctr %r7
  35         bt    31,2f
  36
  37 /* Set the carry (clear the borrow).  */
  38         subfc %r0,%r0,%r0
  39 /* Adjust pointers for loop.  */
  40         addi  %r3,%r3,-4
  41         addi  %r4,%r4,-4
  42         addi  %r5,%r5,-4
  43         b     0f
  44
  45 2:      lwz   %r7,0(%r5)
  46         lwz   %r6,0(%r4)
  47         subfc %r6,%r7,%r6
  48         stw   %r6,0(%r3)
  49         beq   1f
  50
  51 /* Align start of loop to an odd word boundary to guarantee that the
  52    last two words can be fetched in one access (for 601).  This turns
  53    out to be important.  */
  54 0:
  55         lwz   %r9,4(%r4)
  56         lwz   %r8,4(%r5)
  57         lwzu  %r6,8(%r4)
  58         lwzu  %r7,8(%r5)
  59         subfe %r8,%r8,%r9
  60         stw   %r8,4(%r3)
  61         subfe %r6,%r7,%r6
  62         stwu  %r6,8(%r3)
  63         bdnz  0b
  64 /* Return the borrow. */
  65 1:      subfe %r3,%r3,%r3
  66         neg   %r3,%r3
  67         blr
  68 END(__mpn_sub_n)