sysdeps/i386/fpu/s_frexpl.S

   1 /* ix87 specific frexp implementation for long double.
   2    Copyright (C) 1997, 2000-2001, 2005, 2012 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1997.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <machine/asm.h>
  21 #include "bp-sym.h"
  22 #include "bp-asm.h"
  23
  24         .section .rodata
  25
  26         .align ALIGNARG(4)
  27         .type two64,@object
  28 two64:  .byte 0, 0, 0, 0, 0, 0, 0xf0, 0x43
  29         ASM_SIZE_DIRECTIVE(two64)
  30
  31 #ifdef PIC
  32 #define MO(op) op##@GOTOFF(%edx)
  33 #else
  34 #define MO(op) op
  35 #endif
  36
  37 #define PARMS   LINKAGE         /* no space for saved regs */
  38 #define VAL0    PARMS
  39 #define VAL1    VAL0+4
  40 #define VAL2    VAL1+4
  41 #define EXPP    VAL2+4
  42
  43         .text
  44 ENTRY (BP_SYM (__frexpl))
  45         ENTER
  46
  47         movl    VAL0(%esp), %ecx
  48         movl    VAL2(%esp), %eax
  49         orl     VAL1(%esp), %ecx
  50         movl    %eax, %edx
  51         andl    $0x7fff, %eax
  52         orl     %eax, %ecx
  53         jz      1f
  54         xorl    %ecx, %ecx
  55         cmpl    $0x7fff, %eax
  56         je      1f
  57
  58         cmpl    $0, %eax
  59         jne     2f
  60
  61         fldt    VAL0(%esp)
  62 #ifdef  PIC
  63         LOAD_PIC_REG (dx)
  64 #endif
  65
  66         fmull   MO(two64)       /* It's not necessary to use a 80bit factor */
  67         movl    $-64, %ecx
  68         fstpt   VAL0(%esp)
  69         fwait
  70         movl    VAL2(%esp), %eax
  71         movl    %eax, %edx
  72         andl    $0x7fff, %eax
  73
  74 2:      andl    $0x8000, %edx
  75         subl    $16382, %eax
  76         orl     $0x3ffe, %edx
  77         addl    %eax, %ecx
  78         movl    %edx, VAL2(%esp)
  79
  80         /* Store %ecx in the variable pointed to by the second argument,
  81            get the factor from the stack and return.  */
  82 1:      movl    EXPP(%esp), %eax
  83         CHECK_BOUNDS_BOTH_WIDE (%eax, EXPP(%esp), $4)
  84         fldt    VAL0(%esp)
  85         movl    %ecx, (%eax)
  86
  87         LEAVE
  88         ret
  89 END (BP_SYM (__frexpl))
  90 weak_alias (BP_SYM (__frexpl), BP_SYM (frexpl))