sysdeps/powerpc/powerpc64/fpu/s_rintf.S

   1 /* Round float to int floating-point values.  PowerPC64 version.
   2    Copyright (C) 2004-2013 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         .section        ".toc","aw"
  22 .LC0:   /* 2**23 */
  23         .tc FD_4b000000_0[TC],0x4b00000000000000
  24         .section        ".text"
  25
  26 EALIGN (__rintf, 4, 0)
  27         CALL_MCOUNT 0
  28         lfs     fp13,.LC0@toc(2)
  29         fabs    fp0,fp1
  30         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  31         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  32         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  33         bnllr   cr7
  34         bng     cr6,.L4
  35         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  36         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  37         fabs    fp1,fp1         /* if (x == 0.0)  */
  38         blr                     /* x = 0.0; */
  39 .L4:
  40         bnllr   cr6             /* if (x < 0.0)  */
  41         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  42         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  43         fnabs   fp1,fp1         /* if (x == 0.0)  */
  44         blr                     /* x = -0.0; */
  45         END (__rintf)
  46
  47 weak_alias (__rintf, rintf)
  48